[gentoo-commits] repo/proj/libressl:master commit in: mail-mta/opensmtpd/, mail-mta/opensmtpd/files/

["Quentin Retornaz" <gentoo@retornaz.com>]

commit:     d31152e9c9e88e679d24047b89653c82b14f056a
Author:     Anna “CyberTailor” <cyber <AT> sysrq <DOT> in>
AuthorDate: Sun Jan  1 23:22:44 2023 +0000
Commit:     Quentin Retornaz <gentoo <AT> retornaz <DOT> com>
CommitDate: Mon Jan  2 19:38:01 2023 +0000
URL:        https://gitweb.gentoo.org/repo/proj/libressl.git/commit/?id=d31152e9

mail-mta/opensmtpd: new package, add 6.8.0_p2-r2

Signed-off-by: Anna “CyberTailor” <cyber <AT> sysrq.in>
Closes: https://github.com/gentoo/libressl/pull/486
Signed-off-by: Quentin Retornaz <gentoo <AT> retornaz.com>

 mail-mta/opensmtpd/Manifest                     |  1 +
 mail-mta/opensmtpd/files/smtpd.initd            | 11 ++++
 mail-mta/opensmtpd/files/smtpd.pam              |  4 ++
 mail-mta/opensmtpd/files/smtpd.service          | 10 ++++
 mail-mta/opensmtpd/files/smtpd.socket           |  8 +++
 mail-mta/opensmtpd/metadata.xml                 | 17 ++++++
 mail-mta/opensmtpd/opensmtpd-6.8.0_p2-r2.ebuild | 76 +++++++++++++++++++++++++
 7 files changed, 127 insertions(+)

diff --git a/mail-mta/opensmtpd/Manifest b/mail-mta/opensmtpd/Manifest
new file mode 100644
index 0000000..f7a170b
--- /dev/null
+++ b/mail-mta/opensmtpd/Manifest
@@ -0,0 +1 @@
+DIST opensmtpd-6.8.0p2.tar.gz 860189 BLAKE2B 603e8516860eddefb1694ea4cb5631cec2df2a19fa3193b25388caf73c41e82d44e57847fc95b5187488cae629542e72ff2d5a17badc15cef1647bdb173d7827 SHA512 48f152b75575146fdd09bdf47123041ea62fefb6e5de33a69826bf91a2126a918f8db1caffadb2f142a1a21de8126d492de88cb65bdf169e61c0b22d3e78d290

diff --git a/mail-mta/opensmtpd/files/smtpd.initd b/mail-mta/opensmtpd/files/smtpd.initd
new file mode 100644
index 0000000..cf205a8
--- /dev/null
+++ b/mail-mta/opensmtpd/files/smtpd.initd
@@ -0,0 +1,11 @@
+#!/sbin/openrc-run
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+command="smtpd"
+pidfile="/run/smtpd.pid"
+description="SMTP daemon from OpenBSD"
+
+depend() {
+	need net
+}

diff --git a/mail-mta/opensmtpd/files/smtpd.pam b/mail-mta/opensmtpd/files/smtpd.pam
new file mode 100644
index 0000000..a85aeae
--- /dev/null
+++ b/mail-mta/opensmtpd/files/smtpd.pam
@@ -0,0 +1,4 @@
+auth       required     pam_nologin.so
+auth       include      system-auth
+account    include      system-auth
+session    include      system-auth

diff --git a/mail-mta/opensmtpd/files/smtpd.service b/mail-mta/opensmtpd/files/smtpd.service
new file mode 100644
index 0000000..fd2a650
--- /dev/null
+++ b/mail-mta/opensmtpd/files/smtpd.service
@@ -0,0 +1,10 @@
+[Unit]
+Description=OpenSMTPD
+After=network.target
+
+[Service]
+Type=forking
+ExecStart=/usr/sbin/smtpd
+
+[Install]
+WantedBy=multi-user.target

diff --git a/mail-mta/opensmtpd/files/smtpd.socket b/mail-mta/opensmtpd/files/smtpd.socket
new file mode 100644
index 0000000..fb42f85
--- /dev/null
+++ b/mail-mta/opensmtpd/files/smtpd.socket
@@ -0,0 +1,8 @@
+[Unit]
+Description=OpenSMTPD Socket
+
+[Socket]
+ListenStream=/var/run/smtpd.sock
+
+[Install]
+WantedBy=sockets.target

