[gentoo-commits] repo/gentoo:master commit in: dev-python/pdm-pep517/

["Michał Górny" <mgorny@gentoo.org>]

commit:     91f705d8513d66a69255bce6e588834c375ad1ee
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 30 06:50:32 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jan 30 06:58:55 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=91f705d8

dev-python/pdm-pep517: Bump to 1.1.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pdm-pep517/Manifest                |  1 +
 dev-python/pdm-pep517/metadata.xml            |  2 +-
 dev-python/pdm-pep517/pdm-pep517-1.1.0.ebuild | 63 +++++++++++++++++++++++++++
 3 files changed, 65 insertions(+), 1 deletion(-)

diff --git a/dev-python/pdm-pep517/Manifest b/dev-python/pdm-pep517/Manifest
index e966bb484bf9..9f8c051dde70 100644
--- a/dev-python/pdm-pep517/Manifest
+++ b/dev-python/pdm-pep517/Manifest
@@ -1 +1,2 @@
 DIST pdm-pep517-1.0.6.gh.tar.gz 315755 BLAKE2B 7b221d9ddc9683521e901177cafd2ffd2908af4acbe083b4a7d6525a81ece64d3768331135451d45ffc5c40c67c8c72802d75d52fdf85fa89a13f30110436a13 SHA512 5aeef3179d508d2acaedf4b99df41e64b26537120e586a01870651d2b379e2e5a1bf42934ee28a4b285cb83fe10ead073408b6b7d022ca1f55653533d12a2da1
+DIST pdm-pep517-1.1.0.gh.tar.gz 315971 BLAKE2B 679cdd14633a5d745be4dcb215986386464dbdcc91a69a7aaec4910cca7a6c1f65dab8e1a4710715873fae9b0fd07732e8df8a4859155864df330bfda7bfd120 SHA512 b12eeaf294556cdf79e4dc5bfd1d0dc57df64ed632ae678b00452f62b6d48eaf8b7f9437a8f7eec9ecc779d4da3155f3c4923fcdba814cbd1a4575e8f79cecd4

diff --git a/dev-python/pdm-pep517/metadata.xml b/dev-python/pdm-pep517/metadata.xml
index f00d2775021c..8de62c6cc043 100644
--- a/dev-python/pdm-pep517/metadata.xml
+++ b/dev-python/pdm-pep517/metadata.xml
@@ -8,6 +8,6 @@
 	<stabilize-allarches/>
 	<upstream>
 		<remote-id type="pypi">pdm-pep517</remote-id>
-		<remote-id type="github">pdm-project/pdm-pep517</remote-id>
+		<remote-id type="github">pdm-project/pdm-backend</remote-id>
 	</upstream>
 </pkgmetadata>

diff --git a/dev-python/pdm-pep517/pdm-pep517-1.1.0.ebuild b/dev-python/pdm-pep517/pdm-pep517-1.1.0.ebuild
new file mode 100644
index 000000000000..438b25782acb
--- /dev/null
+++ b/dev-python/pdm-pep517/pdm-pep517-1.1.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+
+inherit distutils-r1
+
+# upstream has renamed the repo but the legacy branch is still published
+# as pdm-pep517, sigh
+MY_P=pdm-backend-${PV}
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-pep517/
+	https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/cerberus-1.3.4[${PYTHON_USEDEP}]
+	dev-python/license-expression[${PYTHON_USEDEP}]
+	=dev-python/packaging-21*[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r pdm/pep517/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.pep517\._vendor\.:from :' \
+		-e 's:from pdm\.pep517\._vendor ::' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}