[gentoo-commits] repo/gentoo:master commit in: dev-python/fsspec/

["Michał Górny" <mgorny@gentoo.org>]

commit:     67d74608d868cbb527d8275e38c07b8ecaf72980
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Apr  9 05:52:33 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Apr  9 06:08:32 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=67d74608

dev-python/fsspec: Bump to 2023.4.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/fsspec/Manifest               |  1 +
 dev-python/fsspec/fsspec-2023.4.0.ebuild | 64 ++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/dev-python/fsspec/Manifest b/dev-python/fsspec/Manifest
index 58931c2954cc..45db6c4d2cd8 100644
--- a/dev-python/fsspec/Manifest
+++ b/dev-python/fsspec/Manifest
@@ -1 +1,2 @@
 DIST filesystem_spec-2023.3.0.gh.tar.gz 352352 BLAKE2B e4a4edb882aa0aa15f654d3ae63d278b03a0b1fdc99fb1e7f48baefa750134aa2c9ddc89cc53aa829155b103107cbfb0c99d6c6fdeb5bf85068af5f1fc467ae4 SHA512 7c21eb60932267fe73dea3672d2e9b2d71fb3df26aedec9d109109168b91605602903518337563c00ae8b7d82212211ca569d3a91adb840eefd41eecab33c3ec
+DIST filesystem_spec-2023.4.0.gh.tar.gz 356769 BLAKE2B 72425ae67b57e0e44589903b3858fcca73bd20894586782599e669eb56d48268677bdf6f6047b40317b2e5f10641bea77a4ffa4968666b4ee159536bdb82fd88 SHA512 3b8702de33519ea6e88b61c83b61399bfe1df1717aa1332488f427b0c875a74dfae9c81d8b1407a5c008fb26838e5c798ccddf7eff45bfca1476b5883cf3f0c0

diff --git a/dev-python/fsspec/fsspec-2023.4.0.ebuild b/dev-python/fsspec/fsspec-2023.4.0.ebuild
new file mode 100644
index 000000000000..d5afd3b814ef
--- /dev/null
+++ b/dev-python/fsspec/fsspec-2023.4.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+MY_P=filesystem_spec-${PV}
+DESCRIPTION="A specification that python filesystems should adhere to"
+HOMEPAGE="
+	https://github.com/fsspec/filesystem_spec/
+	https://pypi.org/project/fsspec/
+"
+SRC_URI="
+	https://github.com/fsspec/filesystem_spec/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/tqdm[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+	distutils-r1_src_test
+}
+
+EPYTEST_DESELECT=(
+	fsspec/tests/test_spec.py::test_find
+	# requires s3fs
+	fsspec/implementations/tests/test_local.py::test_urlpath_inference_errors
+	fsspec/tests/test_core.py::test_mismatch
+	# requires pyarrow, fastparquet
+	fsspec/implementations/tests/test_reference.py::test_df_single
+	fsspec/implementations/tests/test_reference.py::test_df_multi
+)
+
+EPYTEST_IGNORE=(
+	# sftp and smb require server started via docker
+	fsspec/implementations/tests/test_dbfs.py
+	fsspec/implementations/tests/test_sftp.py
+	fsspec/implementations/tests/test_smb.py
+	# unhappy about dev-python/fuse-python (?)
+	fsspec/tests/test_fuse.py
+)