[gentoo-commits] repo/proj/guru:master commit in: app-misc/fastfetch/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     6933498865af71b27f02e27bcc1c3575aa63361e
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 27 17:47:49 2023 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Mon Feb 27 17:47:49 2023 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=69334988

app-misc/fastfetch: drop 1.10.2

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 app-misc/fastfetch/Manifest                |   1 -
 app-misc/fastfetch/fastfetch-1.10.2.ebuild | 102 -----------------------------
 2 files changed, 103 deletions(-)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 6ee3c722c..3b51cfd66 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,3 +1,2 @@
-DIST fastfetch-1.10.2.tar.gz 526649 BLAKE2B 23518c8cfbfd7923f1d960aef306acf8a40ef2e3ccea504646c4cdd82bb8a7660e6471668f3f933e87342a68428bcc16398c324a0548c21ea5437e0d09d1a36c SHA512 f683c4ca7d9ffaae05a881efdb003c0a6e238ba9ecfaefa5e315c4c7f620fefcd5fc8ebbf46617b0cd2abab77d9b72fc62fb3827a567de00c3a62df6410dda06
 DIST fastfetch-1.10.3.tar.gz 528112 BLAKE2B b270354b8f0772fb70ea7aa224f4d1d5e46386f419f32460b93a589f1af59ab6e1e6b48cfaa148bb2774e7a51503cf42506f57acbbe1eb9a64452d33cc01c7d5 SHA512 4ce2c1ef9c5481ef1548d741c902125125a428a1b577762e1f47ad7c5bbbda14dd080dbad114151e9a5d03c1695761e91d3a3bb70924da79a2d888b5160e8e3d
 DIST fastfetch-1.9.1.tar.gz 510560 BLAKE2B 086f743a0e9ec09a3222d9c9951e26449dde90d00fb297d96611393bf23ab6eb8df255e9519b35904d73faa726ea83f673c5ea977a9f2b7f0689de898b0683ba SHA512 9b449aa3b5072d2f7b7857d7a11e315dbb7d4148e2761487e6682980e53bb3acf3ccd14b57bf9d788288a931f8aa940b699f07b1a09673fee53d70f63b081f83

diff --git a/app-misc/fastfetch/fastfetch-1.10.2.ebuild b/app-misc/fastfetch/fastfetch-1.10.2.ebuild
deleted file mode 100644
index c60289caf..000000000
--- a/app-misc/fastfetch/fastfetch-1.10.2.ebuild
+++ /dev/null
@@ -1,102 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake flag-o-matic
-
-DESCRIPTION="Fast system information tool"
-HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
-if [[ ${PV} == *9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
-	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
-	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
-	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
-else
-	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64"
-fi
-
-LICENSE="MIT"
-SLOT="0"
-IUSE="X chafa dbus gnome imagemagick networkmanager opencl opengl osmesa pci pulseaudio sqlite vulkan wayland xcb xfce xrandr"
-
-# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
-RDEPEND="
-	sys-libs/zlib
-	X? ( x11-libs/libX11 )
-	chafa? ( media-gfx/chafa )
-	dbus? ( sys-apps/dbus )
-	gnome? (
-		dev-libs/glib
-		gnome-base/dconf
-	)
-	imagemagick? ( media-gfx/imagemagick:= )
-	networkmanager? ( net-misc/networkmanager )
-	opencl? ( virtual/opencl )
-	opengl? ( media-libs/libglvnd[X] )
-	osmesa? ( media-libs/mesa[osmesa] )
-	pci? ( sys-apps/pciutils )
-	pulseaudio? ( media-libs/libpulse )
-	sqlite? ( dev-db/sqlite:3 )
-	vulkan? ( media-libs/vulkan-loader )
-	wayland? ( dev-libs/wayland )
-	xcb? ( x11-libs/libxcb )
-	xfce? ( xfce-base/xfconf )
-	xrandr? ( x11-libs/libXrandr )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="virtual/pkgconfig"
-
-REQUIRED_USE="
-	xrandr? ( X )
-	chafa? ( imagemagick )
-"
-
-src_configure() {
-	local fastfetch_enable_imagemagick7=no
-	local fastfetch_enable_imagemagick6=no
-	if use imagemagick; then
-		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
-		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
-	fi
-
-	local mycmakeargs=(
-		-DENABLE_LIBCJSON=no
-		-DENABLE_RPM=no
-		-DENABLE_ZLIB=yes
-
-		-DENABLE_CHAFA=$(usex chafa)
-		-DENABLE_DBUS=$(usex dbus)
-		-DENABLE_DCONF=$(usex gnome)
-		-DENABLE_EGL=$(usex opengl)
-		-DENABLE_GIO=$(usex gnome)
-		-DENABLE_GLX=$(usex opengl)
-		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
-		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
-		-DENABLE_LIBNM=$(usex networkmanager)
-		-DENABLE_LIBPCI=$(usex pci)
-		-DENABLE_OPENCL=$(usex opencl)
-		-DENABLE_OSMESA=$(usex osmesa)
-		-DENABLE_PULSE=$(usex pulseaudio)
-		-DENABLE_SQLITE3=$(usex sqlite)
-		-DENABLE_VULKAN=$(usex vulkan)
-		-DENABLE_WAYLAND=$(usex wayland)
-		-DENABLE_X11=$(usex X)
-		-DENABLE_XCB=$(usex xcb)
-		-DENABLE_XCB_RANDR=$(usex xcb)
-		-DENABLE_XFCONF=$(usex xfce)
-		-DENABLE_XRANDR=$(usex xrandr)
-	)
-
-	append-cppflags -DNDEBUG
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	rm -r "${ED}"/usr/share/licenses || die
-}