[gentoo-commits] repo/gentoo:master commit in: dev-libs/imath/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     2f4f14af2d5b96d2aff4a0f6cf05118e5fc60f39
Author:     Bernd Waibel <waebbl-gentoo <AT> posteo <DOT> net>
AuthorDate: Sun Mar  5 12:44:51 2023 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Mon Apr  3 07:04:28 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2f4f14af

dev-libs/imath: add 3.1.7

Closes: https://bugs.gentoo.org/899562
Signed-off-by: Bernd Waibel <waebbl-gentoo <AT> posteo.net>
Closes: https://github.com/gentoo/gentoo/pull/29936
Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 dev-libs/imath/Manifest           |  1 +
 dev-libs/imath/imath-3.1.7.ebuild | 74 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/dev-libs/imath/Manifest b/dev-libs/imath/Manifest
index b782847d7470..4bf4962b7f9d 100644
--- a/dev-libs/imath/Manifest
+++ b/dev-libs/imath/Manifest
@@ -1 +1,2 @@
 DIST imath-3.1.6.tar.gz 573255 BLAKE2B c4d5a785a2aed9c5b9b1441ab016a5cf47abeb1d44c0625f0654e8c4d1e47dddddd62c61f83fd7b160beae8aaf5db9350d2a3bc43754e795fe75b10c4836a1b8 SHA512 c099a291ed7fd7702a7609575f2f3d2ed7f95256c23c2180e2ef1f76ceb07734365f57da5244b1d6cec81ca9859864eb4c9236df02a64aa783af6639a3b59acd
+DIST imath-3.1.7.tar.gz 583049 BLAKE2B 54619339f349a944e1d72fcea4438d7bd2ef6c9655ba0e16ac608934a8df30c97a2f3cf5c75adaeb8a6fe6bf19ec3240c11439550b452571d0a8cbf75d6bd83e SHA512 e298454cb845cadde28f7881fdaa4739c3942f941278a07ec912459ac376c2ee7858cb3b2d2047b9afb4d4dacae7a8a52ffef4c104f8499b4e0a1f0ed46cc0f0

diff --git a/dev-libs/imath/imath-3.1.7.ebuild b/dev-libs/imath/imath-3.1.7.ebuild
new file mode 100644
index 000000000000..dcbddf244ce4
--- /dev/null
+++ b/dev-libs/imath/imath-3.1.7.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake python-single-r1
+
+MY_PN="${PN^}"
+
+DESCRIPTION="Imath basic math package"
+HOMEPAGE="https://imath.readthedocs.io"
+SRC_URI="https://github.com/AcademySoftwareFoundation/${MY_PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+# re-keywording needed for (according to ilmbase keywords): ~x64-macos ~x86-solaris
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="BSD"
+SLOT="3/30"
+IUSE="large-stack python test"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+# blocker due to file collision #803347
+RDEPEND="
+	!dev-libs/imath:0
+	!media-libs/ilmbase
+	sys-libs/zlib
+	python? (
+		!dev-python/pyilmbase
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-libs/boost:=[python,${PYTHON_USEDEP}]
+			dev-python/numpy[${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	python? ( ${PYTHON_DEPS} )
+"
+
+DOCS=( CHANGES.md CONTRIBUTORS.md README.md SECURITY.md docs/PortingGuide2-3.md )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# requires press theme, not available in ::gentoo
+		-DBUILD_DOCS=OFF
+		-DIMATH_ENABLE_LARGE_STACK=$(usex large-stack)
+		# the following options are at their default value
+		-DIMATH_HALF_USE_LOOKUP_TABLE=ON
+		-DIMATH_INSTALL_PKG_CONFIG=ON
+		-DIMATH_USE_CLANG_TIDY=OFF
+		-DIMATH_USE_DEFAULT_VISIBILITY=OFF
+		-DIMATH_USE_NOEXCEPT=ON
+	)
+	if use python; then
+		mycmakeargs+=(
+			-DBoost_NO_BOOST_CMAKE=OFF
+			-DPYTHON=ON
+			-DPython3_EXECUTABLE="${PYTHON}"
+			-DPython3_INCLUDE_DIR=$(python_get_includedir)
+			-DPython3_LIBRARY=$(python_get_library_path)
+		)
+	fi
+
+	cmake_src_configure
+}