public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
From: "Jimi Huotari" <chiitoo@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-panel/
Date: Mon, 17 Apr 2023 22:08:04 +0000 (UTC)	[thread overview]
Message-ID: <1681769146.d9622ff534d921da62e23446934b89b939410878.chiitoo@gentoo> (raw)

commit:     d9622ff534d921da62e23446934b89b939410878
Author:     Michael Vetter <jubalh <AT> iodoru <DOT> org>
AuthorDate: Sat Apr 15 18:55:26 2023 +0000
Commit:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
CommitDate: Mon Apr 17 22:05:46 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d9622ff5

lxqt-base/lxqt-panel: add 1.3.0

Signed-off-by: Michael Vetter <jubalh <AT> iodoru.org>
Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>

 lxqt-base/lxqt-panel/Manifest                |   1 +
 lxqt-base/lxqt-panel/lxqt-panel-1.3.0.ebuild | 117 +++++++++++++++++++++++++++
 2 files changed, 118 insertions(+)

diff --git a/lxqt-base/lxqt-panel/Manifest b/lxqt-base/lxqt-panel/Manifest
index 0249c83df9bc..4b20787b7a84 100644
--- a/lxqt-base/lxqt-panel/Manifest
+++ b/lxqt-base/lxqt-panel/Manifest
@@ -1 +1,2 @@
 DIST lxqt-panel-1.2.0.tar.xz 563852 BLAKE2B 78822e0a268448e0ffabec2a8418d7b72d585a8644cf7f1ee3fcd4aa6723bfd5f158ee38a3facf4410575a918e3cd4c331427d74c961ea2a17497fc464140d5c SHA512 7042cf585c153524aaa43b074f3a9f5c2848e2baf200134ca8194f4ffceda438e55d2cff6cc1c37274b35491234800d728cd89cec89cb42dc914a5bba924f3b6
+DIST lxqt-panel-1.3.0.tar.xz 610764 BLAKE2B 96d4f0368a5071badec0c7dfbcb1f5c9592723fa2ca3be81fe47e0cdccd3108451f204c6de95c154d2ca03f7554fe639afd257f72d554682fabc2bd493ab896d SHA512 1bf66db90e4fbd1ec38688b3a27c9dc5ab2e0a71ace74555580c379e9e12211ded61d01fa46484e8a600bb9b30cb3203ec38697ade0a9cb81cb2cd8043af8b97

