[gentoo-commits] repo/gentoo:master commit in: net-wireless/lorcon/

["David Seifert" <soap@gentoo.org>]

commit:     242d5ec7dab26446b124f4d3abf214c6db8019ca
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 19 17:13:56 2023 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Mar 19 17:13:56 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=242d5ec7

net-wireless/lorcon: fix clang16 build

Closes: https://bugs.gentoo.org/843698
Closes: https://bugs.gentoo.org/875401
Closes: https://bugs.gentoo.org/897182
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 ...build => lorcon-2020.06.06_p20220216-r2.ebuild} | 37 ++++++++++------------
 1 file changed, 16 insertions(+), 21 deletions(-)

diff --git a/net-wireless/lorcon/lorcon-2020.06.06_p20220216-r1.ebuild b/net-wireless/lorcon/lorcon-2020.06.06_p20220216-r2.ebuild
similarity index 73%
rename from net-wireless/lorcon/lorcon-2020.06.06_p20220216-r1.ebuild
rename to net-wireless/lorcon/lorcon-2020.06.06_p20220216-r2.ebuild
index 1508abca7594..19a7dbbdd451 100644
--- a/net-wireless/lorcon/lorcon-2020.06.06_p20220216-r1.ebuild
+++ b/net-wireless/lorcon/lorcon-2020.06.06_p20220216-r2.ebuild
@@ -4,71 +4,66 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..10} )
+PYTHON_COMPAT=( python3_{9..11} )
 DISTUTILS_OPTIONAL=1
 
-inherit distutils-r1
+inherit distutils-r1 flag-o-matic
 
 DESCRIPTION="A generic library for injecting 802.11 frames"
 HOMEPAGE="https://github.com/kismetwireless/lorcon"
 
-if [[ ${PV} == "9999" ]] ; then
+if [[ ${PV} == *9999 ]] ; then
 	#main repo
 	#EGIT_REPO_URI="https://www.kismetwireless.net/lorcon.git"
 	#reliable mirror
 	EGIT_REPO_URI="https://github.com/kismetwireless/lorcon.git"
 	inherit git-r3
-	S="${WORKDIR}"/${P}
 else
 	GIT_HASH="4a81d6aaa2c6ac7253ecd182ffe97c6c89411196"
 	SRC_URI="https://github.com/kismetwireless/lorcon/archive/${GIT_HASH}.tar.gz -> ${P}.tar.gz"
 	S="${WORKDIR}"/"${PN}-${GIT_HASH}"
+
 	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86 ~amd64-linux ~x86-linux"
 fi
 
 LICENSE="GPL-2"
 SLOT="0"
 IUSE="python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
 
 RDEPEND="
 	dev-libs/libnl:3=
 	net-libs/libpcap
 	python? ( ${PYTHON_DEPS} )"
 DEPEND="${RDEPEND}"
-BDEPEND="python? ( ${DISTUTILS_DEPS} )"
+BDEPEND="
+	virtual/pkgconfig
+	python? ( ${DISTUTILS_DEPS} )"
 
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-src_unpack() {
-	if [[ ${PV} == "9999" ]] ; then
-		git-r3_src_unpack
-		cp -R "${S}/" "${WORKDIR}/all" || die
-	fi
-	default_src_unpack
-}
+PATCHES=( "${FILESDIR}"/${P}-C99-decls.patch )
 
 src_prepare() {
 	default
 	use python && distutils-r1_src_prepare
 }
 
-src_configure() {
-	econf --disable-static
-}
-
 src_compile() {
-	default_src_compile
+	default
+
 	if use python; then
-		LDFLAGS+=" -L${S}/.libs/"
+		append-ldflags "-L${S}/.libs/"
 		cd pylorcon2 || die
 		distutils-r1_src_compile
 	fi
 }
 
 src_install() {
-	emake DESTDIR="${D}" install
+	default
+
 	if use python; then
 		cd pylorcon2 || die
 		distutils-r1_src_install
 	fi
+
+	find "${ED}" -name '*.la' -delete || die
 }