[gentoo-commits] repo/gentoo:master commit in: sci-libs/htslib/

["David Seifert" <soap@gentoo.org>]

commit:     19c25897b24fd3699dc126bfb89af9d409ff0a71
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 27 00:06:43 2022 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Tue Dec 27 00:06:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=19c25897

sci-libs/htslib: add 1.16

Signed-off-by: David Seifert <soap <AT> gentoo.org>

 sci-libs/htslib/Manifest           |  1 +
 sci-libs/htslib/htslib-1.16.ebuild | 52 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/sci-libs/htslib/Manifest b/sci-libs/htslib/Manifest
index f5b37a27ae5a..b8eaa4248e7d 100644
--- a/sci-libs/htslib/Manifest
+++ b/sci-libs/htslib/Manifest
@@ -1 +1,2 @@
 DIST htslib-1.15.1.tar.bz2 4141140 BLAKE2B 312f67c8916586199b32b7703b43a9fd365b8af22802bf4d63fc40960c62b956915e7c60bbd777a8b179066608cd3a281929a10b60eef21d6eedb4caf8c147c1 SHA512 69d0c7f3ac50a9b9c579e9b3479b6745fc30d0ac838ff14695cf4e3da593854350e345ed1f4a496931ef57395f3416da4316903488f3e641f1e00fec544f3620
+DIST htslib-1.16.tar.bz2 4466776 BLAKE2B 4957dd7a25b3d0b939d4e924db018916a5f8a13a81e55ebd1ce1acc548986e581d017ead9a08245a4af1ebdcd15536f082425ebe05f16eb4faad27d332e48482 SHA512 9fa0b1f9bba50f889d4542825c9543fb3b34c13b4cc0e18940a66fafd130749574bfa2c2663d8b39f0b4ed2b298bf130367cda1b17b2929093d64b386730cbc5

diff --git a/sci-libs/htslib/htslib-1.16.ebuild b/sci-libs/htslib/htslib-1.16.ebuild
new file mode 100644
index 000000000000..c4bd910685de
--- /dev/null
+++ b/sci-libs/htslib/htslib-1.16.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="C library for high-throughput sequencing data formats"
+HOMEPAGE="http://www.htslib.org/"
+SRC_URI="https://github.com/samtools/${PN}/releases/download/${PV}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0/3"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+bzip2 curl +lzma"
+
+RDEPEND="
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	curl? ( net-misc/curl )
+	lzma? ( app-arch/xz-utils )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# upstream injects LDFLAGS into the .pc file,
+	# which is a big nono for QA
+	sed -e '/^\(static_l\|Libs.private\|Requires.private\)/d' \
+		-i htslib.pc.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-gcs \
+		--disable-plugins \
+		--disable-s3 \
+		$(use_enable bzip2 bz2) \
+		$(use_enable curl libcurl) \
+		$(use_enable lzma)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+
+	# doesn't use libtool, can't disable static libraries
+	find "${ED}" -name '*.a' -delete || die
+}