[gentoo-commits] repo/gentoo:master commit in: dev-util/gn/

["Stephan Hartmann" <sultan@gentoo.org>]

commit:     2c85c6a0d5dc202b36ab1e29ad374c10998d7df5
Author:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 24 14:34:47 2022 +0000
Commit:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
CommitDate: Sat Dec 24 14:34:59 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2c85c6a0

dev-util/gn: add 0.2077

Signed-off-by: Stephan Hartmann <sultan <AT> gentoo.org>

 dev-util/gn/Manifest         |  1 +
 dev-util/gn/gn-0.2077.ebuild | 64 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/dev-util/gn/Manifest b/dev-util/gn/Manifest
index 13f3fe2dada5..30569d413f40 100644
--- a/dev-util/gn/Manifest
+++ b/dev-util/gn/Manifest
@@ -1 +1,2 @@
 DIST gn-0.2049.tar.xz 727960 BLAKE2B fe93d09c1fa5b6267a4d26f37ec42e629b36645ef58bf6ebcc07dd8cd2ee9509c1e997182251a3e2c3ef3c5b7d636c9a8228c1e49d1d7245b3ebdac36e7c5a1a SHA512 f3e6dc87d647702c5d22793e2eed3e9950f8c9a6d7178eae67bb7d6518b6533c74fa3f43245fb9e422994a27f1a0f1986709f91e7ce2ed78eb5f17838f75e1db
+DIST gn-0.2077.tar.xz 735596 BLAKE2B 48da6c1b08746d364974c94a8395708ba44f4fb88a4bd6142d8ce3935608538b3e3d316c1b3934b124bb2af8549e0bc355b4f0990ab0b794adca025a4c3db7c5 SHA512 361fa1d71f4c4ed12fec8136fb79ee8d30cd8c9b93f2d9972222e028a8b74326045f000431863c6d7ab598b1d7b06c00c95793830da48f52e623a1246bcc8bc4

diff --git a/dev-util/gn/gn-0.2077.ebuild b/dev-util/gn/gn-0.2077.ebuild
new file mode 100644
index 000000000000..153f7c27a677
--- /dev/null
+++ b/dev-util/gn/gn-0.2077.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2018-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit ninja-utils python-any-r1 toolchain-funcs
+
+DESCRIPTION="GN is a meta-build system that generates build files for Ninja"
+HOMEPAGE="https://gn.googlesource.com/"
+SRC_URI="https://dev.gentoo.org/~sultan/distfiles/dev-util/gn/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="vim-syntax"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/ninja
+"
+
+PATCHES=(
+	"${FILESDIR}"/gn-gen-r5.patch
+)
+
+pkg_setup() {
+	:
+}
+
+src_configure() {
+	python_setup
+	tc-export AR CC CXX
+	unset CFLAGS
+	set -- ${EPYTHON} build/gen.py --no-last-commit-position --no-strip --no-static-libstdc++ --allow-warnings
+	echo "$@" >&2
+	"$@" || die
+	cat >out/last_commit_position.h <<-EOF || die
+	#ifndef OUT_LAST_COMMIT_POSITION_H_
+	#define OUT_LAST_COMMIT_POSITION_H_
+	#define LAST_COMMIT_POSITION_NUM ${PV##0.}
+	#define LAST_COMMIT_POSITION "${PV}"
+	#endif  // OUT_LAST_COMMIT_POSITION_H_
+	EOF
+}
+
+src_compile() {
+	eninja -C out gn
+}
+
+src_test() {
+	eninja -C out gn_unittests
+	out/gn_unittests || die
+}
+
+src_install() {
+	dobin out/gn
+	einstalldocs
+
+	if use vim-syntax; then
+		insinto /usr/share/vim/vimfiles
+		doins -r misc/vim/{autoload,ftdetect,ftplugin,syntax}
+	fi
+}