[gentoo-commits] repo/gentoo:master commit in: sys-devel/autoconf/

["Arsen Arsenović" <arsen@gentoo.org>]

commit:     8a1b8b22c71b9c3ce843bd0dc768bc71fec30806
Author:     Arsen Arsenović <arsen <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 26 08:46:51 2023 +0000
Commit:     Arsen Arsenović <arsen <AT> gentoo <DOT> org>
CommitDate: Mon Mar 27 20:27:12 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8a1b8b22

sys-devel/autoconf: Add revisions without Info path breaking

Closes: https://bugs.gentoo.org/902461
Signed-off-by: Arsen Arsenović <arsen <AT> gentoo.org>

 sys-devel/autoconf/autoconf-2.13-r8.ebuild         | 59 ++++++++++++++++++++
 sys-devel/autoconf/autoconf-2.69-r9.ebuild         | 63 ++++++++++++++++++++++
 ...toconf-2.72c.ebuild => autoconf-2.71-r6.ebuild} | 36 +++++++------
 ...oconf-2.72c.ebuild => autoconf-2.72c-r1.ebuild} |  0
 4 files changed, 142 insertions(+), 16 deletions(-)

diff --git a/sys-devel/autoconf/autoconf-2.13-r8.ebuild b/sys-devel/autoconf/autoconf-2.13-r8.ebuild
new file mode 100644
index 000000000000..69156d4abf78
--- /dev/null
+++ b/sys-devel/autoconf/autoconf-2.13-r8.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-autoconf
+
+DESCRIPTION="Used to create autoconfiguration files"
+HOMEPAGE="https://www.gnu.org/software/autoconf/autoconf.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="${PV:0:3}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-lang/perl
+	sys-devel/m4
+	test? ( dev-util/dejagnu )
+"
+RDEPEND="
+	${BDEPEND}
+	sys-apps/texinfo
+	>=sys-devel/autoconf-wrapper-13
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gentoo.patch
+	"${FILESDIR}"/${P}-destdir.patch
+	"${FILESDIR}"/${P}-test-fixes.patch #146592
+	"${FILESDIR}"/${P}-perl-5.26.patch
+	"${FILESDIR}"/${P}-K-R-decls-clang.patch
+	"${FILESDIR}"/${P}-Clang-16-fixes-for-various-tests.patch
+)
+
+src_configure() {
+	# make sure configure is newer than configure.in
+	touch configure || die
+
+	# need to include --exec-prefix and --bindir or our
+	# DESTDIR patch will trigger sandbox hate :(
+	#
+	# need to force locale to C to avoid bugs in the old
+	# configure script breaking the install paths #351982
+	#
+	# force to `awk` so that we don't encode another awk that
+	# happens to currently be installed, but might later be
+	# uninstalled (like mawk).  same for m4.
+	ac_cv_path_M4="m4" \
+	ac_cv_prog_AWK="awk" \
+	LC_ALL=C \
+	econf \
+		--exec-prefix="${EPREFIX}"/usr \
+		--bindir="${EPREFIX}"/usr/bin \
+		--program-suffix="-${PV}" \
+		--infodir="${TC_AUTOCONF_INFOPATH}"
+}

diff --git a/sys-devel/autoconf/autoconf-2.69-r9.ebuild b/sys-devel/autoconf/autoconf-2.69-r9.ebuild
new file mode 100644
index 000000000000..45c66d96f77c
--- /dev/null
+++ b/sys-devel/autoconf/autoconf-2.69-r9.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/autoconf.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
+		ftp://alpha.gnu.org/pub/gnu/${PN}/${P}.tar.xz
+		https://dev.gentoo.org/~polynomial-c/dist/${P}-runstatedir_patches.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+inherit toolchain-autoconf
+
+DESCRIPTION="Used to create autoconfiguration files"
+HOMEPAGE="https://www.gnu.org/software/autoconf/autoconf.html"
+
+LICENSE="GPL-3+"
+SLOT="${PV}"
+IUSE="emacs"
+
+BDEPEND="
+	>=sys-devel/m4-1.4.16
+	>=dev-lang/perl-5.6
+"
+RDEPEND="
+	${BDEPEND}
+	>=sys-devel/autoconf-wrapper-13
+	!~sys-devel/${P}:2.5
+"
+
+[[ ${PV} == 9999 ]] && BDEPEND+=" >=sys-apps/texinfo-4.3"
+
+PDEPEND="emacs? ( app-emacs/autoconf-mode )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.69-perl-5.26.patch
+	"${FILESDIR}"/${P}-fix-libtool-test.patch
+	"${FILESDIR}"/${PN}-2.69-perl-5.26-2.patch
+	"${FILESDIR}"/${P}-make-tests-bash5-compatible.patch
+	"${FILESDIR}"/${P}-K-R-decls-clang.patch
+
+	"${WORKDIR}"/patches/${P}-texinfo.patch
+)
+
+src_prepare() {
+	# usr/bin/libtool is provided by binutils-apple, need gnu libtool
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		PATCHES+=( "${FILESDIR}"/${PN}-2.61-darwin.patch )
+	fi
+
+	# Save timestamp to avoid later makeinfo call
+	touch -r doc/{,old_}autoconf.texi || die
+
+	toolchain-autoconf_src_prepare
+
+	# Restore timestamp to avoid makeinfo call
+	# We already have an up to date autoconf.info page at this point.
+	touch -r doc/{old_,}autoconf.texi || die
+}

