[gentoo-commits] repo/gentoo:master commit in: dev-python/dask/

["Michał Górny" <mgorny@gentoo.org>]

commit:     c8ee95ca7e4cb67fcd55d2a547fe1f47c24b1650
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 15 06:07:40 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Apr 15 08:23:26 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c8ee95ca

dev-python/dask: Bump to 2023.4.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/dask/Manifest             |  1 +
 dev-python/dask/dask-2023.4.0.ebuild | 73 ++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/dev-python/dask/Manifest b/dev-python/dask/Manifest
index b328b189eb08..b2db70afa003 100644
--- a/dev-python/dask/Manifest
+++ b/dev-python/dask/Manifest
@@ -1 +1,2 @@
 DIST dask-2023.3.2.gh.tar.gz 8525841 BLAKE2B 660f3687320c0d56abe437bf7edea2f40fe624a3f48761238b00756f61358d73d47a570399ed70f6f1f2188cb03b04fc10e5c9683e2a49c6b73a21c35173e1dc SHA512 ef1a961a50e69a32aea14630e9d19fc92646e9f520fa265937bb923aeba5932397840b2971bfb9a47125672ac2bd9b0b6a017b650708a183b3bf6c0c345e2af2
+DIST dask-2023.4.0.gh.tar.gz 8511473 BLAKE2B 3b6a4e07e0ddc1a40b9494089250e80254b16002c18b091911aa007e1e455f146a192e5f8f9c49b5cf73bc60d942429e1d5ff399516f2b81120ae8f4d79b1dbb SHA512 40071fc3f5597312af28a5c545ebb14d2e2aa3d1a3a0a5d81d335fce3a7a8e7036c900a1caa43f84f76335c469b1bf138f662588f0d015943c4a4bf931c20349

diff --git a/dev-python/dask/dask-2023.4.0.ebuild b/dev-python/dask/dask-2023.4.0.ebuild
new file mode 100644
index 000000000000..3176aad61c51
--- /dev/null
+++ b/dev-python/dask/dask-2023.4.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Task scheduling and blocked algorithms for parallel processing"
+HOMEPAGE="
+	https://www.dask.org/
+	https://github.com/dask/dask/
+	https://pypi.org/project/dask/
+"
+SRC_URI="
+	https://github.com/dask/dask/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/click-7.0[${PYTHON_USEDEP}]
+	>=dev-python/cloudpickle-1.1.1[${PYTHON_USEDEP}]
+	>=dev-python/fsspec-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/importlib_metadata-4.13.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.21[${PYTHON_USEDEP}]
+	>=dev-python/pandas-1.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	>=dev-python/partd-1.2.0[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+	>=dev-python/toolz-0.8.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/toolz[${PYTHON_USEDEP}]
+	>=dev-python/versioneer-0.28[${PYTHON_USEDEP}]
+	test? (
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/numexpr[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# more tests relying on -Werror
+	"dask/array/tests/test_overlap.py::test_map_overlap_no_depth[None]"
+	dask/array/tests/test_random.py::test_RandomState_only_funcs
+	# TODO
+	dask/array/tests/test_reductions.py::test_mean_func_does_not_warn
+	dask/tests/test_config.py::test__get_paths
+	dask/array/tests/test_linalg.py::test_solve_assume_a
+	"dask/dataframe/tests/test_dataframe.py::test_repartition_npartitions[<lambda>0-float-5-1-True]"
+	"dask/dataframe/tests/test_dataframe.py::test_repartition_npartitions[<lambda>1-float-5-1-True]"
+	# require sqlalchemy<2.0
+	dask/dataframe/io/tests/test_sql.py
+)
+
+src_prepare() {
+	# fails with sqlalchemy-2.0, even though we don't use it x_x
+	sed -i -e '/RemovedIn20Warning/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	epytest -p no:flaky -m "not network"
+}