diff --git a/mail-mta/opensmtpd/metadata.xml b/mail-mta/opensmtpd/metadata.xml
new file mode 100644
index 0000000..12887d4
--- /dev/null
+++ b/mail-mta/opensmtpd/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<longdescription lang="en">
+		OpenSMTPD is an implementation of the server-side SMTP protocol as defined by RFC 5321, with some additional standard extensions. It allows ordinary machines to exchange e-mails with other systems speaking the SMTP protocol.
+	</longdescription>
+	<maintainer type="person">
+		<email>zx2c4@gentoo.org</email>
+		<name>Jason A. Donenfeld</name>
+	</maintainer>
+	<use>
+		<flag name="mta">Enable this to install as system-wide MTA</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">OpenSMTPD/OpenSMTPD</remote-id>
+	</upstream>
+</pkgmetadata>

diff --git a/mail-mta/opensmtpd/opensmtpd-6.8.0_p2-r2.ebuild b/mail-mta/opensmtpd/opensmtpd-6.8.0_p2-r2.ebuild
new file mode 100644
index 0000000..c41cdef
--- /dev/null
+++ b/mail-mta/opensmtpd/opensmtpd-6.8.0_p2-r2.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit pam systemd
+
+DESCRIPTION="Lightweight but featured SMTP daemon from OpenBSD"
+HOMEPAGE="https://www.opensmtpd.org"
+SRC_URI="https://www.opensmtpd.org/archives/${P/_}.tar.gz"
+
+LICENSE="ISC BSD BSD-1 BSD-2 BSD-4"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ppc64 ~riscv x86"
+IUSE="berkdb +mta pam split-usr"
+
+DEPEND="
+	acct-user/smtpd
+	acct-user/smtpq
+	dev-libs/openssl:=
+	elibc_musl? ( sys-libs/fts-standalone )
+	sys-libs/zlib
+	pam? ( sys-libs/pam )
+	berkdb? ( sys-libs/db:= )
+	dev-libs/libevent:=
+	app-misc/ca-certificates
+	net-mail/mailbase
+	net-libs/libasr
+	virtual/libcrypt:=
+	!mail-mta/courier
+	!mail-mta/esmtp
+	!mail-mta/exim
+	!mail-mta/mini-qmail
+	!mail-mta/msmtp[mta]
+	!mail-mta/netqmail
+	!mail-mta/nullmailer
+	!mail-mta/postfix
+	!mail-mta/qmail-ldap
+	!mail-mta/sendmail
+	!mail-mta/ssmtp[mta]
+"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${P/_}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/smtpd \
+		--with-path-mbox=/var/spool/mail \
+		--with-path-empty=/var/empty \
+		--with-path-socket=/run \
+		--with-path-CAfile=/etc/ssl/certs/ca-certificates.crt \
+		--with-user-smtpd=smtpd \
+		--with-user-queue=smtpq \
+		--with-group-queue=smtpq \
+		$(use_with pam auth-pam) \
+		$(use_with berkdb table-db)
+}
+
+src_install() {
+	default
+	newinitd "${FILESDIR}"/smtpd.initd smtpd
+	systemd_dounit "${FILESDIR}"/smtpd.{service,socket}
+	use pam && newpamd "${FILESDIR}"/smtpd.pam smtpd
+	dosym smtpctl /usr/sbin/makemap
+	dosym smtpctl /usr/sbin/newaliases
+	if use mta ; then
+		dodir /usr/sbin
+		dosym smtpctl /usr/sbin/sendmail
+		# on USE="-split-usr" system sbin and bin are merged
+		# so symlink made above will collide with one below
+		use split-usr && dosym ../sbin/smtpctl /usr/bin/sendmail
+		mkdir -p "${ED}"/usr/$(get_libdir) || die
+		ln -s --relative "${ED}"/usr/sbin/smtpctl "${ED}"/usr/$(get_libdir)/sendmail || die
+	fi
+}