[gentoo-commits] repo/gentoo:master commit in: dev-libs/libdex/

["Matt Turner" <mattst88@gentoo.org>]

commit:     bb8a8acd56511a478c8a8285d9b4a970f568e539
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Tue Mar 14 13:53:49 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Mar 20 22:06:29 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bb8a8acd

dev-libs/libdex: New package 0.2.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libdex/Manifest            |  1 +
 dev-libs/libdex/libdex-0.2.0.ebuild | 60 +++++++++++++++++++++++++++++++++++++
 dev-libs/libdex/metadata.xml        | 22 ++++++++++++++
 3 files changed, 83 insertions(+)

diff --git a/dev-libs/libdex/Manifest b/dev-libs/libdex/Manifest
new file mode 100644
index 000000000000..b60b4a63c716
--- /dev/null
+++ b/dev-libs/libdex/Manifest
@@ -0,0 +1 @@
+DIST libdex-0.2.0.tar.xz 91648 BLAKE2B 258193b29082024cce30d5e20903f1ba6a3c8e566652d341845178797126796fcc1cf628636de02ba9776cb9d8ff5d38c24f10f269fcd9acbc0cdbb1c0918d8b SHA512 db54fa974af97e59e7a21c19be73db8fec6565377ce313a3532435845d3571216d6617f9a8db500019390d85677ca6f30be3f9a36c60240c8130ae0834826a65

diff --git a/dev-libs/libdex/libdex-0.2.0.ebuild b/dev-libs/libdex/libdex-0.2.0.ebuild
new file mode 100644
index 000000000000..f0d86d8a55dd
--- /dev/null
+++ b/dev-libs/libdex/libdex-0.2.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala
+
+DESCRIPTION="Deferred Execution library for GNOME and GTK"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libdex"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="gtk-doc +introspection sysprof test vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.68:2
+	>=sys-libs/liburing-0.7:=
+	introspection? ( dev-libs/gobject-introspection:= )
+	sysprof? ( dev-util/sysprof-capture:4 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gi-docgen )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dexamples=false
+		$(meson_use vala vapi)
+		$(meson_feature introspection)
+		-Dsysprof=false
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-1 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}

diff --git a/dev-libs/libdex/metadata.xml b/dev-libs/libdex/metadata.xml
new file mode 100644
index 000000000000..64509955e2ba
--- /dev/null
+++ b/dev-libs/libdex/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>gnome@gentoo.org</email>
+    <name>Gentoo GNOME Desktop</name>
+  </maintainer>
+  <longdescription>
+    Dex is a library supporting "Deferred Execution" with the explicit
+    goal of integrating with GNOME and GTK-based applications.
+    It provides primatives for supporting futures in a variety of ways
+    with both read-only and writable views. Additionally, integration
+    with existing asynchronous-based APIs is provided through the use
+    of wrapper promises.
+  </longdescription>
+  <upstream>
+    <remote-id type="gnome-gitlab">GNOME/libdex</remote-id>
+  </upstream>
+  <use>
+    <flag name="sysprof">Enable profiling data capture support using <pkg>dev-util/sysprof-capture</pkg></flag>
+  </use>
+</pkgmetadata>