[gentoo-commits] repo/gentoo:master commit in: app-admin/conky/

["Daniel Pielmeier" <billie@gentoo.org>]

commit:     266ac3b2ab222e2425a16920e4e19f37f9990dd6
Author:     Daniel Pielmeier <billie <AT> gentoo <DOT> org>
AuthorDate: Sat Mar  4 17:04:30 2023 +0000
Commit:     Daniel Pielmeier <billie <AT> gentoo <DOT> org>
CommitDate: Sat Mar  4 17:04:30 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=266ac3b2

app-admin/conky: drop 1.15.0

Signed-off-by: Daniel Pielmeier <billie <AT> gentoo.org>

 app-admin/conky/Manifest            |   1 -
 app-admin/conky/conky-1.15.0.ebuild | 210 ------------------------------------
 2 files changed, 211 deletions(-)

diff --git a/app-admin/conky/Manifest b/app-admin/conky/Manifest
index a8c29112c8ee..47ca17eb61b1 100644
--- a/app-admin/conky/Manifest
+++ b/app-admin/conky/Manifest
@@ -1,4 +1,3 @@
 DIST conky-1.13.1.tar.gz 2443276 BLAKE2B e51610172e830d0368e8c9a48ea056285efe48275364c4d0c973da6467ea044303d75f94cc0b963c3b423a7ec61d8eff26da30c102c557ccd5a4e8cf984db4f6 SHA512 3ee0e14f6ff2bac39404c272790055ac1106f47a00e8298da909a0febf6de0661486e8ce23f34e8c5050e364168b2efcefd0b28736cbd0bc135e1362f0dc5516
-DIST conky-1.15.0.tar.gz 1800684 BLAKE2B e3b8c682e99be42cd28ed9507c346f16afefb525269c31bf9731169fa2c52bcaac4f523ecd0ec8c722fb4e269226254f8579876e68a2b27c3a3f5685dd50b423 SHA512 d317b0a141355ce56c9dce5ba6e4b9dbe73b05b9b0b85d93d491f6d6da4194c1aceefbbc7e1b10e5fc233a9732933949e273630845194f6c16dce34a77ee5841
 DIST conky-1.17.0.tar.gz 1699311 BLAKE2B 9aead9e1e9bf4bf61c1b3e09c6e319135ccce19c43740c1bb3c6142c936c2a045820078f4684ea037fc26a8b02343e11b5372f74258fdf2c5386459410498cc9 SHA512 4da55ba3835e8ff42747f2bc01c34a94b2819e08eb74ddb913fd34bf4b682d75331119745ee006d842d3d2142fc53eeada16afdf698a60f37b566f55896aa2db
 DIST conky-1.18.1.tar.gz 1703018 BLAKE2B ba3c0f9624bfcf229de4376a9446ad05285db4241d1caf4a7a8ac92971f57d022192504c9831a786e3c02db140d70f10cf34d7e146c8647cb2a2b923e6acc2cc SHA512 e390d2aa8a3f3b570b2e3dc43ef71ff0001e36f3b42ce5a9c01b8dca656a23b1af80ee2ee138f38b12b4581dd03711562445fb53e23ca0f26e8b8af878aa2ba1

