[gentoo-commits] repo/gentoo:master commit in: dev-util/pahole/

["Matthias Schwarzott" <zzam@gentoo.org>]

commit:     38129134c152450573f54094a887126d545b71f5
Author:     Matthias Schwarzott <zzam <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 15 07:16:52 2023 +0000
Commit:     Matthias Schwarzott <zzam <AT> gentoo <DOT> org>
CommitDate: Sat Apr 15 07:17:51 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=38129134

dev-util/pahole: add 1.25

Signed-off-by: Matthias Schwarzott <zzam <AT> gentoo.org>

 dev-util/pahole/Manifest           |  1 +
 dev-util/pahole/pahole-1.25.ebuild | 65 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/dev-util/pahole/Manifest b/dev-util/pahole/Manifest
index 546524260172..91c614ea459a 100644
--- a/dev-util/pahole/Manifest
+++ b/dev-util/pahole/Manifest
@@ -1,2 +1,3 @@
 DIST dwarves-1.24.tar.xz 875744 BLAKE2B 6766b5a5ecbf64013227e7cd459af662fc213f230b5b1279354fcaaccebfa3d74f9a2254542dc4f3f1bb4a5def1d4c77e2445fa8b531fa8b9e331cdfc23155fe SHA512 3cdca183cf68ec46fd9a0301ae4a8a30b23a8139c65ffba64ae11f85f9e942f7341dca6f88a4a3b49f32bfd880927193a80fa011726e4a33d3e5a1a146326c06
+DIST dwarves-1.25.tar.xz 2244876 BLAKE2B 1926fa1fa123fc3ad0f7f063406260b1e1e2611c563fedebee4c837e491164571fdb40408421c0c4ea2fd24e89c54a7a1ea669313b6dd6d7dcfa4934e2c1336e SHA512 104bfb8712d863e04d0c827c008b23ebc49543b17bfb5b44ce276a5b3d39f12cf71f721055ae2e5f430aa77a3c70f85f6eeaf72fd8c1cdf547260488bc5b5070
 DIST pahole-1.24_p20221024-patches.tar.xz 22088 BLAKE2B b39458400411dd7da0f568257f42164952e170b952e4893a92d769e17ce4cf0de88b727808a38195438fe10e5537f245bf101f647f383b6df7642c5446fa5d45 SHA512 93f160f01023c5402535a34d59005f0a3e056662a2764722480d71b6e522f3bfef0d642084467d1fbea96e23386b4cbb708243713d59eb84f4f767c1ac5ab3f5

diff --git a/dev-util/pahole/pahole-1.25.ebuild b/dev-util/pahole/pahole-1.25.ebuild
new file mode 100644
index 000000000000..5d98a672167d
--- /dev/null
+++ b/dev-util/pahole/pahole-1.25.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit cmake python-single-r1
+
+MY_PN=dwarves
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="pahole (Poke-a-Hole) and other DWARF2 utilities"
+HOMEPAGE="https://git.kernel.org/cgit/devel/pahole/pahole.git/"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/devel/pahole/pahole.git"
+	inherit git-r3
+elif [[ ${PV} == *_p* ]] ; then
+	# Snapshots
+	#SRC_URI="https://dev.gentoo.org/~zzam/${PN}/${P}.tar.xz"
+
+	# Patch rollups from git format-patch. Sometimes there are important
+	# fixes in git which haven't been released (and no release in sight).
+	# Patch rollups are a bit better for understanding where changes have
+	# come from for users.
+	SRC_URI="
+		http://fedorapeople.org/~acme/${MY_PN}/${MY_P%%_p*}.tar.xz
+		https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-patches.tar.xz
+	"
+	S="${WORKDIR}"/${MY_P%%_p*}
+else
+	SRC_URI="http://fedorapeople.org/~acme/${MY_PN}/${MY_P}.tar.xz"
+	S="${WORKDIR}"/${MY_P}
+fi
+
+LICENSE="GPL-2" # only
+SLOT="0"
+IUSE="debug"
+if [[ ${PV} != 9999 ]] ; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+fi
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-libs/elfutils-0.178
+	sys-libs/zlib"
+DEPEND="${RDEPEND}"
+
+DOCS=( README README.ctracer NEWS )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.10-python-import.patch
+)
+
+src_prepare() {
+	[[ -d "${WORKDIR}"/${P}-patches ]] && PATCHES+=( "${WORKDIR}"/${P}-patches )
+
+	cmake_src_prepare
+	python_fix_shebang ostra/ostra-cg ostra/python/ostra.py
+}
+
+src_configure() {
+	local mycmakeargs=( "-D__LIB=$(get_libdir)" )
+	cmake_src_configure
+}