[gentoo-commits] repo/gentoo:master commit in: media-plugins/gst-plugins-vaapi/

["Sam James" <sam@gentoo.org>]

commit:     94397e4e79297727a48538f365ace0340723bac0
Author:     brahmajit das <listout <AT> protonmail <DOT> com>
AuthorDate: Sat Jan 14 15:37:51 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Jan 14 15:49:45 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=94397e4e

media-plugins/gst-plugins-vaapi: add 1.20.5

Signed-off-by: Sam James <sam <AT> gentoo.org>
Signed-off-by: brahmajit das <listout <AT> protonmail.com>

 media-plugins/gst-plugins-vaapi/Manifest           |  1 +
 .../gst-plugins-vaapi-1.20.5.ebuild                | 98 ++++++++++++++++++++++
 2 files changed, 99 insertions(+)

diff --git a/media-plugins/gst-plugins-vaapi/Manifest b/media-plugins/gst-plugins-vaapi/Manifest
index e7144fbfceab..827505bc98d7 100644
--- a/media-plugins/gst-plugins-vaapi/Manifest
+++ b/media-plugins/gst-plugins-vaapi/Manifest
@@ -1,2 +1,3 @@
 DIST gstreamer-vaapi-1.20.3.tar.xz 794840 BLAKE2B d422d982dba11175c57f6b6b329c75cbf96810a8653b028ce43dce8dfad0d474ae56ea7b9bde65e5901fb1453517fc1bd6541c0607d071b5b8444e78f30b355f SHA512 029e3e417c185f7aa8386aa3ce543a14bb7b1145e2386a763e109c636f32547c03cc6382fc45bbf1f5f1aab799b0250b852edbfc30dfb0992bcfd4d20b104a90
 DIST gstreamer-vaapi-1.20.4.tar.xz 795596 BLAKE2B d71b21ad0f0b7a1ef2e3d3c9c6c017766b23c928cbb8e63f52682d18c0517e60c2a51de66670d7a65b5d991c2e99dddeee8f20dd48b5cf50a3830ba57a56cb97 SHA512 5cd9a9f08e76aa36f092b18bfa811db8eeec5ff7e49478da4e78b5f876e84a471de6318c8a74ab6941fa1cd3aa1d4a8595df7ee0bad3b62007968d5615d481a3
+DIST gstreamer-vaapi-1.20.5.tar.xz 801628 BLAKE2B 4c3203baefafccbf8983c9e1da17a3455a0566d27b9a12b4d30292289cded803fb4ae8de1f26ff3536c632984227809df69fa9de78af4190acc30b6750c2d27c SHA512 fd24a58c83b0f820b1b2ca3c179228574a16b9f2657988de0c4569d925f01eb131853b0a322ce95b8523578e66ca66443900af1a5e022ecb4081bfe86a2e23bc

diff --git a/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.20.5.ebuild b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.20.5.ebuild
new file mode 100644
index 000000000000..d43cde42d49a
--- /dev/null
+++ b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.20.5.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gstreamer-meson python-any-r1
+
+MY_PN="gstreamer-vaapi"
+DESCRIPTION="Hardware accelerated video decoding through VA-API plugin for GStreamer"
+HOMEPAGE="https://gitlab.freedesktop.org/gstreamer/gstreamer-vaapi"
+SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="1.0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+drm +egl gles2 +opengl wayland +X" # Keep default enabled IUSE in sync with gst-plugins-base and libva
+
+# gst-vaapi configure is based around GL platform mainly, unlike gst-plugins-bad that goes by GL API mainly; for less surprises,
+# we design gst-vaapi ebuild in terms of GL API as main choice as well, meaning that USE opengl and/or gles2 is required to
+# enable opengl support at all and choices get chained from there.
+# One or multiple video output are required: drm, x11, glx, egl and/or wayland;
+# but GL API is our main trigger, thus USE=egl should be ineffective if neither gles2 or opengl is enabled;
+# So "|| ( drm egl opengl wayland X )" would be wrong, because egl isn't built with USE="egl -opengl -gles2", ending up with no video outputs.
+# As we ensure at least one working GL output with other REQUIRED_USE, we can put gles2/opengl in REQUIRED_USE instead of egl, solving the issue.
+# gles2 API only supported windowing system (on linux) is EGL, so require it
+# opengl API only supported windowing systems (on linux) are EGL and GLX, so require one of them (glx is enabled with USE="opengl X")
+REQUIRED_USE="
+	|| ( drm gles2 opengl wayland X )
+	gles2? ( egl )
+	opengl? ( || ( egl X ) )
+"
+
+# glx doesn't require libva-glx (libva[opengl]) afaics, only by tests/test-display.c
+# USE flag behavior:
+# 'drm' enables vaapi drm support
+# 'egl' enables EGL platform support (but only if also 'opengl||gles2')
+# - 'egl' is exposed as a USE flag mainly to get EGL support instead of or in addition to GLX support with desktop GL while keeping it optional for pure GLX cases;
+#   it's always required with USE=gles2, thus USE="gles2 opengl X" will require and build desktop GL EGL platform support as well on top of GLX, which doesn't add extra deps at that point.
+# 'gles2' enables GLESv2 or GLESv3 based GL API support
+# 'opengl' enables desktop OpenGL based GL API support
+# 'wayland' enables non-GL Wayland support; wayland EGL support when combined with 'egl' (but only if also 'opengl||gles2')
+# 'X' enables non-GL X support; GLX support when combined with 'opengl'
+# gst-plugins-bad still needed for codecparsers (GL libraries moved to -base); checked for 1.14 (recheck for 1.16)
+GST_REQ="${PV}"
+GL_DEPS="
+	>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[egl?,gles2?,opengl?,wayland?,X?]
+	media-libs/mesa[gles2?,egl(+)?,X?,${MULTILIB_USEDEP}]
+"
+RDEPEND="
+	>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-bad-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/libva-1.4.0:=[drm(+)?,wayland?,X?,${MULTILIB_USEDEP}]
+	drm? (
+		>=virtual/libudev-208:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.98[${MULTILIB_USEDEP}]
+	)
+	gles2? ( ${GL_DEPS} )
+	opengl? ( ${GL_DEPS} )
+	wayland? ( >=dev-libs/wayland-1.11.0[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
+		x11-libs/libXrender[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="${PYTHON_DEPS}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+# FIXME: "Failed to create vaapipostproc element"
+RESTRICT="test"
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dwith_encoders=yes
+		-Dwith_drm=$(usex drm yes no)
+		-Dwith_x11=$(usex X yes no)
+		-Dwith_wayland=$(usex wayland yes no)
+	)
+
+	if use opengl || use gles2; then
+		emesonargs+=( -Dwith_egl=$(usex egl yes no) )
+	else
+		emesonargs+=( -Dwith_egl=no )
+	fi
+
+	if use opengl && use X; then
+		emesonargs+=( -Dwith_glx=yes )
+	else
+		emesonargs+=( -Dwith_glx=no )
+	fi
+
+	# Workaround EGL/eglplatform.h being built with X11 present
+	use X || export CFLAGS="${CFLAGS} -DEGL_NO_X11"
+
+	gstreamer_multilib_src_configure
+}