From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1480388-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (2048 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 068AC15800F
	for <garchives@archives.gentoo.org>; Wed, 25 Jan 2023 07:27:25 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 281E6E0837;
	Wed, 25 Jan 2023 07:27:24 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 04FFAE0837
	for <gentoo-commits@lists.gentoo.org>; Wed, 25 Jan 2023 07:27:23 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id D966E340F37
	for <gentoo-commits@lists.gentoo.org>; Wed, 25 Jan 2023 07:27:22 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id E408F84D
	for <gentoo-commits@lists.gentoo.org>; Wed, 25 Jan 2023 07:27:20 +0000 (UTC)
From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Sam James" <sam@gentoo.org>
Message-ID: <1674631493.4e7ca24041bb819e4451ab2d76752b4f47f8b82b.sam@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-print/cups-filters/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-print/cups-filters/Manifest net-print/cups-filters/cups-filters-1.28.17.ebuild
X-VCS-Directories: net-print/cups-filters/
X-VCS-Committer: sam
X-VCS-Committer-Name: Sam James
X-VCS-Revision: 4e7ca24041bb819e4451ab2d76752b4f47f8b82b
X-VCS-Branch: master
Date: Wed, 25 Jan 2023 07:27:20 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 12b1c07f-22b8-430f-b328-c6a5a9f9b7a5
X-Archives-Hash: cb511b1e058b87574548176e63f0b629

commit:     4e7ca24041bb819e4451ab2d76752b4f47f8b82b
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 25 07:24:53 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Jan 25 07:24:53 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4e7ca240

net-print/cups-filters: add 1.28.17

Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-print/cups-filters/Manifest                    |   1 +
 net-print/cups-filters/cups-filters-1.28.17.ebuild | 147 +++++++++++++++++++++
 2 files changed, 148 insertions(+)

diff --git a/net-print/cups-filters/Manifest b/net-print/cups-filters/Manifest
index a80d54825f57..c6150090acd5 100644
--- a/net-print/cups-filters/Manifest
+++ b/net-print/cups-filters/Manifest
@@ -1,2 +1,3 @@
 DIST cups-filters-1.28.15.tar.xz 1511452 BLAKE2B 2ed495f063197955456c07c6c06747093997afce53c15e19d081f2e53e6af9a76a41094d2356a1cd7533c3bb63bfb6257792b71ee14121a0daf5863b3b5cd76f SHA512 cc8d43bba6edb2b839f3be5fcbcdeb7633ed0f0f0c2737bcc6957cf95fb4ded8ee412358cc95fdbf289ae897dd0b7f32e689f02d191a8f15930eb4d2deefd74c
 DIST cups-filters-1.28.16.tar.xz 1512496 BLAKE2B a75a9e09688670332a9fd9a8e4d9004650c6b0fb571a1f48a02e8e4af56d08b7d312d65fdbd66caf82907005dd336de90e2c8bbb46b1ba13d86d8715340f8ce6 SHA512 0369f96a8ae5e33bf75c8765947d5ad7285b3532e9d9b0ded7e206798834c9ade3a2ac3f1d16e0fdd43346f2bc7852c541130e935cbb20f9c1239a53118d1239
+DIST cups-filters-1.28.17.tar.xz 1516052 BLAKE2B 87258391901d55d9e59b06d54603d014e54d224a373529bd70fcd38cded9dc96c88ca73bcea63d7633c065caea3f9e3274cd450aec5f1bd90130d9a88c0d3421 SHA512 320544a48206165581adafb28dbef58f39c66bebd3641be3d180a692605349d9e6af6d464044db9f7bda17a67f4a079370d8cc880cd7873d684b2209882deb35

diff --git a/net-print/cups-filters/cups-filters-1.28.17.ebuild b/net-print/cups-filters/cups-filters-1.28.17.ebuild
new file mode 100644
index 000000000000..343170ff2a30
--- /dev/null
+++ b/net-print/cups-filters/cups-filters-1.28.17.ebuild
@@ -0,0 +1,147 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GENTOO_DEPEND_ON_PERL=no
+inherit perl-module systemd flag-o-matic
+
+DESCRIPTION="Cups filters"
+HOMEPAGE="https://wiki.linuxfoundation.org/openprinting/cups-filters"
+SRC_URI="
+	https://github.com/OpenPrinting/cups-filters/releases/download/${PV}/${P}.tar.xz
+	https://www.openprinting.org/download/${PN}/${P}.tar.xz
+"
+
+LICENSE="MIT GPL-2"
+SLOT="0"
+IUSE="dbus exif +foomatic jpeg ldap pclm pdf perl png +postscript test tiff zeroconf"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=app-text/poppler-0.32[cxx,jpeg?,lcms,tiff?,utils]
+	>=app-text/qpdf-8.3.0:=
+	dev-libs/glib:2
+	media-libs/fontconfig
+	media-libs/freetype:2
+	media-libs/lcms:2
+	>=net-print/cups-1.7.3
+	!<=net-print/cups-1.5.9999
+	sys-devel/bc
+	sys-libs/zlib
+	exif? ( media-libs/libexif )
+	dbus? ( sys-apps/dbus )
+	foomatic? ( !net-print/foomatic-filters )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	ldap? ( net-nds/openldap:= )
+	pdf? ( app-text/mupdf:= )
+	perl? ( dev-lang/perl:= )
+	png? ( media-libs/libpng:= )
+	postscript? ( >=app-text/ghostscript-gpl-9.09[cups] )
+	tiff? ( media-libs/tiff:= )
+	zeroconf? ( net-dns/avahi[dbus] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+	test? ( media-fonts/dejavu )
+"
+
+src_configure() {
+	# (As of 1.28.15, still defaults upstream to c++0x, so it's still needed,
+	# probably.)
+	# Bug #626800
+	append-cxxflags -std=c++11
+
+	local myeconfargs=(
+		--enable-imagefilters
+		--localstatedir="${EPREFIX}"/var
+		--with-browseremoteprotocols=DNSSD,CUPS
+		--with-cups-rundir="${EPREFIX}"/run/cups
+		--with-fontdir="fonts/conf.avail"
+		--with-pdftops=pdftops
+		--with-rcdir=no
+		--without-php
+
+		$(use_enable exif)
+		$(use_enable dbus)
+		$(use_enable foomatic)
+		$(use_enable ldap)
+		$(use_enable pclm)
+		$(use_enable pdf mutool)
+		$(use_enable postscript ghostscript)
+		$(use_enable zeroconf avahi)
+		$(use_with jpeg)
+		$(use_with png)
+		$(use_with tiff)
+	)
+
+	econf "${myeconfargs[@]}"
+
+	if use perl; then
+		pushd "${S}"/scripting/perl > /dev/null || die
+		perl-module_src_configure
+		popd > /dev/null || die
+	fi
+}
+
+src_compile() {
+	default
+
+	if use perl; then
+		pushd "${S}"/scripting/perl > /dev/null || die
+		perl-module_src_compile
+		popd > /dev/null || die
+	fi
+}
+
+src_test() {
+	# Avoid perl-module_src_test
+	default
+
+	if use perl; then
+		pushd "${S}/scripting/perl" > /dev/null || die
+		perl-module_src_test
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	default
+
+	if use perl; then
+		pushd "${S}"/scripting/perl > /dev/null || die
+		perl-module_src_install
+		perl_delete_localpod
+		popd > /dev/null || die
+	fi
+
+	if use postscript; then
+		# workaround: some printer drivers still require pstoraster and pstopxl, bug #383831
+		dosym gstoraster /usr/libexec/cups/filter/pstoraster
+		dosym gstopxl /usr/libexec/cups/filter/pstopxl
+	fi
+
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+
+	cp "${FILESDIR}"/cups-browsed.init.d-r2 "${T}"/cups-browsed || die
+
+	if ! use zeroconf ; then
+		sed -i -e 's:need cupsd avahi-daemon:need cupsd:g' "${T}"/cups-browsed || die
+		sed -i -e 's:cups\.service avahi-daemon\.service:cups.service:g' "${S}"/utils/cups-browsed.service || die
+	fi
+
+	doinitd "${T}"/cups-browsed
+	systemd_dounit "${S}"/utils/cups-browsed.service
+}
+
+pkg_postinst() {
+	if ! use foomatic ; then
+		ewarn "You are disabling the foomatic code in cups-filters. Please do that ONLY if absolutely"
+		ewarn "necessary. net-print/foomatic-filters as a replacement is deprecated and unmaintained."
+	fi
+}