[gentoo-commits] repo/gentoo:master commit in: dev-embedded/dfu-programmer/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     8b3c6321d7ffd649bc521f46be393515756cef11
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Thu Mar  2 18:34:58 2023 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Thu Mar  2 18:54:11 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8b3c6321

dev-embedded/dfu-programmer: drop 0.7.2-r2

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 .../dfu-programmer/dfu-programmer-0.7.2-r2.ebuild  | 59 ----------------------
 1 file changed, 59 deletions(-)

diff --git a/dev-embedded/dfu-programmer/dfu-programmer-0.7.2-r2.ebuild b/dev-embedded/dfu-programmer/dfu-programmer-0.7.2-r2.ebuild
deleted file mode 100644
index 226ed4cd05d2..000000000000
--- a/dev-embedded/dfu-programmer/dfu-programmer-0.7.2-r2.ebuild
+++ /dev/null
@@ -1,59 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit toolchain-funcs udev
-
-DESCRIPTION="A Device Firmware Update based USB programmer for Atmel chips"
-HOMEPAGE="https://dfu-programmer.github.io/ https://sourceforge.net/projects/dfu-programmer/"
-
-SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64"
-
-RDEPEND="
-	acct-group/plugdev
-	virtual/libusb:1
-	virtual/udev"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
-
-src_prepare() {
-	default
-
-	# Upstream has fixed this in their configure already.
-	tc-export CPP PKG_CONFIG
-	sed -i \
-		-e "/LIBUSB_1_0_CFLAGS=/s:=.*:='$(${PKG_CONFIG} --cflags libusb-1.0)':" \
-		-e "/LIBUSB_1_0_LIBS=/s:=.*:='$(${PKG_CONFIG} --libs libusb-1.0)':" \
-		configure || die
-}
-
-src_install() {
-	default
-
-	cat <<-EOF > 70-dfu-programmer.rules
-	#
-	# do not edit this file, it will be overwritten on update
-	#
-	EOF
-	printf 'SUBSYSTEM=="usb", ACTION=="add", ATTRS{idVendor}=="03eb", ATTRS{idProduct}=="%s", MODE="660", GROUP="plugdev", SYMLINK+="dfu-%%n"\n' \
-		2ff{a,b,9,7,4,3} >> 70-dfu-programmer.rules
-
-	udev_dorules 70-dfu-programmer.rules
-}
-
-pkg_postinst() {
-	udev_reload
-
-	elog "To update device firmware as user you must be in the plugdev group:"
-	elog
-	elog "usermod -aG plugdev <user>"
-}
-
-pkg_postrm() {
-	udev_reload
-}