[gentoo-commits] repo/gentoo:master commit in: dev-python/pyopenssl/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     89251753288c35587f2ea44d996c87575019e788
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 24 19:00:12 2023 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Mar 24 19:05:54 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=89251753

dev-python/pyopenssl: add 23.1.0

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/pyopenssl/Manifest                |  1 +
 dev-python/pyopenssl/pyopenssl-23.1.0.ebuild | 66 ++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/dev-python/pyopenssl/Manifest b/dev-python/pyopenssl/Manifest
index fdfdbedfa7ec..55d7225ab86a 100644
--- a/dev-python/pyopenssl/Manifest
+++ b/dev-python/pyopenssl/Manifest
@@ -1 +1,2 @@
 DIST pyOpenSSL-23.0.0.tar.gz 182375 BLAKE2B 8a902ecd7e771dcd281dda184569fef53c7f7d1a801f5cea663ff95014717786ceaaa999b6f67fe710ade253335c856c3964a96705afd6ddb93679856d57d7cd SHA512 68c42de58305461606d9fb932a7711775cfcf1a7c5dbe900b2c7ba18eab546d4c37fcd3dd82ab2c18b15eb07bef126534473b5b29f8af4f46e0147d45ac9e64b
+DIST pyOpenSSL-23.1.0.tar.gz 182977 BLAKE2B 75bb5cf215d17a39d2f11a8948c015766d291ae4c4a9d81f03bc634a0d2abbff78d963d382f858f5609cde3e153fa709ee52c9bcccf0fed35f5f00a18cf4b5e0 SHA512 b46b9a4de7ca584f5711089f1a056c479e65e06b9a0868263aa51b3f724d81342cc89fe06c9eb6e8d44fb87e93c7face9643577145d57608ef6162a5be18127b

diff --git a/dev-python/pyopenssl/pyopenssl-23.1.0.ebuild b/dev-python/pyopenssl/pyopenssl-23.1.0.ebuild
new file mode 100644
index 000000000000..0e095e2b825a
--- /dev/null
+++ b/dev-python/pyopenssl/pyopenssl-23.1.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+PYPI_NO_NORMALIZE=1
+PYPI_PN=pyOpenSSL
+
+inherit distutils-r1 toolchain-funcs pypi
+
+DESCRIPTION="Python interface to the OpenSSL library"
+HOMEPAGE="
+	https://www.pyopenssl.org/
+	https://github.com/pyca/pyopenssl/
+	https://pypi.org/project/pyOpenSSL/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/cryptography-41[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-38.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/cffi[${PYTHON_USEDEP}]
+		' 'python*')
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx doc \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_test() {
+	local -x TZ=UTC
+	local EPYTEST_DESELECT=(
+		tests/test_ssl.py::TestContext::test_set_default_verify_paths
+	)
+
+	# test for 32-bit time_t
+	"$(tc-getCC)" ${CFLAGS} ${CPPFLAGS} -c -x c - -o /dev/null <<-EOF &>/dev/null
+		#include <sys/types.h>
+		int test[sizeof(time_t) >= 8 ? 1 : -1];
+	EOF
+
+	if [[ ${?} -eq 0 ]]; then
+		einfo "time_t is at least 64-bit long"
+	else
+		einfo "time_t is smaller than 64 bits, will skip broken tests"
+		EPYTEST_DESELECT+=(
+			tests/test_crypto.py::TestX509StoreContext::test_verify_with_time
+		)
+	fi
+
+	distutils-r1_src_test
+}