[gentoo-commits] repo/gentoo:master commit in: net-libs/libpsl/

["Sam James" <sam@gentoo.org>]

commit:     85b87fcaed4c750bfa90343e8fa122ce476728ea
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 27 10:36:34 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Dec 27 10:42:21 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=85b87fca

net-libs/libpsl: add 0.21.2

Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-libs/libpsl/Manifest             |  1 +
 net-libs/libpsl/libpsl-0.21.2.ebuild | 59 ++++++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/net-libs/libpsl/Manifest b/net-libs/libpsl/Manifest
index aa270fd801d1..7bd4b6bebd02 100644
--- a/net-libs/libpsl/Manifest
+++ b/net-libs/libpsl/Manifest
@@ -1 +1,2 @@
 DIST libpsl-0.21.1.tar.gz 9199351 BLAKE2B 87c72651303a7870fd3f742e9ce8028e0dd48d3ded78ae7dea317ce54b98975f372429399b6a2d6746fd8e074d6a3ed13772b6c173f96c3a86aa7d726fd75586 SHA512 a5084b9df4ff2a0b1f5074b20972efe0da846473396d27b57967c7f6aa190ab3c910b4bfc4f8f03802f08decbbad5820d850c36ad59610262ae37fe77de0c7f5
+DIST libpsl-0.21.2.tar.gz 7617025 BLAKE2B b50f805bb467dc3284bc91645a37a2208098ad809d3771c74ef13c3b8f6029a07ad80a56702c7e3d1a1125d272403c85dd97b64a28465b9ff2d095eaf94b9a4d SHA512 f1df72220bf4391d4701007100b0df66c833a2cbcb7481c9d13f0b9e0cad3b66d2d15d4b976e5bad60d2ad1540355112fa1acb07aa925c241d2d7cd20681c71d

diff --git a/net-libs/libpsl/libpsl-0.21.2.ebuild b/net-libs/libpsl/libpsl-0.21.2.ebuild
new file mode 100644
index 000000000000..0a8623f9e742
--- /dev/null
+++ b/net-libs/libpsl/libpsl-0.21.2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit meson-multilib python-any-r1
+
+DESCRIPTION="C library for the Public Suffix List"
+HOMEPAGE="https://github.com/rockdaboot/libpsl"
+SRC_URI="https://github.com/rockdaboot/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="icu +idn"
+
+RDEPEND="
+	icu? ( !idn? ( dev-libs/icu:=[${MULTILIB_USEDEP}] ) )
+	idn? (
+		dev-libs/libunistring:=[${MULTILIB_USEDEP}]
+		net-dns/libidn2:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+pkg_pretend() {
+	if use icu && use idn ; then
+		ewarn "\"icu\" and \"idn\" USE flags are enabled. Using \"idn\"."
+	fi
+}
+
+multilib_src_configure() {
+	local emesonargs=()
+
+	# Prefer idn even if icu is in USE as well
+	if use idn ; then
+		emesonargs+=(
+			-Druntime=libidn2
+			-Dbuiltin=true
+		)
+	elif use icu ; then
+		emesonargs+=(
+			-Druntime=libicu
+			-Dbuiltin=true
+		)
+	else
+		emesonargs+=(
+			-Druntime=no
+		)
+	fi
+
+	meson_src_configure
+}