diff --git a/app-admin/conky/conky-1.15.0.ebuild b/app-admin/conky/conky-1.15.0.ebuild
deleted file mode 100644
index 640060b9264d..000000000000
--- a/app-admin/conky/conky-1.15.0.ebuild
+++ /dev/null
@@ -1,210 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( lua5-3 )
-PYTHON_COMPAT=( python{3_9,3_10,3_11} )
-
-inherit cmake linux-info lua-single python-any-r1 readme.gentoo-r1 xdg
-
-DESCRIPTION="An advanced, highly configurable system monitor for X"
-HOMEPAGE="https://github.com/brndnmtthws/conky"
-SRC_URI="https://github.com/brndnmtthws/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-3 BSD LGPL-2.1 MIT"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
-IUSE="apcupsd bundled-toluapp cmus curl doc extras hddtemp ical iconv imlib
-	intel-backlight iostats irc lua-cairo lua-imlib lua-rsvg math moc mpd
-	mysql ncurses nvidia +portmon pulseaudio rss systemd thinkpad truetype
-	webserver wifi X xinerama xmms2"
-
-COMMON_DEPEND="
-	curl? ( net-misc/curl )
-	ical? ( dev-libs/libical:= )
-	iconv? ( virtual/libiconv )
-	imlib? ( media-libs/imlib2[X] )
-	irc? ( net-libs/libircclient )
-	lua-cairo? ( x11-libs/cairo[X] )
-	lua-imlib? ( media-libs/imlib2[X] )
-	lua-rsvg? ( gnome-base/librsvg )
-	mysql? ( dev-db/mysql-connector-c )
-	ncurses? ( sys-libs/ncurses:= )
-	nvidia? ( x11-drivers/nvidia-drivers[tools,static-libs] )
-	pulseaudio? ( media-libs/libpulse )
-	rss? ( dev-libs/libxml2 net-misc/curl dev-libs/glib:2 )
-	systemd? ( sys-apps/systemd )
-	truetype? ( x11-libs/libXft >=media-libs/freetype-2 )
-	wifi? ( net-wireless/wireless-tools )
-	webserver? ( net-libs/libmicrohttpd )
-	X? (
-		x11-libs/libX11
-		x11-libs/libXdamage
-		x11-libs/libXfixes
-		x11-libs/libXext
-	)
-	xinerama? ( x11-libs/libXinerama )
-	xmms2? ( media-sound/xmms2 )
-	${LUA_DEPS}
-"
-RDEPEND="
-	${COMMON_DEPEND}
-	apcupsd? ( sys-power/apcupsd )
-	cmus? ( media-sound/cmus )
-	hddtemp? ( app-admin/hddtemp )
-	moc? ( media-sound/moc )
-	extras? (
-		app-editors/nano
-		|| ( app-editors/vim app-editors/gvim )
-		)
-"
-DEPEND="
-	${COMMON_DEPEND}
-"
-BDEPEND="
-	doc? (
-		virtual/pandoc
-		$(python_gen_any_dep '
-			dev-python/pyyaml[${PYTHON_USEDEP}]
-			dev-python/jinja[${PYTHON_USEDEP}]
-		')
-	)
-	extras? (
-		$(python_gen_any_dep '
-			dev-python/pyyaml[${PYTHON_USEDEP}]
-			dev-python/jinja[${PYTHON_USEDEP}]
-		')
-	)
-"
-
-python_check_deps() {
-	use doc || use extras || return 0
-	python_has_version -b "dev-python/pyyaml[${PYTHON_USEDEP}]" &&
-	python_has_version -b "dev-python/jinja[${PYTHON_USEDEP}]"
-}
-
-REQUIRED_USE="
-	imlib? ( X )
-	lua-cairo? ( X  bundled-toluapp )
-	lua-imlib? ( X  bundled-toluapp )
-	lua-rsvg? ( X  bundled-toluapp )
-	nvidia? ( X )
-	truetype? ( X )
-	xinerama? ( X )
-"
-
-CONFIG_CHECK="~IPV6"
-
-DOCS=( README.md AUTHORS )
-
-DISABLE_AUTOFORMATTING="yes"
-DOC_CONTENTS="You can find sample configurations at ${ROOT}/usr/share/doc/${PF}.
-To customize, copy to \${XDG_CONFIG_HOME}/conky/conky.conf and edit it to your liking.
-
-There are pretty html docs available at https://conky.cc/.
-
-Also see https://github.com/brndnmtthws/conky/wiki or https://wiki.gentoo.org/wiki/Conky"
-
-pkg_setup() {
-	linux-info_pkg_setup
-	lua-single_pkg_setup
-	if use doc || use extras; then
-		python-any-r1_pkg_setup
-	fi
-}
-
-src_prepare() {
-	cmake_src_prepare
-	xdg_environment_reset
-}
-
-src_configure() {
-	local mycmakeargs=()
-
-	if use X; then
-		mycmakeargs+=(
-			-DBUILD_ARGB=yes
-			-DBUILD_X11=yes
-			-DBUILD_XDAMAGE=yes
-			-DBUILD_XDBE=yes
-			-DBUILD_XSHAPE=yes
-			-DOWN_WINDOW=yes
-		)
-	else
-		mycmakeargs+=(
-			-DBUILD_X11=no
-		)
-	fi
-
-	mycmakeargs+=(
-		-DBUILD_APCUPSD=$(usex apcupsd)
-		-DBUILD_AUDACIOUS=no
-		-DBUILD_BUILTIN_CONFIG=yes
-		-DBUILD_CMUS=$(usex cmus)
-		-DBUILD_CURL=$(usex curl)
-		-DBUILD_DOCS=$(usex doc)
-		-DBUILD_EXTRAS=$(usex extras)
-		-DBUILD_HDDTEMP=$(usex hddtemp)
-		-DBUILD_HTTP=$(usex webserver)
-		-DBUILD_I18N=yes
-		-DBUILD_IBM=$(usex thinkpad)
-		-DBUILD_ICAL=$(usex ical)
-		-DBUILD_ICONV=$(usex iconv)
-		-DBUILD_IMLIB2=$(usex imlib)
-		-DBUILD_INTEL_BACKLIGHT=$(usex intel-backlight)
-		-DBUILD_IOSTATS=$(usex iostats)
-		-DBUILD_IPV6=yes
-		-DBUILD_IRC=$(usex irc)
-		-DBUILD_JOURNAL=$(usex systemd)
-		-DBUILD_LUA_CAIRO=$(usex lua-cairo)
-		-DBUILD_LUA_IMLIB2=$(usex lua-imlib)
-		-DBUILD_LUA_RSVG=$(usex lua-rsvg)
-		-DBUILD_MATH=$(usex math)
-		-DBUILD_MOC=$(usex moc)
-		-DBUILD_MPD=$(usex mpd)
-		-DBUILD_MYSQL=$(usex mysql)
-		-DBUILD_NCURSES=$(usex ncurses)
-		-DBUILD_NVIDIA=$(usex nvidia)
-		-DBUILD_OLD_CONFIG=yes
-		-DBUILD_PORT_MONITORS=$(usex portmon)
-		-DBUILD_PULSEAUDIO=$(usex pulseaudio)
-		-DBUILD_RSS=$(usex rss)
-		-DBUILD_WLAN=$(usex wifi)
-		-DBUILD_XFT=$(usex truetype)
-		-DBUILD_XINERAMA=$(usex xinerama)
-		-DBUILD_XMMS2=$(usex xmms2)
-		-DDOC_PATH=/usr/share/doc/${PF}
-		-DMAINTAINER_MODE=no
-		-DRELEASE=yes
-	)
-
-	if use doc || use extras; then
-		mycmakeargs+=( -DPython3_EXECUTABLE="${PYTHON}" )
-	fi
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	if use extras; then
-		insinto /usr/share/vim/vimfiles/ftdetect
-		doins "${S}"/extras/vim/ftdetect/conkyrc.vim
-
-		insinto /usr/share/vim/vimfiles/syntax
-		doins "${BUILD_DIR}"/extras/vim/syntax/conkyrc.vim
-
-		insinto /usr/share/nano/
-		doins "${BUILD_DIR}"/extras/nano/conky.nanorc
-	fi
-
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	readme.gentoo_print_elog
-
-	xdg_pkg_postinst
-}