diff --git a/sys-devel/autoconf/autoconf-2.72c.ebuild b/sys-devel/autoconf/autoconf-2.71-r6.ebuild
similarity index 71%
copy from sys-devel/autoconf/autoconf-2.72c.ebuild
copy to sys-devel/autoconf/autoconf-2.71-r6.ebuild
index 1bd34bcdca1a..af4176383c24 100644
--- a/sys-devel/autoconf/autoconf-2.72c.ebuild
+++ b/sys-devel/autoconf/autoconf-2.71-r6.ebuild
@@ -11,17 +11,14 @@ else
 	MY_PV="${PV}"
 	MY_P="${PN}-${MY_PV}"
 	#PATCH_TARBALL_NAME="${PN}-2.70-patches-01"
+	SRC_URI="mirror://gnu/${PN}/${MY_P}.tar.xz
+		https://alpha.gnu.org/pub/gnu/${PN}/${MY_P}.tar.xz"
+	#SRC_URI+=" https://dev.gentoo.org/~polynomial-c/${PATCH_TARBALL_NAME}.tar.xz"
 
-	SRC_URI="
-		mirror://gnu/${PN}/${MY_P}.tar.xz
-		https://alpha.gnu.org/pub/gnu/${PN}/${MY_P}.tar.xz
-		https://meyering.net/ac/${P}.tar.xz
-	"
-	 S="${WORKDIR}"/${MY_P}
-
-	if [[ ${PV} != *_beta* ]] && ! [[ $(ver_cut 3) =~ [a-z] ]] ; then
+	if ! [[ ${PV} == *_beta* ]] ; then
 		KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 	fi
+	S="${WORKDIR}"/${MY_P}
 fi
 
 inherit toolchain-autoconf
@@ -33,19 +30,26 @@ LICENSE="GPL-3+"
 SLOT="${PV/_*}"
 IUSE="emacs"
 
-BDEPEND="
-	>=dev-lang/perl-5.10
-	>=sys-devel/m4-1.4.16
-"
-RDEPEND="
-	${BDEPEND}
+# for 2.71, our Perl time resolution patch changes our min Perl from 5.6
+# (vanilla upstream for 2.71) to 5.8.
+BDEPEND=">=sys-devel/m4-1.4.16
+	>=dev-lang/perl-5.8"
+RDEPEND="${BDEPEND}
 	>=sys-devel/autoconf-wrapper-15
 	sys-devel/gnuconfig
-	!~sys-devel/${P}:2.5
-"
+	!~sys-devel/${P}:2.5"
 [[ ${PV} == 9999 ]] && BDEPEND+=" >=sys-apps/texinfo-4.3"
 PDEPEND="emacs? ( app-emacs/autoconf-mode )"
 
+PATCHES=(
+	"${FILESDIR}"/${P}-AC_LANG_CALL_C_cxx.patch
+	"${FILESDIR}"/${P}-time.patch
+	"${FILESDIR}"/${P}-AC_C_BIGENDIAN-lto.patch
+	"${FILESDIR}"/${P}-K-R-decls-clang.patch
+	"${FILESDIR}"/${P}-make-4.4.patch
+	"${FILESDIR}"/${P}-K-R-decls-clang-deux.patch
+)
+
 src_prepare() {
 	# usr/bin/libtool is provided by binutils-apple, need gnu libtool
 	if [[ ${CHOST} == *-darwin* ]] ; then

diff --git a/sys-devel/autoconf/autoconf-2.72c.ebuild b/sys-devel/autoconf/autoconf-2.72c-r1.ebuild
similarity index 100%
rename from sys-devel/autoconf/autoconf-2.72c.ebuild
rename to sys-devel/autoconf/autoconf-2.72c-r1.ebuild