[gentoo-commits] repo/gentoo:master commit in: dev-python/symengine/

["Sam James" <sam@gentoo.org>]

commit:     178a02a99ce506fc6bd7046ec501f69df90f0656
Author:     Jérôme Carretero <cJ-gentoo <AT> zougloub <DOT> eu>
AuthorDate: Thu Feb 16 09:33:10 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Feb 18 00:40:18 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=178a02a9

dev-python/symengine: add python3.11 to PYTHON_COMPAT

CI-tested:
https://github.com/symengine/symengine.py/blob/master/.github/workflows/ci.yml#L11
Signed-off-by: Jérôme Carretero <cJ-gentoo <AT> zougloub.eu>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/symengine/symengine-0.9.2-r2.ebuild | 56 ++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/dev-python/symengine/symengine-0.9.2-r2.ebuild b/dev-python/symengine/symengine-0.9.2-r2.ebuild
new file mode 100644
index 000000000000..d0dc5ac3c521
--- /dev/null
+++ b/dev-python/symengine/symengine-0.9.2-r2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+MY_P=${PN}.py-${PV}
+DESCRIPTION="Python wrappers to the symengine C++ library"
+HOMEPAGE="https://github.com/symengine/symengine.py/"
+SRC_URI="
+	https://github.com/symengine/symengine.py/archive/v${PV}.tar.gz
+		-> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+BDEPEND="
+	dev-util/cmake
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/sympy[${PYTHON_USEDEP}]
+	)
+"
+# See bug #786582 for symengine constraint
+# See also https://github.com/symengine/symengine.py/blob/master/symengine_version.txt
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=sci-libs/symengine-$(ver_cut 1-2):=
+"
+DEPEND="${RDEPEND}"
+
+# the C library installs the same docs
+DOCS=()
+
+PATCHES=(
+	"${FILESDIR}"/${P}-setuptools-61.patch
+	"${FILESDIR}"/${PN}-0.9.2-cmake-setuptools.patch
+)
+
+distutils_enable_tests pytest
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	epytest
+}
+
+python_install() {
+	distutils-r1_python_install
+	python_optimize
+}