[gentoo-commits] repo/gentoo:master commit in: profiles/, net-misc/gnome-remote-desktop/

["Matt Turner" <mattst88@gentoo.org>]

commit:     f27dfc6dadbb2a836b0bd0cc8d22087cf2cffce4
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Mon Mar 13 22:54:24 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Mar 13 23:21:32 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f27dfc6d

net-misc/gnome-remote-desktop: Version bump to 44_rc

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/30112
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-misc/gnome-remote-desktop/Manifest             |  1 +
 .../gnome-remote-desktop-44_rc.ebuild              | 75 ++++++++++++++++++++++
 profiles/package.mask                              |  1 +
 3 files changed, 77 insertions(+)

diff --git a/net-misc/gnome-remote-desktop/Manifest b/net-misc/gnome-remote-desktop/Manifest
index 01d4bf669477..93cc4ebb8936 100644
--- a/net-misc/gnome-remote-desktop/Manifest
+++ b/net-misc/gnome-remote-desktop/Manifest
@@ -1 +1,2 @@
 DIST gnome-remote-desktop-43.3.tar.xz 196540 BLAKE2B a33dcb830cd5ed0e9c44da8717a7c621231a97a0d503daa007d6d4c47feb83e16905f61a9ebe60ce5231b7fbad035ab24603284f9c9212ccb48dab90cb845a5c SHA512 67dc7c4ab7d2db9ef843e30b688e024ed91341c09fbf4c7d33f4c1d8b7d9d3564fb64bc948b12f2aee3ca8a545fb21842ce79970ec1ddaf99fd64c41a44b8f59
+DIST gnome-remote-desktop-44.rc.tar.xz 199388 BLAKE2B 69ee4ad0cae29eea60a79cce24b5852fdffb524af599e21a4a4963bac6e10fa3cef9c4ed361fc1fb2ebf4954968365288ec6da747e1363b0e0e87e7faeeb138a SHA512 ed33a3add26ada4b8d15d3e0e22cb14ac87c6779c5c7ad89db5ceacae457b4967460a40994c38ebf59b194c23c6d5a94e1b8719ad60d582961091b7ca9ad5ae2

diff --git a/net-misc/gnome-remote-desktop/gnome-remote-desktop-44_rc.ebuild b/net-misc/gnome-remote-desktop/gnome-remote-desktop-44_rc.ebuild
new file mode 100644
index 000000000000..c842fb5d9532
--- /dev/null
+++ b/net-misc/gnome-remote-desktop/gnome-remote-desktop-44_rc.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd xdg
+
+DESCRIPTION="Remote desktop daemon for GNOME using pipewire"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+SRC_URI="https://download.gnome.org/sources/${PN}/44/${PN}-44.rc.tar.xz"
+S="${WORKDIR}/${PN}-44.rc"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="aac doc +rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc ) aac? ( rdp )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	x11-libs/libdrm
+	>=media-libs/libepoxy-1.4
+	>=dev-libs/glib-2.68:2
+	x11-libs/libnotify
+	app-crypt/libsecret
+	>=media-video/pipewire-0.3.49:=
+	app-crypt/tpm2-tss:=
+	rdp? (
+		>=media-libs/nv-codec-headers-11.1.5.0
+		>=net-misc/freerdp-2.10.0:=[server]
+		>=sys-fs/fuse-3.9.1:3
+		>=x11-libs/libxkbcommon-1.0.0
+
+		aac? (
+			media-libs/fdk-aac:=
+		)
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+	doc? (
+		app-text/asciidoc
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc man)
+		$(meson_use aac fdk_aac)
+		$(meson_use rdp)
+		$(meson_use vnc)
+		$(meson_use systemd)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}

diff --git a/profiles/package.mask b/profiles/package.mask
index e8bec345c613..92ba5013ecb8 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -64,6 +64,7 @@ dev-ruby/net-http-persistent:3
 >=gui-libs/libadwaita-1.3_rc
 >=net-libs/glib-networking-2.76_beta
 >=net-misc/gnome-connections-44_rc
+>=net-misc/gnome-remote-desktop-44_rc
 >=sys-apps/xdg-desktop-portal-gnome-44_rc
 >=x11-wm/mutter-44_rc