[gentoo-commits] repo/proj/guru:master commit in: app-misc/fastfetch/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     0cdfb252363dd46752c0fd2091b77f2f2b7bc28a
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 22 06:27:51 2023 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Wed Feb 22 06:27:51 2023 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=0cdfb252

app-misc/fastfetch: add 1.10.1

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 app-misc/fastfetch/Manifest                |   1 +
 app-misc/fastfetch/fastfetch-1.10.1.ebuild | 102 +++++++++++++++++++++++++++++
 2 files changed, 103 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 4a4c3458a..7b030d2a8 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,2 +1,3 @@
+DIST fastfetch-1.10.1.tar.gz 526593 BLAKE2B f64832bc8f1937eae352e47e9448ad5be7aa30c7c583590d591840cb718d3aa4bdabe3ce49ef5401a930a144dd64ba5d37503ba13aad8b37b8d4c6088494671b SHA512 83fbddaf87095d35ee19c3527a65fe942a08e16ebc6838331336c2d06683e8385d6c2f0ff3080c2a529590614e18a8cc2ef74fa0fc7065a86f7a7b65716fc026
 DIST fastfetch-1.8.2.tar.gz 495971 BLAKE2B e490323b2a18c2cc6a17569955fde820584a4b1e547ad18162b1cbb6f72c61cf8e891c4d1ed56c89f78ac0bc3d5769603e1dfc61c32bad07985c0df27cdf5e10 SHA512 cad6e1f69fd9192e63a55478ee6abe1f0a72c1d4af645d2b8fc1e56fc90eda80f62b5da7a87744ba1a668e5f0b785aac0e49be90867d3b61c674cf455cf984c0
 DIST fastfetch-1.9.1.tar.gz 510560 BLAKE2B 086f743a0e9ec09a3222d9c9951e26449dde90d00fb297d96611393bf23ab6eb8df255e9519b35904d73faa726ea83f673c5ea977a9f2b7f0689de898b0683ba SHA512 9b449aa3b5072d2f7b7857d7a11e315dbb7d4148e2761487e6682980e53bb3acf3ccd14b57bf9d788288a931f8aa940b699f07b1a09673fee53d70f63b081f83

diff --git a/app-misc/fastfetch/fastfetch-1.10.1.ebuild b/app-misc/fastfetch/fastfetch-1.10.1.ebuild
new file mode 100644
index 000000000..c60289caf
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-1.10.1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast system information tool"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus gnome imagemagick networkmanager opencl opengl osmesa pci pulseaudio sqlite vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	networkmanager? ( net-misc/networkmanager )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_LIBCJSON=no
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LIBNM=$(usex networkmanager)
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	rm -r "${ED}"/usr/share/licenses || die
+}