[gentoo-commits] repo/gentoo:master commit in: dev-python/awxkit/

["Michał Górny" <mgorny@gentoo.org>]

commit:     73114b75af3dc4d13648b73031647b2bc35f35ae
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 28 04:29:31 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Mar 28 05:19:44 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=73114b75

dev-python/awxkit: Bump to 21.14.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/awxkit/Manifest              |  1 +
 dev-python/awxkit/awxkit-21.14.0.ebuild | 49 +++++++++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/dev-python/awxkit/Manifest b/dev-python/awxkit/Manifest
index 131107a573ce..aaacd39f7afa 100644
--- a/dev-python/awxkit/Manifest
+++ b/dev-python/awxkit/Manifest
@@ -1 +1,2 @@
 DIST awx-21.13.0.gh.tar.gz 16221713 BLAKE2B 7e875efced94fb22d782deb9583fddfa13e10079a202298d0ca05af58048d4bf70480aacec7f0e3c408c9600fff126886cb6912bdadb3f48a33932c9debd2344 SHA512 90628347f71663d4e13fed2cc529b3bda858d07130b74593582e82e19b8c6e6049c9ad6cdd419e4efa4bd366771e993665ef4527f5de336edd5f020c9a93ca7a
+DIST awx-21.14.0.gh.tar.gz 16484659 BLAKE2B 3541286c899eceb3a64719b08c0456abe34d70f6e97f3ecf24c4066da1173be02e613e42ecb1193f371703f8fa55abf0eba0106ccf884e6bb53bca9f2f2d2a0e SHA512 5c7efae528cdebffbce745f5e63807944db5a3a4b72880515da6d25de414d2d8c8a1ffb74f9f78f8cf72a6584437b627d8d53fd555021b943653d28427bd1021

diff --git a/dev-python/awxkit/awxkit-21.14.0.ebuild b/dev-python/awxkit/awxkit-21.14.0.ebuild
new file mode 100644
index 000000000000..707b930aafad
--- /dev/null
+++ b/dev-python/awxkit/awxkit-21.14.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..10} )
+
+inherit distutils-r1
+
+MY_P=awx-${PV}
+DESCRIPTION="Command line interface for Ansible AWX"
+HOMEPAGE="
+	https://github.com/ansible/awx/
+	https://pypi.org/project/awxkit/
+"
+SRC_URI="
+	https://github.com/ansible/awx/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/awxkit"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+	dev-python/pyjwt[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+	printf '%s\n' "${PV}" > VERSION || die
+
+	sed -e 's|websocket-client==[[:digit:]\.]*|websocket-client|' \
+		-e "/'clean'/d" \
+		-i setup.py || die
+	distutils-r1_src_prepare
+}