[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-software/

["Matt Turner" <mattst88@gentoo.org>]

commit:     d0931c36239fd24ac5ab19078fbf1a4393796832
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri Apr 21 14:36:13 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Apr 22 03:08:04 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d0931c36

gnome-extra/gnome-software: Version bump to 44.1

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/30684
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/gnome-software/Manifest                |   1 +
 .../gnome-software/gnome-software-44.1.ebuild      | 102 +++++++++++++++++++++
 2 files changed, 103 insertions(+)

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 02d31d21609c..988d68e12fa6 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1 +1,2 @@
 DIST gnome-software-44.0.tar.xz 2424172 BLAKE2B 70f20720f6547b0e88d726d9127b989b275f12766bd0fbba86c0ba90ebaf0dcda64f10387bf5a409652f37a5b06baf7447a15a23e811be756172617b1687217f SHA512 592a88fd3488d7d9cd573eff99e8ec503169b52354d672263d7e514846c666c56f87fcbdb31fb8c497ed048808ec223646c247326af76a7e4a361084fd1b180e
+DIST gnome-software-44.1.tar.xz 2422660 BLAKE2B af23ff99a4b5746a1525830bb5454dc823eba519829d390dc21d412a17347396b594df969d5cc80ffc552cf4edf3961e29cf3781f4553bc74293e96bbd33f000 SHA512 4f6d50d8308b3d2694a67f35db0c716f8631380282c7586243499449dd86d11ebfa08a18ccd083839b93bcf7e1b16075433cb427642c2c7b59033e721bb32c9b

diff --git a/gnome-extra/gnome-software/gnome-software-44.1.ebuild b/gnome-extra/gnome-software/gnome-software-44.1.ebuild
new file mode 100644
index 000000000000..78e8766c6584
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-44.1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software https://gitlab.gnome.org/GNOME/gnome-software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flatpak +firmware gnome gtk-doc sysprof udev test"
+
+RDEPEND="
+	>=dev-libs/appstream-0.14.0:0=
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.1.7:=
+	>=gui-libs/gtk-4.9.2:4
+	>=dev-libs/glib-2.70.0:2
+	>=dev-libs/json-glib-1.6.0
+	>=net-libs/libsoup-3.0:3.0
+	>=gui-libs/libadwaita-1.3_rc:1
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+	gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+	sys-auth/polkit
+	firmware? ( >=sys-apps/fwupd-1.5.6 )
+	flatpak? (
+		>=sys-apps/flatpak-1.14.0-r1
+		dev-util/ostree
+	)
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/libglib-testing )
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+	sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test tests)
+		$(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+		-Dman=true
+		-Dpackagekit=false
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		-Deos_updater=false # Endless OS updater
+		$(meson_use firmware fwupd)
+		$(meson_use flatpak)
+		-Dmalcontent=false
+		-Drpm_ostree=false
+		-Dwebapps=true
+		-Dhardcoded_foss_webapps=true
+		-Dhardcoded_proprietary_webapps=true
+		$(meson_use udev gudev)
+		-Dapt=false
+		-Dsnap=false
+		-Dexternal_appstream=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dhardcoded_curated=true
+		-Ddefault_featured_apps=false # TODO: Will this be beneficial to us with flatpak at least? If enabled, it shows some apps under installed (probably merely due to /usr/share/app-info presence), but launching and removal of them is broken
+		-Dmogwai=false #TODO?
+		$(meson_feature sysprof)
+		-Dprofile=''
+		-Dsoup2=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}