[gentoo-commits] repo/gentoo:master commit in: app-text/cherrytree/

["Sam James" <sam@gentoo.org>]

commit:     ec8082d8a9bd808d863f0f24863e8d1cc4c1a4ee
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Wed Dec 21 23:07:58 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Dec 21 23:09:15 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ec8082d8

app-text/cherrytree: add 0.99.53

Closes: https://github.com/gentoo/gentoo/pull/28469
Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-text/cherrytree/cherrytree-0.99.53.ebuild | 74 +++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)

diff --git a/app-text/cherrytree/cherrytree-0.99.53.ebuild b/app-text/cherrytree/cherrytree-0.99.53.ebuild
new file mode 100644
index 000000000000..49820446e2a1
--- /dev/null
+++ b/app-text/cherrytree/cherrytree-0.99.53.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit cmake python-any-r1 xdg
+
+DESCRIPTION="A hierarchical note taking application (C++ version)"
+HOMEPAGE="https://www.giuspen.com/cherrytree/"
+
+SRC_URI="https://github.com/giuspen/cherrytree/releases/download/${PV}/${P/-/_}.tar.xz"
+S="${WORKDIR}"/${P/-/_}
+
+KEYWORDS="~amd64 ~x86"
+
+# GPL-3 — future/src/ct (CherryTree)
+# LGPL-2.1 — future/src/7za (7zip)
+# MIT — future/src/fmt (libfmt)
+LICENSE="GPL-3 LGPL-2.1 MIT"
+SLOT="0"
+IUSE="nls test"
+
+# Has deps that aren't available in ::gentoo repo
+RESTRICT="test"
+
+RDEPEND="app-i18n/uchardet
+	app-text/gspell:=
+	>=dev-cpp/glibmm-2.64.2:2
+	dev-cpp/gtkmm:3.0
+	dev-cpp/gtksourceviewmm:3.0
+	dev-cpp/libxmlpp:2.6
+	dev-cpp/pangomm:1.4
+	dev-db/sqlite:3
+	dev-libs/fribidi
+	dev-libs/glib:2
+	dev-libs/libfmt:=
+	dev-libs/libxml2:2
+	dev-libs/spdlog
+	gui-libs/vte:2.91-gtk4
+	net-misc/curl
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/pango"
+
+DEPEND="${PYTHON_DEPS}
+	${RDEPEND}"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( dev-util/cpputest )"
+
+src_prepare() {
+	# disable compress man pages
+	sed -i -e \
+		'/install(FILES/s|${MANFILE_FULL_GZ}|${CMAKE_SOURCE_DIR}/data/cherrytree.1|' \
+		CMakeLists.txt || die
+
+	# python_fix_shebang .
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPYTHON_EXEC="${PYTHON}"
+		-DUSE_NLS=$(usex nls)
+		-DBUILD_TESTING=$(usex test)
+		-DUSE_SHARED_FMT_SPDLOG=ON
+	)
+
+	cmake_src_configure
+}