diff --git a/lxqt-base/lxqt-panel/lxqt-panel-1.3.0.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-1.3.0.ebuild
new file mode 100644
index 000000000000..00ca261b2d51
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-1.3.0.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="https://lxqt-project.org/"
+
+MY_PV="$(ver_cut 1-2)"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+IUSE="+alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator
++mainmenu +mount networkmonitor pulseaudio +quicklaunch lm-sensors +showdesktop
++spacer +statusnotifier sysstat +taskbar tray +volume +worldclock"
+
+# Work around a missing header issue: https://bugs.gentoo.org/666278
+REQUIRED_USE="
+	|| ( desktopswitch mainmenu showdesktop taskbar )
+	volume? ( || ( alsa pulseaudio ) )
+"
+
+BDEPEND="
+	>=dev-qt/linguist-tools-5.15:5
+	>=dev-util/lxqt-build-tools-0.13.0
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.11.0
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtdbus-5.15:5
+	>=dev-qt/qtgui-5.15:5
+	>=dev-qt/qtsvg-5.15:5
+	>=dev-qt/qtwidgets-5.15:5
+	>=dev-qt/qtx11extras-5.15:5
+	>=dev-qt/qtxml-5.15:5
+	kde-frameworks/kwindowsystem:5[X]
+	>=lxde-base/lxmenu-data-0.1.5
+	>=lxde-base/menu-cache-1.1.0
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	=lxqt-base/lxqt-globalkeys-${MY_PV}*
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	kbindicator? ( x11-libs/libxkbcommon )
+	lm-sensors? ( sys-apps/lm-sensors:= )
+	mount? ( kde-frameworks/solid:5 )
+	networkmonitor? ( sys-libs/libstatgrab )
+	statusnotifier? (
+		dev-libs/libdbusmenu-qt[qt5(+)]
+		>=dev-qt/qtconcurrent-5.15:5
+	)
+	sysstat? ( >=lxqt-base/libsysstat-0.4.6 )
+	tray? (
+		x11-libs/libxcb:=
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXrender
+		x11-libs/xcb-util
+	)
+	volume? (
+		alsa? ( media-libs/alsa-lib )
+		pulseaudio? (
+			media-sound/pavucontrol-qt
+			media-sound/pulseaudio
+		)
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		# Plugins
+		-DCOLORPICKER_PLUGIN=$(usex colorpicker)
+		-DCPULOAD_PLUGIN=$(usex cpuload)
+		-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
+		-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
+		-DDOM_PLUGIN=$(usex dom)
+		-DKBINDICATOR_PLUGIN=$(usex kbindicator)
+		-DMAINMENU_PLUGIN=$(usex mainmenu)
+		-DMOUNT_PLUGIN=$(usex mount)
+		-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
+		-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
+		-DSENSORS_PLUGIN=$(usex lm-sensors)
+		-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
+		-DSPACER_PLUGIN=$(usex spacer)
+		-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
+		-DSYSSTAT_PLUGIN=$(usex sysstat)
+		-DTASKBAR_PLUGIN=$(usex taskbar)
+		-DTRAY_PLUGIN=$(usex tray)
+		-DVOLUME_PLUGIN=$(usex volume)
+		-DWORLDCLOCK_PLUGIN=$(usex worldclock)
+	)
+
+	if use volume; then
+		mycmakeargs+=(
+			-DVOLUME_USE_ALSA=$(usex alsa)
+			-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman panel/man/*.1
+}


             reply	other threads:[~2023-04-17 22:08 UTC|newest]

Thread overview: 74+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2023-04-17 22:08 Jimi Huotari [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-01-31  7:41 [gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-panel/ Arthur Zamarin
2025-01-13 11:10 Jimi Huotari
2025-01-13 11:10 Jimi Huotari
2024-12-07 14:03 Jimi Huotari
2024-12-07 14:03 Jimi Huotari
2024-12-07 14:03 Jimi Huotari
2024-11-07 23:12 Jimi Huotari
2024-10-04 15:37 Arthur Zamarin
2024-09-12 17:23 Arthur Zamarin
2024-09-01 21:30 Sam James
2024-07-13 10:09 Yixun Lan
2024-07-11 19:44 Arthur Zamarin
2024-06-28 20:33 Jimi Huotari
2024-06-14 21:57 Jimi Huotari
2023-12-27 21:03 Sam James
2023-12-20  1:40 Sam James
2023-12-17 23:55 Ionen Wolkens
2023-11-10 13:59 Arthur Zamarin
2023-11-10 12:26 Arthur Zamarin
2023-11-10 12:26 Arthur Zamarin
2023-11-10 12:01 Arthur Zamarin
2023-11-10 10:07 Yixun Lan
2023-11-09 21:45 Jimi Huotari
2023-06-18 14:53 Andreas Sturmlechner
2023-05-29 21:57 Sam James
2023-05-29 18:29 Andreas Sturmlechner
2023-05-29 18:29 Andreas Sturmlechner
2023-05-29 11:05 Arthur Zamarin
2023-05-29  0:10 Sam James
2023-03-26 15:50 Jimi Huotari
2022-12-17 19:28 Arthur Zamarin
2022-12-16 21:49 Sam James
2022-12-16 20:33 Arthur Zamarin
2022-11-10 12:57 Jimi Huotari
2022-07-26  7:05 Sam James
2022-07-22 17:54 Sam James
2022-07-20  5:36 Sam James
2022-05-25 11:20 WANG Xuerui
2022-05-15  0:13 Sam James
2022-04-15 13:14 Arthur Zamarin
2022-04-15  6:17 Sam James
2021-07-26  7:40 Yixun Lan
2021-07-10  0:48 Sam James
2021-04-18 12:11 Andreas Sturmlechner
2021-04-18 12:11 Andreas Sturmlechner
2021-04-18  5:09 Joonas Niilola
2021-01-23 22:55 Sam James
2021-01-21  9:03 Agostino Sarubbo
2020-11-23  7:12 Andreas Sturmlechner
2020-07-31 16:35 Mikle Kolyada
2020-07-31 16:33 Mikle Kolyada
2020-05-20 23:28 Andreas Sturmlechner
2019-09-12 14:28 Michał Górny
2019-09-08 16:18 Andreas Sturmlechner
2019-05-23 12:30 Mikle Kolyada
2019-05-22  7:30 Mikle Kolyada
2019-05-13  0:18 Andreas Sturmlechner
2018-10-17 12:30 Thomas Deutschmann
2018-10-16 13:07 Mikle Kolyada
2018-10-15 22:08 Andreas Sturmlechner
2018-08-11 10:10 Jonathan Scruggs
2018-05-11 21:56 Patrice Clement
2018-04-15 12:43 David Seifert
2017-12-11  1:42 Anthony G. Basile
2017-12-11  0:45 Anthony G. Basile
2016-10-01 12:22 Manuel Rüger
2016-08-07  8:28 Pacho Ramos
2016-04-23 12:59 Davide Pesavento
2016-04-23 12:59 Davide Pesavento
2015-11-28 17:36 Patrice Clement
2015-11-28 17:36 Patrice Clement
2015-11-28 17:36 Patrice Clement
2015-11-28 17:36 Patrice Clement

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1681769146.d9622ff534d921da62e23446934b89b939410878.chiitoo@gentoo \
    --to=chiitoo@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox