[gentoo-commits] repo/gentoo:master commit in: dev-games/godot/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     182ccae2bf58af9e51cd2a00cede3a6a33f96c8b
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 29 16:31:04 2022 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Dec 29 20:28:53 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=182ccae2

dev-games/godot: drop 4.0_beta9

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 dev-games/godot/Manifest               |   1 -
 dev-games/godot/godot-4.0_beta9.ebuild | 256 ---------------------------------
 2 files changed, 257 deletions(-)

diff --git a/dev-games/godot/Manifest b/dev-games/godot/Manifest
index 6994ec303198..5d533eb9a1dd 100644
--- a/dev-games/godot/Manifest
+++ b/dev-games/godot/Manifest
@@ -1,3 +1,2 @@
 DIST godot-3.5.1-stable.tar.xz 24153448 BLAKE2B 9d61276a2d82ef4f4487ec1046b7fa58f2b3626640b2db25c1f98c3f8e2ff40eddcf943fd9ffaaf6814fbafbbe7ef1d3f642d77af953b87731cff570ac3a5473 SHA512 59e5ca88534f542562971efb83b76561705f9ca8761311f01b4453857e7ae046c17cadd0d5ca6f6f56e262b5031294a8b9ad970fa6ffc95e1a6a1e1bae48d55f
 DIST godot-4.0-beta10.tar.xz 31668884 BLAKE2B 25fead426d6f5d1e572363a2f4b895454d0e35434d570bb894cbb5b20db9c6db076942e126730f210661a2f8a75e1e780a02226ee732fdb1f5c8f0043e115a81 SHA512 8806471abc699beca9cef87b8e386c6a044083e9a9dc6ff3c0a65655222c874eeb1fb2cfbd6c479ead4b4106beed530f7205a4873a3da16b4b4fa5f95496168b
-DIST godot-4.0-beta9.tar.xz 31655148 BLAKE2B 296fb2e8d21bc4357d5262c3c8b11587cdb9d8f181b25b93600ca341c5d9bff1b47d500f676d7b8fdbf3ea4a53afa9ef2882d94380d7209813dbe281bef452bb SHA512 13eec9129644746bd7e81e1e0fe164d6d91a4d0618d40af335e2deb79fc15b794f1366c4b54cc27de5b088dc49f56417bd4e018a1bad29f76b71c19ed22c0603

