[gentoo-commits] repo/gentoo:master commit in: dev-scheme/bigloo/

[gentoo-commits] repo/gentoo:master commit in: dev-scheme/bigloo/

[Maciej Barć]

commit:     3c6a4d25077a40a7bd9aa8c2fb082bfe1cd02c1c
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 27 15:45:50 2022 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Sun Mar 27 15:53:48 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3c6a4d25

dev-scheme/bigloo: respect AS, AR and RANLIB

Closes: https://bugs.gentoo.org/836246
Clsoes: https://bugs.gentoo.org/836247
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-scheme/bigloo/bigloo-4.4c_p4-r1.ebuild | 20 ++++++++++++++++----
 1 file changed, 16 insertions(+), 4 deletions(-)

diff --git a/dev-scheme/bigloo/bigloo-4.4c_p4-r1.ebuild b/dev-scheme/bigloo/bigloo-4.4c_p4-r1.ebuild
index e0bff03017b4..0d56b78e294e 100644
--- a/dev-scheme/bigloo/bigloo-4.4c_p4-r1.ebuild
+++ b/dev-scheme/bigloo/bigloo-4.4c_p4-r1.ebuild
@@ -54,13 +54,25 @@ BDEPEND="
 DOCS=( ChangeLog README.md TODO.org )
 SITEFILE="50${PN}-gentoo.el"
 
