[gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-config/

["Jimi Huotari" <chiitoo@gentoo.org>]

commit:     08a4efa3eab2bca84bcf015e0d74c29dc349051a
Author:     Michael Vetter <jubalh <AT> iodoru <DOT> org>
AuthorDate: Sat Apr 15 18:47:06 2023 +0000
Commit:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
CommitDate: Mon Apr 17 22:05:39 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=08a4efa3

lxqt-base/lxqt-config: add 1.3.0

Signed-off-by: Michael Vetter <jubalh <AT> iodoru.org>
Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>

 lxqt-base/lxqt-config/Manifest                 |  1 +
 lxqt-base/lxqt-config/lxqt-config-1.3.0.ebuild | 72 ++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/lxqt-base/lxqt-config/Manifest b/lxqt-base/lxqt-config/Manifest
index 49f27324d3da..5743629277c1 100644
--- a/lxqt-base/lxqt-config/Manifest
+++ b/lxqt-base/lxqt-config/Manifest
@@ -1 +1,2 @@
 DIST lxqt-config-1.2.0.tar.xz 364972 BLAKE2B 2c4082f8b70284492d02372e03088dbade48a8288cd2e0038dd60fd4a70c4ff434188d795ec75bbd268ea3d75661751230c06a74f1cd65273934f89604c7170d SHA512 ae0f71a6ac85e80bc1d1de890148b908bda21aced0829f5f203442f3a0139dbeec44e7190adc1f5706361f4cf7a00bdead3035c63bf6da2bbba5a16a88d7b469
+DIST lxqt-config-1.3.0.tar.xz 370624 BLAKE2B 2015d2ec8f1a925e505b8c93b3db99fe351d8db742c78b2a19e8f8be7df47be619b3b5c313a693f1ac4e54b1f117aea5a706e8eae2d0fb6340fafe1b4a47412d SHA512 30610d1c90d897eb54ce5ee75a39721a7818b0164bc97dece5b74aec2032c3b0027316995d83c077352e93fd2f7ab319d1801ed5ce356b857805e855db71cd75

diff --git a/lxqt-base/lxqt-config/lxqt-config-1.3.0.ebuild b/lxqt-base/lxqt-config/lxqt-config-1.3.0.ebuild
new file mode 100644
index 000000000000..ba267034532a
--- /dev/null
+++ b/lxqt-base/lxqt-config/lxqt-config-1.3.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PV="$(ver_cut 1-2)"
+
+inherit cmake xdg-utils
+
+DESCRIPTION="LXQt system configuration control center"
+HOMEPAGE="https://lxqt-project.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-2 GPL-2+ GPL-3 LGPL-2 LGPL-2+ LGPL-2.1+ WTFPL-2"
+SLOT="0"
+IUSE="+monitor +touchpad"
+
+BDEPEND="
+	>=dev-qt/linguist-tools-5.15:5
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.11.0
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtgui-5.15:5
+	>=dev-qt/qtwidgets-5.15:5
+	>=dev-qt/qtsvg-5.15:5
+	>=dev-qt/qtx11extras-5.15:5
+	>=dev-qt/qtxml-5.15:5
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	sys-libs/zlib:=
+	x11-apps/setxkbmap
+	x11-libs/libxcb:=
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	monitor? ( kde-plasma/libkscreen:5= )
+	touchpad? (
+		virtual/libudev:=
+		x11-drivers/xf86-input-libinput
+		x11-libs/libXi
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MONITOR=$(usex monitor)
+		-DWITH_TOUCHPAD=$(usex touchpad)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman man/*.1 liblxqt-config-cursor/man/*.1 lxqt-config-appearance/man/*.1
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}