diff --git a/dev-games/godot/godot-4.0_beta9.ebuild b/dev-games/godot/godot-4.0_beta9.ebuild
deleted file mode 100644
index ba144b6c7e6c..000000000000
--- a/dev-games/godot/godot-4.0_beta9.ebuild
+++ /dev/null
@@ -1,256 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..11} )
-inherit bash-completion-r1 desktop python-any-r1 scons-utils toolchain-funcs xdg
-
-MY_P="${PN}-$(ver_rs 2 -)"
-
-DESCRIPTION="Multi-platform 2D and 3D game engine with a feature-rich editor"
-HOMEPAGE="https://godotengine.org/"
-SRC_URI="https://downloads.tuxfamily.org/godotengine/$(ver_rs 2 /)/${MY_P}.tar.xz"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="
-	MIT
-	Apache-2.0 BSD Boost-1.0 CC0-1.0 Unlicense ZLIB
-	gui? ( CC-BY-4.0 ) tools? ( OFL-1.1 )"
-SLOT="4"
-KEYWORDS="~amd64"
-# Enable roughly same as upstream by default so it works as expected,
-# except raycast (tools-only heavy dependency), and deprecated.
-IUSE="
-	+dbus debug deprecated +fontconfig +gui pulseaudio raycast
-	+runner speech test +theora +tools +udev +upnp +webp"
-# disable tests until out of beta, tests themselves are new and can be volatile
-RESTRICT="test"
-
-# libX11 range is temporary while this is being looked into:
-# - https://github.com/godotengine/godot/issues/69352
-# - https://gitlab.freedesktop.org/xorg/lib/libx11/-/issues/170
-# dlopen: alsa-lib,dbus,fontconfig,libX*,pulseaudio,speech-dispatcher,udev
-RDEPEND="
-	app-arch/zstd:=
-	dev-games/recastnavigation:=
-	dev-libs/icu:=
-	dev-libs/libpcre2:=[pcre32]
-	media-libs/freetype[brotli,harfbuzz]
-	media-libs/harfbuzz:=[icu]
-	media-libs/libogg
-	media-libs/libpng:=
-	media-libs/libvorbis
-	<net-libs/mbedtls-3:=
-	net-libs/wslay
-	sys-libs/zlib:=
-	fontconfig? ( media-libs/fontconfig )
-	gui? (
-		media-libs/alsa-lib
-		media-libs/libglvnd[X]
-		media-libs/vulkan-loader[X]
-		|| (
-			>x11-libs/libX11-1.8.3
-			<x11-libs/libX11-1.8.2-r1
-		)
-		x11-libs/libXcursor
-		x11-libs/libXext
-		x11-libs/libXi
-		x11-libs/libXinerama
-		x11-libs/libXrandr
-		x11-libs/libXrender
-		dbus? ( sys-apps/dbus )
-		pulseaudio? ( media-libs/libpulse )
-		tools? ( raycast? ( media-libs/embree:3 ) )
-		udev? ( virtual/udev )
-	)
-	speech? ( app-accessibility/speech-dispatcher )
-	theora? ( media-libs/libtheora )
-	tools? ( app-misc/ca-certificates )
-	upnp? ( net-libs/miniupnpc:= )
-	webp? ( media-libs/libwebp:= )"
-DEPEND="
-	${RDEPEND}
-	gui? ( x11-base/xorg-proto )
-	tools? ( test? ( dev-cpp/doctest ) )"
-BDEPEND="virtual/pkgconfig"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-4.0-musl.patch
-	"${FILESDIR}"/${PN}-4.0_beta3-headless-header.patch
-	"${FILESDIR}"/${PN}-4.0_beta8-scons.patch
-)
-
-src_prepare() {
-	default
-
-	sed -i "1,5s/ godot/&${SLOT}/i" misc/dist/linux/godot.6 || die
-	sed -i "/id/s/Godot/&${SLOT}/" misc/dist/linux/org.godotengine.Godot.appdata.xml || die
-	sed -e "s/=godot/&${SLOT}/" -e "/^Name=/s/$/ ${SLOT}/" \
-		-i misc/dist/linux/org.godotengine.Godot.desktop || die
-
-	sed -i "s|pkg-config |$(tc-getPKG_CONFIG) |" platform/linuxbsd/detect.py || die
-
-	# use of builtin_ switches can be messy (see below), delete to be sure
-	local unbundle=(
-		doctest embree freetype graphite harfbuzz icu4c libogg
-		libpng libtheora libvorbis libwebp mbedtls miniupnpc
-		pcre2 recastnavigation volk wslay zlib zstd
-		# certs: unused by generated header, but scons panics if not found
-	)
-	rm -r "${unbundle[@]/#/thirdparty/}" || die
-
-	# do symlinks to avoid too much patching with hardcoded header paths
-	mkdir thirdparty/lib{vorbis,ogg} || die
-	ln -s "${ESYSROOT}"/usr/include thirdparty/zstd || die
-	ln -s "${ESYSROOT}"/usr/include/doctest thirdparty/ || die
-	ln -s "${ESYSROOT}"/usr/include/ogg thirdparty/libogg/ || die
-	ln -s "${ESYSROOT}"/usr/include/vorbis thirdparty/libvorbis/ || die
-}
-
-src_compile() {
-	local -x GODOT_VERSION_STATUS=$(ver_cut 3-4) # for dev versions only
-	local -x BUILD_NAME=gentoo # replaces "custom_build" in version string
-
-	local esconsargs=(
-		AR="$(tc-getAR)" CC="$(tc-getCC)" CXX="$(tc-getCXX)"
-
-		progress=no
-		verbose=yes
-
-		deprecated=$(usex deprecated)
-		#execinfo=$(usex !elibc_glibc) # libexecinfo is not packaged
-		fontconfig=$(usex fontconfig)
-		minizip=yes # uses a modified bundled copy
-		opengl3=$(usex gui)
-		pulseaudio=$(usex gui $(usex pulseaudio))
-		speechd=$(usex speech)
-		udev=$(usex gui $(usex udev))
-		use_dbus=$(usex gui $(usex dbus))
-		use_volk=no # unnecessary when linking directly to libvulkan
-		vulkan=$(usex gui) # hard-required and favored by upstream over gles3
-		x11=$(usex gui)
-
-		system_certs_path="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt
-
-		# platform/*/detect.py uses builtin_* switches to check if need
-		# to link with system libraries, but ignores whether the dep is
-		# actually used, so "enable" deleted builtins on disabled deps
-		builtin_certs=no
-		builtin_embree=$(usex !gui yes $(usex !tools yes $(usex !raycast)))
-		builtin_enet=yes # bundled copy is patched for IPv6+DTLS support
-		builtin_freetype=no
-		builtin_glslang=yes #879111
-		builtin_graphite=no
-		builtin_harfbuzz=no
-		builtin_icu=no
-		builtin_libogg=no
-		builtin_libpng=no
-		builtin_libtheora=$(usex !theora)
-		builtin_libvorbis=no
-		builtin_libwebp=$(usex !webp)
-		builtin_mbedtls=no
-		builtin_miniupnpc=$(usex !upnp)
-		builtin_msdfgen=yes # not wired for unbundling nor packaged
-		builtin_pcre2=no
-		builtin_recast=no
-		builtin_rvo2=yes # bundled copy has godot-specific changes
-		builtin_squish=yes # ^ likewise, may not be safe to unbundle
-		builtin_wslay=no
-		builtin_xatlas=yes # not wired for unbundling nor packaged
-		builtin_zlib=no
-		builtin_zstd=no
-		# also bundled but lacking a builtin_* switch:
-		#	amd-fsr, basis_universal, cvtt, etcpak, fonts, glad,
-		#	jpeg-compressor, meshoptimizer, minimp3, minizip (patched to
-		#	seek in archives), noise, oidn, openxr, spirv-reflect, thorvg,
-		#	tinyexr, vhacd, vulkan, and the misc directory.
-
-		# modules with optional dependencies, "possible" to disable more but
-		# gets messy and breaks all sorts of features (expected enabled)
-		module_gridmap_enabled=$(usex deprecated) # fails without deprecated
-		module_mono_enabled=no # unhandled
-		# note raycast is only enabled on amd64+arm64, see raycast/config.py
-		module_raycast_enabled=$(usex gui $(usex tools $(usex raycast)))
-		module_theora_enabled=$(usex theora)
-		module_upnp_enabled=$(usex upnp)
-		module_webp_enabled=$(usex webp)
-
-		# let *FLAGS handle these, e.g. can pass -flto as-is
-		debug_symbols=no
-		lto=none
-		optimize=custom
-		use_static_cpp=no
-	)
-
-	if use runner && use tools; then
-		# build alternate faster + ~60% smaller binary for running
-		# games or servers without game development debug paths
-		escons extra_suffix=runner target=template_release "${esconsargs[@]}"
-	fi
-
-	esconsargs+=(
-		target=$(usex tools editor template_$(usex debug{,} release))
-		dev_build=$(usex debug)
-
-		# harmless but note this bakes in --test in the final binary
-		tests=$(usex tools $(usex test))
-	)
-
-	escons extra_suffix=main "${esconsargs[@]}"
-}
-
-src_test() {
-	xdg_environment_reset
-	bin/godot*.main --headless --test || die
-}
-
-src_install() {
-	local s=godot${SLOT}
-
-	newbin bin/godot*.main ${s}
-	if use runner && use tools; then
-		newbin bin/godot*.runner ${s}-runner
-	else
-		# always available, revdeps shouldn't depend on [runner]
-		dosym ${s} /usr/bin/${s}-runner
-	fi
-
-	newman misc/dist/linux/godot.6 ${s}.6
-	dodoc AUTHORS.md CHANGELOG.md DONORS.md README.md
-
-	if use gui; then
-		newicon icon.svg ${s}.svg
-		newmenu misc/dist/linux/org.godotengine.Godot.desktop \
-			org.godotengine.${s^}.desktop
-
-		insinto /usr/share/metainfo
-		newins misc/dist/linux/org.godotengine.Godot.appdata.xml \
-			org.godotengine.${s^}.appdata.xml
-
-		insinto /usr/share/mime/application
-		newins misc/dist/linux/org.godotengine.Godot.xml \
-			org.godotengine.${s^}.xml
-	fi
-
-	newbashcomp misc/dist/shell/godot.bash-completion ${s}
-	bashcomp_alias ${s}{,-runner}
-
-	insinto /usr/share/fish/vendor_completions.d
-	newins misc/dist/shell/godot.fish ${s}.fish
-	dosym ${s}.fish /usr/share/fish/vendor_completions.d/${s}-runner.fish
-
-	insinto /usr/share/zsh/site-functions
-	newins misc/dist/shell/_godot.zsh-completion _${s}
-	dosym _${s} /usr/share/zsh/site-functions/_${s}-runner
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if [[ ! ${REPLACING_VERSIONS} ]] && has_version ${CATEGORY}/${PN}:3; then
-		elog
-		elog "Remember to make backups before opening any Godot <=3.x projects in Godot 4."
-		elog "Automated migration is only partial, and it would be difficult to revert."
-	fi
-}