[gentoo-commits] repo/gentoo:master commit in: media-gfx/shotwell/

["Matt Turner" <mattst88@gentoo.org>]

commit:     f2abd982dbf883988f8a9922dd258c30218f4417
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Mar  5 20:01:53 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Mar  5 20:32:52 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f2abd982

media-gfx/shotwell: Version bump to 0.31.7

This is a development version that I wouldn't normally package, but it
doesn't seem stable versions are forthcoming, and I'm sure users would
appreciate not needing an additional webkit slot if possible.

Bug: https://bugs.gentoo.org/893702
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-gfx/shotwell/Manifest               |  1 +
 media-gfx/shotwell/shotwell-0.31.7.ebuild | 93 +++++++++++++++++++++++++++++++
 2 files changed, 94 insertions(+)

diff --git a/media-gfx/shotwell/Manifest b/media-gfx/shotwell/Manifest
index 8c6c23c5c1dd..ebab828a7044 100644
--- a/media-gfx/shotwell/Manifest
+++ b/media-gfx/shotwell/Manifest
@@ -1 +1,2 @@
 DIST shotwell-0.30.17.tar.xz 6533460 BLAKE2B 58ec94f21bf465dcc19760f40235db7d2ad7d00c214802cd3ad6cfd67cb1088a5999f183c8ae36398e492a1b387e6ea717a9b8d0f31f4ef369e67c10150ae57a SHA512 f680b6f58538fb7b584594d00da7fe997dbc766583a5b5a85943b3df905dbc7192d3e7b5c7b47b6bd1221280995aaba878ea1afff9b042995bf30fbcbce5f7ea
+DIST shotwell-0.31.7.tar.xz 6610144 BLAKE2B b8f69237abb987508f565d5bfd59123fabf2fa1023783362b189da2690a2b72d5908e13c1371097b48db9eddf1b1361b0b92ca1b5e86287dd35b484bbf119593 SHA512 6653cbc2b2147f65d615f6ea879d012e6a5c5b55c9dfcdb8ff9fecf909ee6f5db96ac8124608d8223e0a95ab26508064b9376a293a2bd4fe05a821988400f42e

diff --git a/media-gfx/shotwell/shotwell-0.31.7.ebuild b/media-gfx/shotwell/shotwell-0.31.7.ebuild
new file mode 100644
index 000000000000..2e50785196e9
--- /dev/null
+++ b/media-gfx/shotwell/shotwell-0.31.7.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Open source photo manager for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Shotwell"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~sparc ~x86"
+IUSE="opencv udev"
+
+DEPEND="
+	>=x11-libs/gtk+-3.22.0:3
+	>=dev-libs/glib-2.40.0:2
+	>=dev-libs/libgee-0.8.5:0.8=
+	>=net-libs/webkit-gtk-2.26:4.1
+	net-libs/libsoup:3.0
+	>=dev-libs/json-glib-0.7.6
+	>=dev-libs/libxml2-2.6.32:2
+	x11-libs/gdk-pixbuf:2
+	>=dev-db/sqlite-3.5.9:3
+	>=media-libs/gstreamer-1.20:1.0
+	>=media-libs/gst-plugins-base-1.20:1.0
+	>=media-libs/libgphoto2-2.5:=
+	udev? ( >=dev-libs/libgudev-145:= )
+	>=media-libs/gexiv2-0.12.3
+	>=media-libs/libraw-0.13.2:=
+	>=media-libs/libexif-0.6.16
+	app-crypt/libsecret
+	>=dev-libs/libportal-0.5:=[gtk]
+	media-libs/libwebp:=
+
+	>=app-crypt/gcr-3:0=[gtk]
+	x11-libs/cairo
+	opencv? ( >=media-libs/opencv-4.0.0:= )
+"
+RDEPEND="${DEPEND}
+	media-plugins/gst-plugins-gdkpixbuf:1.0
+	media-plugins/gst-plugins-meta:1.0
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-libs/appstream-glib
+	dev-libs/glib
+	dev-util/gdbus-codegen
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	net-libs/libsoup:3.0[vala]
+	media-libs/gexiv2[vala]
+	app-crypt/gcr:0[vala]
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-gphoto2-Add-missing-cheader-attributes-of-delegate-s.patch
+)
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dunity_support=false
+		# -Dpublishers # In 0.30.2 all get compiled in anyways, even if restricted list, affects only runtime support
+		#trace
+		#measure
+		-Ddupe_detection=true
+		$(meson_use udev)
+		-Dinstall_apport_hook=false
+		$(meson_use opencv face_detection)
+		-Dfatal_warnings=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}