[gentoo-commits] repo/gentoo:master commit in: media-libs/libraw/

["Sam James" <sam@gentoo.org>]

commit:     6a42d29813dc7ed4de374803b65bbc779746a45e
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 20 08:13:09 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Dec 20 08:14:36 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6a42d298

media-libs/libraw: add 0.21.0

Closes: https://bugs.gentoo.org/830441
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-libs/libraw/Manifest             |  1 +
 media-libs/libraw/libraw-0.21.0.ebuild | 60 ++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/media-libs/libraw/Manifest b/media-libs/libraw/Manifest
index c52249f7f093..edfb5a789256 100644
--- a/media-libs/libraw/Manifest
+++ b/media-libs/libraw/Manifest
@@ -1 +1,2 @@
 DIST LibRaw-0.20.2.tar.gz 1432141 BLAKE2B 6e41d91b560951ad4595c41a1d089505ca91337f4fc6b98bafe44211971bee143709482a070bacb7daebbd643bbbf17730f544d791c0237bf1689a7a59133079 SHA512 96b1aaf09e2d46448d1b3619270c1f1c32e9bcbd866567cec67d5b1f889362f0fae3f3533ea9bf6a11a917be3b61ee6c9938bad09209d93453039ed04eaeae4a
+DIST LibRaw-0.21.0.tar.gz 1638463 BLAKE2B 1a87417e73f22411661bb6150c12dda745d931975f76357496ab92e6f48b5a1e6e7a907bd6ae8d0655f4250c4524290fec8130955da1cabaedfe6a238253274b SHA512 af5a7361d39ea77315e883eff3afe8aa7d998e65afa6da5019368b46eef862e275bf6eadc095d626573a821de9b86e76dc2bfa955382a4bd030f97b30699f149

diff --git a/media-libs/libraw/libraw-0.21.0.ebuild b/media-libs/libraw/libraw-0.21.0.ebuild
new file mode 100644
index 000000000000..47594160ed5d
--- /dev/null
+++ b/media-libs/libraw/libraw-0.21.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal toolchain-funcs
+
+MY_PN=LibRaw
+MY_PV="${PV/_b/-B}"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="LibRaw is a library for reading RAW files obtained from digital photo cameras"
+HOMEPAGE="https://www.libraw.org/ https://github.com/LibRaw/LibRaw"
+SRC_URI="https://www.libraw.org/data/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1 CDDL"
+# SONAME isn't exactly the same as PV but it does correspond and
+# libraw has unstable ABI across releases.
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples jpeg +lcms openmp zlib"
+
+RDEPEND="
+	jpeg? ( media-libs/libjpeg-turbo:=[${MULTILIB_USEDEP}] )
+	lcms? ( >=media-libs/lcms-2.5:2[${MULTILIB_USEDEP}] )
+	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( Changelog.txt README.md )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-jasper
+		$(multilib_native_use_enable examples)
+		$(use_enable jpeg)
+		$(use_enable lcms)
+		$(use_enable openmp)
+		$(use_enable zlib)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	# package installs .pc files
+	find "${D}" -name '*.la' -delete || die
+}