+src_prepare() {
+	default
+
+	sed -e "/^ar=/s|=|=\"$(tc-getAR)\"|" \
+		-e "/^ranlib=/s|=|=\"$(tc-getRANLIB)\"|" \
+		-i ./configure || die
+
+	sed "s|^ar |$(tc-getAR) |" -i ./autoconf/ranlib || die
+}
+
 src_configure() {
 	tc-export AR AS CC CPP CXX LD
-	export CFLAGS="${CFLAGS}"
-	export LDFLAGS="${LDFLAGS}"
+	export CFLAGS
+	export LDFLAGS
 
-	myconf=(
-		# Compilation FLAGS
+	local myconf=(
+		# Compilation
+		--as="$(tc-getAS)"
+		--cc="$(tc-getCC)"
 		--cflags="${CFLAGS}"
 		--cpicflags="-fPIC"
 		--cwarningflags=""

[gentoo-commits] repo/gentoo:master commit in: dev-scheme/bigloo/

[Maciej Barć]

commit:     897de91a87eb741c6b48014f44be5d3c0975314e
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 19 23:00:15 2022 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Tue Apr 19 23:16:37 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=897de91a

dev-scheme/bigloo: fix elisp libraries installation

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 .../bigloo/{bigloo-4.4c_p4-r1.ebuild => bigloo-4.4c_p4-r2.ebuild}  | 7 +++++++
 1 file changed, 7 insertions(+)

diff --git a/dev-scheme/bigloo/bigloo-4.4c_p4-r1.ebuild b/dev-scheme/bigloo/bigloo-4.4c_p4-r2.ebuild
similarity index 94%
rename from dev-scheme/bigloo/bigloo-4.4c_p4-r1.ebuild
rename to dev-scheme/bigloo/bigloo-4.4c_p4-r2.ebuild
index 0d56b78e294e..32f3aac80a14 100644
--- a/dev-scheme/bigloo/bigloo-4.4c_p4-r1.ebuild
+++ b/dev-scheme/bigloo/bigloo-4.4c_p4-r2.ebuild
@@ -132,6 +132,13 @@ src_configure() {
 	ebegin "Configuring Bigloo with the following options: ${myconf[@]}"
 	sh ./configure "${myconf[@]}"
 	eend $? || die "configure script failed"
+
+	# When Emacs version is too high (e.g. 28) bigloo will skip compiling
+	# and installing the Emacs support files.
+	# The file "bmacs/Makefile" lists all officially supported Emacs versions.
+	if use emacs ; then
+		sed "/^EMACSBRAND=/s|generic|emacs23|" -i Makefile.config || die
+	fi
 }
 
 src_compile() {

[gentoo-commits] repo/gentoo:master commit in: dev-scheme/bigloo/

[Maciej Barć]

commit:     ff3eea5071e5d079341ac378cea3f9b8e02dff8a
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 15 23:04:44 2023 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Sun Jan 15 23:05:09 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff3eea50

dev-scheme/bigloo: do not install static libs

Closes: https://bugs.gentoo.org/890820
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 .../bigloo/{bigloo-4.4c_p4-r3.ebuild => bigloo-4.4c_p4-r4.ebuild}    | 5 ++++-
 1 file changed, 4 insertions(+), 1 deletion(-)

diff --git a/dev-scheme/bigloo/bigloo-4.4c_p4-r3.ebuild b/dev-scheme/bigloo/bigloo-4.4c_p4-r4.ebuild
similarity index 97%
rename from dev-scheme/bigloo/bigloo-4.4c_p4-r3.ebuild
rename to dev-scheme/bigloo/bigloo-4.4c_p4-r4.ebuild
index 9e7c5157fb76..2baba06090ea 100644
--- a/dev-scheme/bigloo/bigloo-4.4c_p4-r3.ebuild
+++ b/dev-scheme/bigloo/bigloo-4.4c_p4-r4.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -161,6 +161,9 @@ src_install() {
 	emake DESTDIR="${D}" -C bdb install
 	emake DESTDIR="${D}" -C cigloo install
 
+	# Remove static libs, bug #890820
+	find "${ED}" -type f -name "*.a" -delete || die
+
 	# The ".sh" scripts set proper environment and library order for Bigloo,
 	# but programs (and the Bigloo Emacs library, "bee-mode") want "bigloo",
 	# not "bigloo.sh". To make programs work we install all executable files

[gentoo-commits] repo/gentoo:master commit in: dev-scheme/bigloo/

[Maciej Barć]

commit:     cffa59e18ba99f89c5f790af06ffbdcef8a2c6c3
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 16 20:09:27 2023 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Mon Jan 16 20:18:36 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cffa59e1

dev-scheme/bigloo: do not install links to static libs

Closes: https://bugs.gentoo.org/891041
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 .../bigloo/{bigloo-4.4c_p4-r4.ebuild => bigloo-4.4c_p4-r5.ebuild}   | 6 +++---
 1 file changed, 3 insertions(+), 3 deletions(-)

diff --git a/dev-scheme/bigloo/bigloo-4.4c_p4-r4.ebuild b/dev-scheme/bigloo/bigloo-4.4c_p4-r5.ebuild
similarity index 98%
rename from dev-scheme/bigloo/bigloo-4.4c_p4-r4.ebuild
rename to dev-scheme/bigloo/bigloo-4.4c_p4-r5.ebuild
index 2baba06090ea..c1d2c93aafbb 100644
--- a/dev-scheme/bigloo/bigloo-4.4c_p4-r4.ebuild
+++ b/dev-scheme/bigloo/bigloo-4.4c_p4-r5.ebuild
@@ -161,9 +161,6 @@ src_install() {
 	emake DESTDIR="${D}" -C bdb install
 	emake DESTDIR="${D}" -C cigloo install
 
-	# Remove static libs, bug #890820
-	find "${ED}" -type f -name "*.a" -delete || die
-
 	# The ".sh" scripts set proper environment and library order for Bigloo,
 	# but programs (and the Bigloo Emacs library, "bee-mode") want "bigloo",
 	# not "bigloo.sh". To make programs work we install all executable files
@@ -191,6 +188,9 @@ src_install() {
 	fi
 
 	einstalldocs
+
+	# Remove static libs, bug #890820, #891041
+	find "${ED}" -name "*.a" -delete || die
 }
 
 pkg_postinst() {

[gentoo-commits] repo/gentoo:master commit in: dev-scheme/bigloo/

[Maciej Barć]

commit:     fb6d25bb149013e1b50f9db346a16abccceb44de
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  8 20:02:26 2023 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Sat Jul  8 21:22:16 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fb6d25bb

dev-scheme/bigloo: run with 1 makejob

Closes: https://bugs.gentoo.org/836286
Closes: https://bugs.gentoo.org/838043
Closes: https://bugs.gentoo.org/843113
Closes: https://bugs.gentoo.org/909205
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-scheme/bigloo/bigloo-4.4c_p4-r5.ebuild | 8 ++++----
 1 file changed, 4 insertions(+), 4 deletions(-)

diff --git a/dev-scheme/bigloo/bigloo-4.4c_p4-r5.ebuild b/dev-scheme/bigloo/bigloo-4.4c_p4-r5.ebuild
index c1d2c93aafbb..4cfa3c8cc3ba 100644
--- a/dev-scheme/bigloo/bigloo-4.4c_p4-r5.ebuild
+++ b/dev-scheme/bigloo/bigloo-4.4c_p4-r5.ebuild
@@ -142,11 +142,11 @@ src_configure() {
 }
 
 src_compile() {
-	default
+	emake -j1
 
-	emake -C bdl
-	emake -C bdb
-	emake -C cigloo
+	emake -C bdl -j1
+	emake -C bdb -j1
+	emake -C cigloo -j1
 
 	use emacs && emake -C bmacs
 }

[gentoo-commits] repo/gentoo:master commit in: dev-scheme/bigloo/

[Maciej Barć]

commit:     1a00e1ef7d7698bd0386f17913c3f6aaa755cadd
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 22 07:47:59 2023 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Sun Oct 22 08:46:53 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1a00e1ef

dev-scheme/bigloo: add zip dep, use libpulse

Closes: https://bugs.gentoo.org/911492
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 ...-4.4c_p4-r5.ebuild => bigloo-4.4c_p4-r6.ebuild} | 34 +++++++++++++---------
 1 file changed, 21 insertions(+), 13 deletions(-)

diff --git a/dev-scheme/bigloo/bigloo-4.4c_p4-r5.ebuild b/dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild
similarity index 90%
rename from dev-scheme/bigloo/bigloo-4.4c_p4-r5.ebuild
rename to dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild
index 4cfa3c8cc3ba..9289ee34eeb4 100644
--- a/dev-scheme/bigloo/bigloo-4.4c_p4-r5.ebuild
+++ b/dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild
@@ -6,12 +6,12 @@ EAPI=8
 inherit elisp-common toolchain-funcs
 
 MY_PV=${PV/_p/-}  # e.g.: 4.4c_p4 -> 4.4c-4
-MY_P=${PN}-${MY_PV}
+MY_P="${PN}-${MY_PV}"
 
 DESCRIPTION="Practical Scheme Compiler with many extensions"
 HOMEPAGE="http://www-sop.inria.fr/indes/fp/Bigloo/index.html"
 SRC_URI="ftp://ftp-sop.inria.fr/indes/fp/Bigloo/${MY_P}.tar.gz"
-S="${WORKDIR}"/${MY_P}
+S="${WORKDIR}/${MY_P}"
 
 LICENSE="GPL-2+"
 SLOT="0"
@@ -19,7 +19,9 @@ KEYWORDS="~amd64 ~x86"
 IUSE="alsa avahi emacs flac +gmp gpg gstreamer java libuv mp3 pulseaudio +sqlite"
 REQUIRED_USE="flac? ( alsa ) mp3? ( alsa )"
 
-EMACS_DEPEND="emacs? ( >=app-editors/emacs-23.1:* )"
+EMACS_DEPEND="
+	emacs? ( >=app-editors/emacs-23.1:* )
+"
 DEPEND="
 	dev-libs/boehm-gc[threads]
 	dev-libs/libpcre2:=
@@ -34,10 +36,13 @@ DEPEND="
 		media-libs/gst-plugins-base:1.0=
 		media-libs/gstreamer:1.0=
 	)
-	java? ( virtual/jdk:* )
+	java? (
+		app-arch/zip
+		virtual/jdk:*
+	)
 	libuv? ( dev-libs/libuv:= )
 	mp3? ( media-sound/mpg123 )
-	pulseaudio? ( media-sound/pulseaudio )
+	pulseaudio? ( media-libs/libpulse )
 	sqlite? ( dev-db/sqlite:3= )
 "
 RDEPEND="
@@ -57,9 +62,10 @@ SITEFILE="50${PN}-gentoo.el"
 src_prepare() {
 	default
 
-	sed -e "/^ar=/s|=|=\"$(tc-getAR)\"|" \
-		-e "/^ranlib=/s|=|=\"$(tc-getRANLIB)\"|" \
-		-i ./configure || die
+	sed -e "/^ar=/s|=|= \"$(tc-getAR)\"|"			\
+		-e "/^ranlib=/s|=|= \"$(tc-getRANLIB)\"|"	\
+		-i ./configure								\
+		|| die
 
 	sed "s|^ar |$(tc-getAR) |" -i ./autoconf/ranlib || die
 }
@@ -69,7 +75,7 @@ src_configure() {
 	export CFLAGS
 	export LDFLAGS
 
-	local myconf=(
+	local -a myconf=(
 		# Compilation
 		--as="$(tc-getAS)"
 		--cc="$(tc-getCC)"
@@ -171,12 +177,13 @@ src_install() {
 	pushd "${D}" >/dev/null || die
 	local bin bin_link
 	for bin in usr/share/${PN}/bin/* ; do
-		if [[ ${bin} != *.sh ]] ; then
-			bin_link=usr/bin/$(basename ${bin})
+		if [[ "${bin}" != *.sh ]] ; then
+			bin_link="usr/bin/$(basename "${bin}")"
+
 			if [[ -f ${bin}.sh ]] ; then
-				ln -s ../../${bin}.sh ${bin_link} || die
+				ln -s ../../${bin}.sh "${bin_link}" || die
 			else
-				ln -s ../../${bin} ${bin_link} || die
+				ln -s ../../${bin} "${bin_link}" || die
 			fi
 		fi
 	done
@@ -184,6 +191,7 @@ src_install() {
 
 	if use emacs ; then
 		emake DESTDIR="${D}" install-bee
+
 		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
 	fi
 

[gentoo-commits] repo/gentoo:master commit in: dev-scheme/bigloo/

[Sam James]

commit:     d9ca5c919dd2bd59629a96056bc1884b1a52cdd5
Author:     Eli Schwartz <eschwartz93 <AT> gmail <DOT> com>
AuthorDate: Sun Mar 17 05:06:46 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Mar 17 05:28:44 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d9ca5c91

dev-scheme/bigloo: mark as LTO-unsafe

Still cannot actually compile it because of a raft of other bugs. My
theory is that fixing this one issue makes the other issues easier to
spot, at least, in addition to clearing up the LTO tracker bug.

Closes: https://bugs.gentoo.org/858248
Signed-off-by: Eli Schwartz <eschwartz93 <AT> gmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild | 13 ++++++++++++-
 1 file changed, 12 insertions(+), 1 deletion(-)

diff --git a/dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild b/dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild
index dee6dc5c4eeb..4fff4bfd6313 100644
--- a/dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild
+++ b/dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-inherit elisp-common toolchain-funcs
+inherit elisp-common flag-o-matic toolchain-funcs
 
 MY_PV=${PV/_p/-}  # e.g.: 4.4c_p4 -> 4.4c-4
 MY_P="${PN}-${MY_PV}"
@@ -71,6 +71,17 @@ src_prepare() {
 }
 
 src_configure() {
+	# -Werror=lto-type-mismatch
+	# https://bugs.gentoo.org/858248
+	#
+	# The code has various issues that make it look quite worrying to enable
+	# LTO, so I wouldn't risk it even if upstream fixes this one. Cannot even
+	# test compile the package due to bug #870481, bug #911667
+	#
+	# It is also impossible to test from git if any of these are fixed, since
+	# you need a working version in order to compile from git.
+	filter-lto
+
 	tc-export AR AS CC CPP CXX LD
 	export CFLAGS
 	export LDFLAGS

[gentoo-commits] repo/gentoo:master commit in: dev-scheme/bigloo/

[Maciej Barć]

commit:     4a6040b5193950693e6ddfade4b00f8ff0f12b31
Author:     NHOrus <jy6x2b32pie9 <AT> yahoo <DOT> com>
AuthorDate: Wed Jun  5 19:03:42 2024 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Wed Jun  5 19:33:34 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4a6040b5

dev-scheme/bigloo: drop 4.4c_p4-r6

Closes: https://bugs.gentoo.org/927163
Closes: https://bugs.gentoo.org/924857
Closes: https://bugs.gentoo.org/870481
Closes: https://bugs.gentoo.org/911667
Closes: https://github.com/gentoo/gentoo/pull/37037
Signed-off-by: NHOrus <jy6x2b32pie9 <AT> yahoo.com>
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-scheme/bigloo/Manifest                 |   1 -
 dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild | 221 -----------------------------
 2 files changed, 222 deletions(-)

diff --git a/dev-scheme/bigloo/Manifest b/dev-scheme/bigloo/Manifest
index 38d248088c61..09866c145501 100644
--- a/dev-scheme/bigloo/Manifest
+++ b/dev-scheme/bigloo/Manifest
@@ -1,2 +1 @@
-DIST bigloo-4.4c-4.tar.gz 47714106 BLAKE2B f30775cfa3e29f781f31dc5ec80087712504ffab528a911e2a29746562b6179b03cbfc63a45ddf337b2424fbfa476005ffed67674a75b4629ab70459c47147a6 SHA512 b1a7f7f610303dbbd7339ac4f80679b07d1bf5304865fe61f28bd5af8205f1a5c2b5b3edb1c47a0409a6392a2242d2adde1f5129b026b6a7ee022b8f5faec157
 DIST bigloo-4.5b.tar.gz 59015812 BLAKE2B 8dfa73da5ba50a2ec92adde7c9c3fc76841bc0702139238776af2c174099aab85ea28b5d2ec640b6d85f986759b63950f3cfa55e8ec2eb2e73930093b767c93d SHA512 7810f9895ea373f716cd2c93a7b1072d289e2b333632b5b4f293a6317f31a56d2b098790763e96c2d15ce212dafb45c70ec6a7941a344fb8c53a3ef3c6b67feb

diff --git a/dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild b/dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild
deleted file mode 100644
index 4fff4bfd6313..000000000000
--- a/dev-scheme/bigloo/bigloo-4.4c_p4-r6.ebuild
+++ /dev/null
@@ -1,221 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit elisp-common flag-o-matic toolchain-funcs
-
-MY_PV=${PV/_p/-}  # e.g.: 4.4c_p4 -> 4.4c-4
-MY_P="${PN}-${MY_PV}"
-
-DESCRIPTION="Practical Scheme Compiler with many extensions"
-HOMEPAGE="http://www-sop.inria.fr/indes/fp/Bigloo/index.html"
-SRC_URI="ftp://ftp-sop.inria.fr/indes/fp/Bigloo/${MY_P}.tar.gz"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="alsa avahi emacs flac +gmp gpg gstreamer java libuv mp3 pulseaudio +sqlite"
-REQUIRED_USE="flac? ( alsa ) mp3? ( alsa )"
-
-EMACS_DEPEND="
-	emacs? ( >=app-editors/emacs-23.1:* )
-"
-DEPEND="
-	dev-libs/boehm-gc[threads]
-	dev-libs/libpcre2:=
-	dev-libs/libunistring:=
-	dev-libs/openssl:=
-	alsa? ( media-libs/alsa-lib )
-	avahi? ( net-dns/avahi )
-	flac? ( media-libs/flac:= )
-	gmp? ( dev-libs/gmp:= )
-	gpg? ( app-crypt/gnupg )
-	gstreamer? (
-		media-libs/gst-plugins-base:1.0=
-		media-libs/gstreamer:1.0=
-	)
-	java? (
-		app-arch/zip
-		virtual/jdk:*
-	)
-	libuv? ( dev-libs/libuv:= )
-	mp3? ( media-sound/mpg123 )
-	pulseaudio? ( media-libs/libpulse )
-	sqlite? ( dev-db/sqlite:3= )
-"
-RDEPEND="
-	${DEPEND}
-	${EMACS_DEPEND}
-	sys-devel/binutils
-	dev-debug/gdb
-"
-BDEPEND="
-	${EMACS_DEPEND}
-	sys-apps/texinfo
-"
-
-DOCS=( ChangeLog README.md TODO.org )
-SITEFILE="50${PN}-gentoo.el"
-
-src_prepare() {
-	default
-
-	sed -e "/^ar=/s|=|= \"$(tc-getAR)\"|"			\
-		-e "/^ranlib=/s|=|= \"$(tc-getRANLIB)\"|"	\
-		-i ./configure								\
-		|| die
-
-	sed "s|^ar |$(tc-getAR) |" -i ./autoconf/ranlib || die
-}
-
-src_configure() {
-	# -Werror=lto-type-mismatch
-	# https://bugs.gentoo.org/858248
-	#
-	# The code has various issues that make it look quite worrying to enable
-	# LTO, so I wouldn't risk it even if upstream fixes this one. Cannot even
-	# test compile the package due to bug #870481, bug #911667
-	#
-	# It is also impossible to test from git if any of these are fixed, since
-	# you need a working version in order to compile from git.
-	filter-lto
-
-	tc-export AR AS CC CPP CXX LD
-	export CFLAGS
-	export LDFLAGS
-
-	local -a myconf=(
-		# Compilation
-		--as="$(tc-getAS)"
-		--cc="$(tc-getCC)"
-		--cflags="${CFLAGS}"
-		--cpicflags="-fPIC"
-		--cwarningflags=""
-		--ldflags="${LDFLAGS}"
-		# Installation directories
-		--prefix=/usr
-		--bindir=/usr/share/${PN}/bin
-		--docdir=/usr/share/doc/${PF}
-		--infodir=/usr/share/info
-		--libdir=/usr/"$(get_libdir)"
-		--mandir=/usr/share/man
-		# Custom internal components
-		--customgc=no
-		--customgmp=no
-		--customlibuv=no
-		--customunistring=no
-		--jvm=$(usex java)
-		--native=yes
-		--sharedbde=yes
-		--sharedcompiler=yes
-		--strip=no
-		# Libraries, Bigloo calls them APIs
-		--disable-phidget  # not important for now, only in ::ros-overlay ?
-		--enable-calendar  # iCalendar parser
-		--enable-crypto
-		--enable-csv   # parsing CSV files
-		--enable-mail  # IMAP protocol implementation
-		--enable-multimedia
-		--enable-packrat  # packrat parser
-		--enable-phone
-		--enable-pkgcomp
-		--enable-pthread
-		--enable-srfi1
-		--enable-srfi18
-		--enable-ssl
-		--enable-text  # BibTeX parser
-		--enable-upnp  # Upnp protocol implementation
-		--enable-web   # XML, CGI, and RSS parsers
-		$(use_enable alsa)
-		$(use_enable avahi)
-		$(use_enable flac wav)
-		$(use_enable flac)
-		$(use_enable gmp srfi27)
-		$(use_enable gmp)
-		$(use_enable gpg openpgp)
-		$(use_enable gstreamer)
-		$(use_enable libuv)
-		$(use_enable mp3 mpg123)
-		$(use_enable pulseaudio)
-		$(use_enable sqlite pkglib)
-		$(use_enable sqlite)
-		# GNU Emacs libraries
-		--bee=$(usex emacs full partial)
-		--emacs=$(usex emacs "${EMACS}" "no")
-		--lispdir=$(usex emacs "${SITELISP}/${PN}" "")
-	)
-	ebegin "Configuring Bigloo with the following options: ${myconf[@]}"
-	sh ./configure "${myconf[@]}"
-	eend $? || die "configure script failed"
-
-	# When Emacs version is too high (e.g. 28) bigloo will skip compiling
-	# and installing the Emacs support files.
-	# The file "bmacs/Makefile" lists all officially supported Emacs versions.
-	if use emacs ; then
-		sed "/^EMACSBRAND=/s|generic|emacs23|" -i Makefile.config || die
-	fi
-}
-
-src_compile() {
-	emake -j1
-
-	emake -C bdl -j1
-	emake -C bdb -j1
-	emake -C cigloo -j1
-
-	use emacs && emake -C bmacs
-}
-
-src_test() {
-	emake test
-}
-
-src_install() {
-	emake DESTDIR="${D}" LN_S="ln -rs" install
-	emake DESTDIR="${D}" -C bdl install
-	emake DESTDIR="${D}" -C bdb install
-	emake DESTDIR="${D}" -C cigloo install
-
-	# The ".sh" scripts set proper environment and library order for Bigloo,
-	# but programs (and the Bigloo Emacs library, "bee-mode") want "bigloo",
-	# not "bigloo.sh". To make programs work we install all executable files
-	# into "/usr/share/bigloo/bin", and then pick one by one for non-scripts:
-	# if a script with ".sh" extensions exists, then we link the script,
-	# not the picked executable to a binary name, otherwise link the binary.
-	mkdir -p "${D}"/usr/bin || die
-	pushd "${D}" >/dev/null || die
-	local bin bin_link
-	for bin in usr/share/${PN}/bin/* ; do
-		if [[ "${bin}" != *.sh ]] ; then
-			bin_link="usr/bin/$(basename "${bin}")"
-
-			if [[ -f ${bin}.sh ]] ; then
-				ln -s ../../${bin}.sh "${bin_link}" || die
-			else
-				ln -s ../../${bin} "${bin_link}" || die
-			fi
-		fi
-	done
-	popd >/dev/null || die
-
-	if use emacs ; then
-		emake DESTDIR="${D}" install-bee
-
-		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
-	fi
-
-	einstalldocs
-
-	# Remove static libs, bug #890820, #891041
-	find "${ED}" -name "*.a" -delete || die
-}
-
-pkg_postinst() {
-	use emacs && elisp-site-regen
-}
-
-pkg_postrm() {
-	use emacs && elisp-site-regen
-}

[gentoo-commits] repo/gentoo:master commit in: dev-scheme/bigloo/

[Maciej Barć]

commit:     509edd0cada8c1cabcb8e9b44cb2b19c3e9aec4b
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Thu Jun  6 07:48:30 2024 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Thu Jun  6 08:09:30 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=509edd0c

dev-scheme/bigloo: remove libtool .la files

Closes: https://bugs.gentoo.org/933665
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-scheme/bigloo/{bigloo-4.5b.ebuild => bigloo-4.5b-r1.ebuild} | 9 +++++----
 1 file changed, 5 insertions(+), 4 deletions(-)

diff --git a/dev-scheme/bigloo/bigloo-4.5b.ebuild b/dev-scheme/bigloo/bigloo-4.5b-r1.ebuild
similarity index 96%
rename from dev-scheme/bigloo/bigloo-4.5b.ebuild
rename to dev-scheme/bigloo/bigloo-4.5b-r1.ebuild
index 15820af36235..e1175674a698 100644
--- a/dev-scheme/bigloo/bigloo-4.5b.ebuild
+++ b/dev-scheme/bigloo/bigloo-4.5b-r1.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 inherit elisp-common flag-o-matic toolchain-funcs
 
-MY_PV=${PV/_p/-}  # e.g.: 4.4c_p4 -> 4.4c-4
+MY_PV="${PV/_p/-}"  # e.g.: 4.4c_p4 -> 4.4c-4
 MY_P="${PN}-${MY_PV}"
 
 DESCRIPTION="Practical Scheme Compiler with many extensions"
@@ -56,11 +56,11 @@ BDEPEND="
 	sys-apps/texinfo
 "
 
+PATCHES=( "${FILESDIR}/${P}-makefile.patch" )
+
 DOCS=( ChangeLog README.md TODO.org )
 SITEFILE="50${PN}-gentoo.el"
 
-PATCHES="${FILESDIR}/${P}-makefile.patch"
-
 src_prepare() {
 	default
 
@@ -211,8 +211,9 @@ src_install() {
 
 	einstalldocs
 
-	# Remove static libs, bug #890820, #891041
+	# Remove static libs, bug #890820, #891041, #933665
 	find "${ED}" -name "*.a" -delete || die
+	find "${ED}" -name "*.la" -delete || die
 }
 
 pkg_postinst() {