[gentoo-commits] repo/gentoo:master commit in: net-misc/gnome-remote-desktop/

["Matt Turner" <mattst88@gentoo.org>]

commit:     259b2bfd3ee1ffd61cb8445a36ccb06c19dce246
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Mon Jan  9 14:41:50 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Jan  9 15:41:39 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=259b2bfd

net-misc/gnome-remote-desktop: Version bump to 43.3

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/29034
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-misc/gnome-remote-desktop/Manifest             |  1 +
 .../gnome-remote-desktop-43.3.ebuild               | 73 ++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/net-misc/gnome-remote-desktop/Manifest b/net-misc/gnome-remote-desktop/Manifest
index 4fc2e5ea4680..90b2d358972e 100644
--- a/net-misc/gnome-remote-desktop/Manifest
+++ b/net-misc/gnome-remote-desktop/Manifest
@@ -1 +1,2 @@
 DIST gnome-remote-desktop-43.2.tar.xz 195984 BLAKE2B 7f6bcf142f98a1b6f357cbc6bb651c63bcae5360a52a83ac44b8eea8f0f3bcdb29c23ec4d973ee40b29ebc0ff59958468a236238b50e68a886e31334a45f5c5c SHA512 e7e9c36e04a7273cb1700859d59ab8130bca7103c3def7f51a6df31b98f6021b9ceb15d2f9e71fef2464141dcd01d467e126731028d7dd6b6ec843dd52b1e8d4
+DIST gnome-remote-desktop-43.3.tar.xz 196540 BLAKE2B a33dcb830cd5ed0e9c44da8717a7c621231a97a0d503daa007d6d4c47feb83e16905f61a9ebe60ce5231b7fbad035ab24603284f9c9212ccb48dab90cb845a5c SHA512 67dc7c4ab7d2db9ef843e30b688e024ed91341c09fbf4c7d33f4c1d8b7d9d3564fb64bc948b12f2aee3ca8a545fb21842ce79970ec1ddaf99fd64c41a44b8f59

diff --git a/net-misc/gnome-remote-desktop/gnome-remote-desktop-43.3.ebuild b/net-misc/gnome-remote-desktop/gnome-remote-desktop-43.3.ebuild
new file mode 100644
index 000000000000..9b0c3dfafbb2
--- /dev/null
+++ b/net-misc/gnome-remote-desktop/gnome-remote-desktop-43.3.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd xdg
+
+DESCRIPTION="Remote desktop daemon for GNOME using pipewire"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="aac doc +rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc ) aac? ( rdp )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	x11-libs/libdrm
+	>=media-libs/libepoxy-1.4
+	>=dev-libs/glib-2.68:2
+	x11-libs/libnotify
+	app-crypt/libsecret
+	>=media-video/pipewire-0.3.49:=
+	app-crypt/tpm2-tss:=
+	rdp? (
+		>=media-libs/nv-codec-headers-11.1.5.0
+		>=net-misc/freerdp-2.8.0:=[server]
+		>=sys-fs/fuse-3.9.1:3
+		>=x11-libs/libxkbcommon-1.0.0
+
+		aac? (
+			media-libs/fdk-aac:=
+		)
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+	doc? (
+		app-text/asciidoc
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc man)
+		$(meson_use aac fdk_aac)
+		$(meson_use rdp)
+		$(meson_use vnc)
+		$(meson_use systemd)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}