[gentoo-commits] repo/gentoo:master commit in: dev-util/librnp/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     1ee9c4190e2ce8af9ee0d8545a198f16d8954b05
Author:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 13 05:40:17 2023 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Thu Apr 13 05:55:14 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1ee9c419

dev-util/librnp: add 0.16.3

Bug: https://bugs.gentoo.org/904250
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-util/librnp/Manifest             |  1 +
 dev-util/librnp/librnp-0.16.3.ebuild | 73 ++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/dev-util/librnp/Manifest b/dev-util/librnp/Manifest
index 492987b6ba46..f4790bac456a 100644
--- a/dev-util/librnp/Manifest
+++ b/dev-util/librnp/Manifest
@@ -1 +1,2 @@
 DIST librnp-0.16.2.tar.gz 2897137 BLAKE2B 5f756047506531e0ed3d431cebd3977f3492b464445f6dc54850badc795478f5d04ff036147e8212b4a3e2d4fd939f4bcf668e9a260c2e7fc616ef51dea02117 SHA512 5fd5fceb39429e130adafd4869d9a01149d9c08271770da4eedbe75910788f8256c8bf19e6bb0886a902b22dd5564eb93baddaf84689cbf5e6617674f4f0efac
+DIST librnp-0.16.3.tar.gz 2897854 BLAKE2B 71e39e810bdbee351c8136df1d11621daccb1738db691b99244ffe5bd2ea372c3ef520ade7cd63c38510fae0f252d5a1c2ceb44db3fbffbd64dfc10612341e29 SHA512 b133fb1f9aab6e9b5caecdcf0bd9f2c67a62a98543ca1ac6a7cf4a35b7a571d53e4fa99cefc98f8253117cf0de16194db309efa03bc40fd3556f9b84cf51a942

diff --git a/dev-util/librnp/librnp-0.16.3.ebuild b/dev-util/librnp/librnp-0.16.3.ebuild
new file mode 100644
index 000000000000..ca34a07b87f9
--- /dev/null
+++ b/dev-util/librnp/librnp-0.16.3.ebuild
@@ -0,0 +1,73 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="High performance C++ OpenPGP library"
+HOMEPAGE="https://www.rnpgp.org/ https://github.com/rnpgp/rnp"
+SRC_URI="https://github.com/rnpgp/rnp/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0 BSD BSD-2"
+SLOT="0/0.16.1"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+botan man test"
+
+RDEPEND="app-arch/bzip2
+	dev-libs/json-c:=
+	sys-libs/zlib
+	botan? ( dev-libs/botan:2= )
+	!botan? ( >=dev-libs/openssl-1.1.1:= )"
+DEPEND="${RDEPEND}
+	test? ( dev-cpp/gtest )"
+BDEPEND="man? ( dev-ruby/asciidoctor )"
+
+RESTRICT="!test? ( test )"
+S="${WORKDIR}/${P/*lib/}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test on off)
+
+		-DCRYPTO_BACKEND=$(usex botan botan openssl)
+
+		-DDOWNLOAD_GTEST=off
+		-DDOWNLOAD_RUBYRNP=off
+
+		-DENABLE_COVERAGE=off
+		-DENABLE_DOC=$(usex man on off)
+		-DENABLE_FUZZERS=off
+		-DENABLE_SANITIZERS=off
+	)
+
+	if use botan; then
+		local mycmakeargs+=(
+			-DENABLE_AEAD=on
+			-DENABLE_BRAINPOOL=on
+			-DENABLE_IDEA=on
+			-DENABLE_SM2=on
+			-DENABLE_TWOFISH=on
+		)
+
+	# OpenSSL support is still not as complete as botan.
+	# https://github.com/rnpgp/rnp/issues/1642 (v. 0.17.0),
+	# https://github.com/rnpgp/rnp/issues/1877 SM2,
+	# https://github.com/openssl/openssl/issues/2046 TWOFISH (won't be implemented).
+	else
+		local mycmakeargs+=(
+			-DENABLE_AEAD=off
+			-DENABLE_BRAINPOOL=on
+			-DENABLE_IDEA=on
+			-DENABLE_SM2=off
+			-DENABLE_TWOFISH=off
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}"/src/tests || die
+	ctest -j"${MAKEOPTS}" -R .* --output-on-failure || die
+}