[gentoo-commits] repo/gentoo:master commit in: net-libs/davix/

["Guilherme Amadio" <amadio@gentoo.org>]

commit:     1a48f61a3ba2e4fec02d68180db5fcceb9643b36
Author:     Guilherme Amadio <amadio <AT> gentoo <DOT> org>
AuthorDate: Wed Feb  8 10:51:33 2023 +0000
Commit:     Guilherme Amadio <amadio <AT> gentoo <DOT> org>
CommitDate: Wed Feb  8 10:57:19 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1a48f61a

net-libs/davix: version bump to 0.8.4

Signed-off-by: Guilherme Amadio <amadio <AT> gentoo.org>

 net-libs/davix/Manifest           |  1 +
 net-libs/davix/davix-0.8.4.ebuild | 85 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+)

diff --git a/net-libs/davix/Manifest b/net-libs/davix/Manifest
index 1311cb200d7d..bdebbe9ffc7b 100644
--- a/net-libs/davix/Manifest
+++ b/net-libs/davix/Manifest
@@ -1 +1,2 @@
 DIST davix-0.8.3.tar.gz 7615016 BLAKE2B 7bb9ba6e267439db0f8b42d2a2b48ded801e3a10d6443101918514f999922e9cabce485b7a666ee0c1fb60d18cd537aa76b93096eeb0445b5ce4b25e214496d4 SHA512 ce5c66e8d59710e5658a6bb9bebdce3749843ab672274171f936cc533ce42689e1f75454de2a71529df97eb182d996c4ade00f30e1b21891fbfe4a40b1dd2dc5
+DIST davix-0.8.4.tar.gz 7616367 BLAKE2B 0048d066b5ebae0639ea511dfb9147a5c76b73e5f273e0912abd7a10c40228bbbc60fea56f1b91a1c64b396b5ab67a291b42743e037e1e61a14aee2fbb783e09 SHA512 09a0389788b525e3c29639091c11ab4dacf1668efec42a93f3e995663793467b7aaf43daf66351e8a140f760711e96391c1cce0759a7f198110ebe511c0c7a4d

diff --git a/net-libs/davix/davix-0.8.4.ebuild b/net-libs/davix/davix-0.8.4.ebuild
new file mode 100644
index 000000000000..1e98f134e369
--- /dev/null
+++ b/net-libs/davix/davix-0.8.4.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake python-any-r1
+
+DESCRIPTION="High-performance file management over WebDAV/HTTP"
+HOMEPAGE="https://github.com/cern-fts/davix"
+SRC_URI="https://github.com/cern-fts/${PN}/releases/download/R_${PV//./_}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test tools"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+		dev-libs/libxml2:2=
+		dev-libs/openssl:0=
+		net-libs/gsoap[ssl,-gnutls]
+		net-misc/curl:0=
+		kernel_linux? ( sys-apps/util-linux )
+"
+
+DEPEND="${CDEPEND}"
+BDEPEND="
+		doc? (
+			app-doc/doxygen[dot]
+			dev-python/sphinx
+		)
+		virtual/pkgconfig
+		${PYTHON_DEPS}
+"
+
+RDEPEND="${CDEPEND}"
+
+REQUIRED_USE="test? ( tools )"
+
+src_prepare() {
+	cmake_src_prepare
+
+	for x in doc test; do
+		if ! use $x; then
+			sed -i -e "/add_subdirectory ($x)/d" CMakeLists.txt
+		fi
+	done
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DDOC_INSTALL_DIR="${EPREFIX}/usr/share/doc/${P}"
+		-DEMBEDDED_LIBCURL=OFF
+		-DLIBCURL_BACKEND_BY_DEFAULT=OFF
+		-DENABLE_HTML_DOCS=$(usex doc)
+		-DENABLE_IPV6=TRUE
+		-DENABLE_TCP_NODELAY=TRUE
+		-DENABLE_THIRD_PARTY_COPY=TRUE
+		-DENABLE_TOOLS=$(usex tools)
+		-DHTML_INSTALL_DIR="${EPREFIX}/usr/share/doc/${P}/html"
+		-DSOUND_INSTALL_DIR="${EPREFIX}/usr/share/${PN}/sounds"
+		-DSTATIC_LIBRARY=OFF
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}/etc"
+		-DBUILD_TESTING=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	if use doc; then
+		cmake_src_compile doc
+	fi
+}
+
+src_install() {
+	cmake_src_install
+	if use test; then
+		rm "${ED}/usr/bin/davix-unit-tests" || die
+		rm "${ED}/usr/bin/davix-tester" || die
+	fi
+}