[gentoo-commits] repo/gentoo:master commit in: games-strategy/naev/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     2cfae874d59de7db9d30715077e5529b652a2703
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Sun Feb  5 12:05:45 2023 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Sun Feb  5 12:09:37 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2cfae874

games-strategy/naev: add 0.10.4

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-strategy/naev/Manifest           |   1 +
 games-strategy/naev/naev-0.10.4.ebuild | 105 +++++++++++++++++++++++++++++++++
 2 files changed, 106 insertions(+)

diff --git a/games-strategy/naev/Manifest b/games-strategy/naev/Manifest
index f5d75324a445..5f31302ef7fc 100644
--- a/games-strategy/naev/Manifest
+++ b/games-strategy/naev/Manifest
@@ -1 +1,2 @@
 DIST naev-0.10.3-source.tar.xz 444825304 BLAKE2B ec38f7a9786041cc00cf5a515a7e33f8a8fe17b8de6550f896c546f5463d9764f0e287ccea48a0831c6247de31509fc50893ae2ce49711ffe69909f705b0a75a SHA512 7491c61bae446aa98f3847be8719cf822955d3cd0a1b01e4a0d55d49a58628ec07f4872140b3fc77b6c1a928da9d4c8b112a2814ae3ce7edfcc98841f6812a59
+DIST naev-0.10.4-source.tar.xz 444932700 BLAKE2B 998eec9fbcc8dfd16cf8513fdb3c845fa1d509caf7fbe1e6f70b1f5c08cbf142bba3c0303858286c51450dccc329a3950ee146e5f5a383de66f8ae37bc6f7546 SHA512 bd0167ebc43db77237cd833f77d2620f24eba46cab21295568ece6a6dbf4db904fab3849d019308487545d1cbed3aa409fb867946adfdf3113d79f93acc07935

diff --git a/games-strategy/naev/naev-0.10.4.ebuild b/games-strategy/naev/naev-0.10.4.ebuild
new file mode 100644
index 000000000000..49ade5da0d5e
--- /dev/null
+++ b/games-strategy/naev/naev-0.10.4.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{9..11} )
+inherit lua-single meson python-any-r1 virtualx xdg
+
+DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
+HOMEPAGE="https://naev.org/"
+SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
+
+LICENSE="
+	GPL-3+
+	Apache-2.0 BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0
+	CC-BY-SA-4.0 CC0-1.0 GPL-2+ MIT OFL-1.1 public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+# dlopen: libglvnd
+RDEPEND="
+	${LUA_DEPS}
+	dev-games/physfs
+	dev-libs/libpcre2:=
+	dev-libs/libunibreak:=
+	dev-libs/libxml2
+	media-libs/freetype:2
+	media-libs/libglvnd
+	media-libs/libsdl2[joystick,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	media-libs/sdl2-image[png,webp]
+	net-libs/enet:1.3=
+	sci-libs/cholmod
+	sci-libs/cxsparse
+	sci-libs/openblas
+	sci-libs/suitesparse
+	sci-mathematics/glpk:=
+	virtual/libintl"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-games/physfs[zip]
+		media-libs/libsdl2[X]
+		media-libs/mesa[llvm]
+	)"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	sys-devel/gettext
+	doc? (
+		app-doc/doxygen
+		dev-lua/ldoc
+		media-gfx/graphviz
+	)
+	test? ( x11-base/xorg-server[-minimal] )"
+
+python_check_deps() {
+	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# use eclass' generated lua.pc first rather than as fallback
+	sed -i "s/'lua51'/'lua'/" meson.build || die
+
+	# don't probe OpenGL for tests (avoids sandbox violations, bug #829369),
+	# mesa[llvm] should ensure software rendering will work
+	sed -i "/subdir('glcheck')/d" test/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature doc docs_c)
+		$(meson_feature doc docs_lua)
+		$(meson_feature lua_single_target_luajit luajit)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	local DOCS=( CHANGELOG Readme.md )
+	meson_src_install
+
+	if use doc; then
+		dodir /usr/share/doc/${PF}/html
+		mv "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}/html} || die
+		rm -r "${ED}"/usr/doc || die
+	fi
+
+	rm -r "${ED}"/usr/share/doc/naev || die
+}