[gentoo-commits] repo/gentoo:master commit in: dev-python/pyacoustid/

["Sam James" <sam@gentoo.org>]

commit:     f707f65b608446281aa1d7201709530828f98ded
Author:     Petr Vaněk <arkamar <AT> atlas <DOT> cz>
AuthorDate: Tue Feb 21 16:07:05 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Feb 22 12:31:22 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f707f65b

dev-python/pyacoustid: enable py3.11

- python 3.11 enabled
- add network restricted test with a random song under CC-BB-SA license
- dev-python/audioread needs to enable ffmpeg use in order to make the
  test work properly

Signed-off-by: Petr Vaněk <arkamar <AT> atlas.cz>
Closes: https://github.com/gentoo/gentoo/pull/29718
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/pyacoustid/Manifest                   |  1 +
 dev-python/pyacoustid/pyacoustid-1.2.2-r1.ebuild | 48 ++++++++++++++++++++++++
 2 files changed, 49 insertions(+)

diff --git a/dev-python/pyacoustid/Manifest b/dev-python/pyacoustid/Manifest
index 6fb5e78771ed..0be135d373c9 100644
--- a/dev-python/pyacoustid/Manifest
+++ b/dev-python/pyacoustid/Manifest
@@ -1 +1,2 @@
 DIST pyacoustid-1.2.2.tar.gz 15869 BLAKE2B 01f327dd640819dd799f48b32e859fe39dccda3fd62714bf324c8219cf7053b36f1399793523634e9d4f3c6405bed5050abb34bdf53c72ff0ee22708fb57225a SHA512 5bcb3f017c3013eb8fc9e335540a1f5e6a52fc2fefa53d5ef246ba16e4ff615dd1d1cf08b5c80b1a38b149e0fa7dc0b15e4890dcc3f5478ef874b4ec22cf0813
+DIST pyacoustid-test.mp3 4507187 BLAKE2B 54494d9f23481f9d1ee77b136ac3e1790e9fb78c782159ad1793dbebf18f694e13f6413a8259bae84c789f73ea8241e590dbd7e30ccb7377b2afa946335da19b SHA512 faa582640e759322d4bd58d85f4aa7d3ef88fd90aa3c67c1390ba6d4c3213278c11fb60c8d6c87a25e82dffcc54986caa4f0e463acfbcd90993166577e5226d8

diff --git a/dev-python/pyacoustid/pyacoustid-1.2.2-r1.ebuild b/dev-python/pyacoustid/pyacoustid-1.2.2-r1.ebuild
new file mode 100644
index 000000000000..0b0c3a8fd45f
--- /dev/null
+++ b/dev-python/pyacoustid/pyacoustid-1.2.2-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for Chromaprint and the AcoustID web service"
+HOMEPAGE="https://pypi.org/project/pyacoustid/"
+SRC_URI="
+	mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	test? (
+		https://s3.wasabisys.com/blocsonic/releases/maxblocs/bsmx0198/01-Follow_192kb.mp3
+			-> ${PN}-test.mp3
+	)
+"
+
+LICENSE="MIT test? ( CC-BY-SA-4.0 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+
+# Tests fail with network-sandbox, since they need to connect to acoustid.org
+PROPERTIES="test_network"
+RESTRICT="test"
+
+RDEPEND="
+	dev-python/audioread[${PYTHON_USEDEP},ffmpeg]
+	dev-python/requests[${PYTHON_USEDEP}]
+	media-libs/chromaprint
+"
+
+python_test() {
+	# Working test will print the top metadata match from Acoustid's database.
+	"${EPYTHON}" aidmatch.py "${DISTDIR}/${PN}-test.mp3" || die "Test failed with ${EPYTHON}"
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	if use examples ; then
+		docinto examples
+		dodoc aidmatch.py fpcalc.py
+		docompress -x /usr/share/doc/${PF}/examples/
+	fi
+}