[gentoo-commits] repo/gentoo:master commit in: media-gfx/eog-plugins/

["Matt Turner" <mattst88@gentoo.org>]

commit:     e78575bc3fa1e79bc2a5db4158226238afb29875
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Sat Mar 18 20:31:22 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Mar 19 03:51:29 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e78575bc

media-gfx/eog-plugins: Version bump to 44.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/30222
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-gfx/eog-plugins/Manifest                |  1 +
 media-gfx/eog-plugins/eog-plugins-44.0.ebuild | 74 +++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/media-gfx/eog-plugins/Manifest b/media-gfx/eog-plugins/Manifest
index 76c022545179..56028714af99 100644
--- a/media-gfx/eog-plugins/Manifest
+++ b/media-gfx/eog-plugins/Manifest
@@ -1 +1,2 @@
 DIST eog-plugins-42.3.tar.xz 134284 BLAKE2B 903ee1af89d48c46ab12d1330b4605cd78db573d59d5fc6ba34c27a8b017ce90c2af0b55009e5ecec61229dbdd8852bc4ecc5b10e6a2d2391c06e8244f7b24da SHA512 af680fe7cc83d3b3ae6782127edf90cf2a89093030f15d22fe5ff81eb165a493dc487b32a41383c36b72ce188c8f49b3f52ca3b991d24faa9667b0317bff414f
+DIST eog-plugins-44.0.tar.xz 134544 BLAKE2B db384d949f2a63cb0fcdf1bdfb8ed4c5c97af88d21079af5de7560b3c3bab231a6361ae459727a9b9f31b49e63f7cd227f465a1a7b8e2bc55e8d7a08f0335ed9 SHA512 2955830aa60a3518869ec1af7a9f0c455277b0a571cb14a5e5926b52b80ed0443e91f28e270feffcf26066e1e9b6080c9a457b55175051c20838c8b80e2da195

diff --git a/media-gfx/eog-plugins/eog-plugins-44.0.ebuild b/media-gfx/eog-plugins/eog-plugins-44.0.ebuild
new file mode 100644
index 000000000000..1a40b2451460
--- /dev/null
+++ b/media-gfx/eog-plugins/eog-plugins-44.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit gnome.org meson python-single-r1
+
+DESCRIPTION="Eye of GNOME plugins"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome/Plugins https://gitlab.gnome.org/GNOME/eog-plugins"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+exif map picasa +python test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	map? ( exif )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.53.4:2
+	>=dev-libs/libpeas-1.14.1
+	>=media-gfx/eog-41.0:1
+	exif? ( >=media-libs/libexif-0.6.16 )
+	map? (
+		media-libs/libchamplain:0.12[gtk]
+		>=media-libs/clutter-1.9.4:1.0
+		>=media-libs/clutter-gtk-1.1.2:1.0
+	)
+	picasa? ( >=dev-libs/libgdata-0.9.1:= )
+	python? (
+		${PYTHON_DEPS}
+		dev-libs/glib[dbus]
+		dev-libs/libpeas:=[gtk,python,${PYTHON_SINGLE_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+		')
+		gnome-base/gsettings-desktop-schemas
+		media-gfx/eog[introspection]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection]
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/appstream-glib )"
+BDEPEND="
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use exif plugin_exif-display)
+		$(meson_use python plugin_export-to-folder)
+		-Dplugin_fit-to-width=true
+		$(meson_use python plugin_fullscreenbg)
+		-Dplugin_light-theme=true
+		$(meson_use map plugin_map)
+		$(meson_use python plugin_maximize-windows)
+		$(meson_use picasa plugin_postasa)
+		-Dplugin_postr=false
+		$(meson_use python plugin_pythonconsole)
+		-Dplugin_send-by-mail=true
+		$(meson_use python plugin_slideshowshuffle)
+	)
+	meson_src_configure
+}