[gentoo-commits] repo/gentoo:master commit in: sci-libs/htslib/

["David Seifert" <soap@gentoo.org>]

commit:     30fc69a81e71a3c6d6a72af3b9b24e5b742c2832
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 30 11:10:58 2023 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Thu Mar 30 11:10:58 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=30fc69a8

sci-libs/htslib: add 1.17

Signed-off-by: David Seifert <soap <AT> gentoo.org>

 sci-libs/htslib/Manifest           |  1 +
 sci-libs/htslib/htslib-1.17.ebuild | 52 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/sci-libs/htslib/Manifest b/sci-libs/htslib/Manifest
index 5634c4532cc9..6f53bfe1e726 100644
--- a/sci-libs/htslib/Manifest
+++ b/sci-libs/htslib/Manifest
@@ -1 +1,2 @@
 DIST htslib-1.16.tar.bz2 4466776 BLAKE2B 4957dd7a25b3d0b939d4e924db018916a5f8a13a81e55ebd1ce1acc548986e581d017ead9a08245a4af1ebdcd15536f082425ebe05f16eb4faad27d332e48482 SHA512 9fa0b1f9bba50f889d4542825c9543fb3b34c13b4cc0e18940a66fafd130749574bfa2c2663d8b39f0b4ed2b298bf130367cda1b17b2929093d64b386730cbc5
+DIST htslib-1.17.tar.bz2 4619884 BLAKE2B c45591b3f1da4f6ddfdf5e1a20864583d57de2a460d42049715335fce7dafe1f5cd14403e6033fee4f9d0bfc75f8777b5835d2d01bf2cadff0155d9fc92b97d9 SHA512 624ab449d57713dab2d34399926c065f8cff8a45e6fbe68e0bb518c601421f587b613caeb095f8639b1d67cdb4a65d658c85f942173bcaa48da026fe15def5d3

diff --git a/sci-libs/htslib/htslib-1.17.ebuild b/sci-libs/htslib/htslib-1.17.ebuild
new file mode 100644
index 000000000000..6f690363326b
--- /dev/null
+++ b/sci-libs/htslib/htslib-1.17.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="C library for high-throughput sequencing data formats"
+HOMEPAGE="http://www.htslib.org/"
+SRC_URI="https://github.com/samtools/${PN}/releases/download/${PV}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0/3"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+bzip2 curl +lzma"
+
+RDEPEND="
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	curl? ( net-misc/curl )
+	lzma? ( app-arch/xz-utils )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# upstream injects LDFLAGS into the .pc file,
+	# which is a big nono for QA
+	sed -e '/^\(static_l\|Libs.private\|Requires.private\)/d' \
+		-i htslib.pc.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-gcs \
+		--disable-plugins \
+		--disable-s3 \
+		$(use_enable bzip2 bz2) \
+		$(use_enable curl libcurl) \
+		$(use_enable lzma)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+
+	# doesn't use libtool, can't disable static libraries
+	find "${ED}" -name '*.a' -delete || die
+}