[gentoo-commits] repo/gentoo:master commit in: app-admin/rasdaemon/

["Sam James" <sam@gentoo.org>]

commit:     3693db19f56e5873b9a54521bb1ecc9f37276b2b
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 22 06:51:35 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Jan 22 06:51:35 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3693db19

app-admin/rasdaemon: add 0.7.0

Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-admin/rasdaemon/Manifest               |  1 +
 app-admin/rasdaemon/rasdaemon-0.7.0.ebuild | 66 ++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/app-admin/rasdaemon/Manifest b/app-admin/rasdaemon/Manifest
index 1e16c310cda2..4a209b8bbcc0 100644
--- a/app-admin/rasdaemon/Manifest
+++ b/app-admin/rasdaemon/Manifest
@@ -1 +1,2 @@
 DIST rasdaemon-0.6.8.tar.gz 161343 BLAKE2B 95dab212e404480d45e5b07fa0f9ec7361036c9295a81dd082657c71cf8ad1114cc28f163b8975733e2042dfeb957f8da71dc52440249c75c24653c1ce235e86 SHA512 634638154c6b0bf7a079d6aba884a55e540c9edc3c25715a792ad7535c68629618e9cef8b6ec7e20845f78bd57f712d437be4d772523020f09d30cce42759a30
+DIST rasdaemon-0.7.0.tar.bz2 433555 BLAKE2B cf73f59558d8a6f3138fea20e7096a1b1214dd44a4518da88a4b1f0c4c92a6df4eb7922e9a2e76d5012364219067cf66e220d8f54588ab22acf09937e41aa2dc SHA512 a7938ccd8171d849b5d89df6ab90942278c824a3dbd17abda8ae3d80ce5227cbc3fe23b31806609114482606d780ec7f0676a0fedfa950ed8cb5a59f3583bd57

diff --git a/app-admin/rasdaemon/rasdaemon-0.7.0.ebuild b/app-admin/rasdaemon/rasdaemon-0.7.0.ebuild
new file mode 100644
index 000000000000..ff6aeb34ef98
--- /dev/null
+++ b/app-admin/rasdaemon/rasdaemon-0.7.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic linux-info systemd
+
+DESCRIPTION="Reliability, Availability and Serviceability logging tool"
+HOMEPAGE="https://github.com/mchehab/rasdaemon"
+SRC_URI="https://github.com/mchehab/rasdaemon/releases/download/v${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+
+DEPEND="
+	dev-db/sqlite
+	elibc_musl? ( sys-libs/argp-standalone )
+"
+RDEPEND="
+	${DEPEND}
+	dev-perl/DBI
+	dev-perl/DBD-SQLite
+	sys-apps/dmidecode
+"
+BDEPEND="sys-devel/gettext"
+
+pkg_setup() {
+	linux-info_pkg_setup
+	local CONFIG_CHECK="~ACPI_EXTLOG ~DEBUG_FS"
+	check_extra_config
+}
+
+src_configure() {
+	local myconfargs=(
+		--enable-sqlite3
+		--enable-abrt-report
+		--enable-aer
+		--enable-arm
+		--enable-extlog
+		--enable-hisi-ns-decode
+		--enable-mce
+		--enable-non-standard
+		--enable-devlink
+		--enable-diskerror
+		--enable-memory-ce-pfa
+		--includedir="/usr/include/${PN}"
+		--localstatedir=/var
+	)
+
+	use elibc_musl && append-libs -largp
+
+	econf "${myconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	keepdir "/var/lib/${PN}"
+
+	systemd_dounit misc/*.service
+
+	newinitd "${FILESDIR}/rasdaemon.openrc-r2" rasdaemon
+	newinitd "${FILESDIR}/ras-mc-ctl.openrc-r1" ras-mc-ctl
+	newconfd "${FILESDIR}"/rasdaemon.confd rasdaemon
+}