[gentoo-commits] repo/gentoo:master commit in: dev-games/clanlib/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     77059bc5662b164e9583e31dc3e29e8f79a5c069
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 19 06:28:08 2022 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Mon Dec 19 07:11:34 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=77059bc5

dev-games/clanlib: drop 2.3.7-r2

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 dev-games/clanlib/clanlib-2.3.7-r2.ebuild | 108 ------------------------------
 1 file changed, 108 deletions(-)

diff --git a/dev-games/clanlib/clanlib-2.3.7-r2.ebuild b/dev-games/clanlib/clanlib-2.3.7-r2.ebuild
deleted file mode 100644
index 600c112305e3..000000000000
--- a/dev-games/clanlib/clanlib-2.3.7-r2.ebuild
+++ /dev/null
@@ -1,108 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools toolchain-funcs
-
-MY_P=ClanLib-${PV}
-DESCRIPTION="Multi-platform game development library"
-HOMEPAGE="http://www.clanlib.org/"
-SRC_URI="http://clanlib.org/download/releases-2.0/${MY_P}.tgz"
-S="${WORKDIR}"/${MY_P}
-
-LICENSE="ZLIB"
-SLOT="2.3"
-# Not big endian safe! #82779
-KEYWORDS="amd64 x86"
-IUSE="doc ipv6 mikmod opengl sound sqlite cpu_flags_x86_sse2 static-libs vorbis X"
-REQUIRED_USE="opengl? ( X )"
-
-BDEPEND="
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen dev-lang/perl )
-"
-RDEPEND="
-	sys-libs/zlib
-	X? (
-		app-arch/bzip2
-		media-libs/libpng:0
-		media-libs/freetype
-		media-libs/fontconfig
-		virtual/jpeg:0
-		x11-libs/libX11
-		opengl? ( virtual/opengl )
-	)
-	mikmod? (
-		media-libs/alsa-lib
-		media-libs/libmikmod
-	)
-	sqlite? ( dev-db/sqlite:3 )
-	sound? ( media-libs/alsa-lib )
-	vorbis? (
-		media-libs/alsa-lib
-		media-libs/libogg
-		media-libs/libvorbis
-	)
-"
-DEPEND="${RDEPEND}"
-
-PATCHES=(
-	"${FILESDIR}"/${P}-autotools.patch
-	"${FILESDIR}"/${P}-doc.patch
-	"${FILESDIR}"/${P}-freetype_pkgconfig.patch #764902
-	"${FILESDIR}"/${P}-glibc2.34.patch
-	"${FILESDIR}"/${P}-32bit-opengl.patch
-)
-
-DOCS=( CODING_STYLE CREDITS PATCHES README )
-
-src_prepare() {
-	default
-
-	eautoreconf
-
-	ln -sf ../../../Sources/API Documentation/Utilities/ReferenceDocs/ClanLib || die
-}
-
-src_configure() {
-	# Add -DPACKAGE_BUGREPORT?
-	local myeconfargs=(
-		$(use_enable doc docs)
-		$(use_enable cpu_flags_x86_sse2 sse2)
-		$(use_enable opengl clanGL)
-		$(use_enable opengl clanGL1)
-		$(use_enable opengl clanGUI)
-		$(use_enable X clanDisplay)
-		$(use_enable vorbis clanVorbis)
-		$(use_enable mikmod clanMikMod)
-		$(use_enable sqlite clanSqlite)
-		$(use_enable ipv6 getaddr)
-	)
-
-	use sound \
-		|| use vorbis \
-		|| use mikmod \
-		|| myeconfargs+=( --disable-clanSound )
-
-	tc-export PKG_CONFIG
-
-	econf "${myeconfargs[@]}"
-}
-
-src_compile() {
-	emake
-
-	use doc && emake html
-}
-
-# html files are keeped in a directory that is dependent on the SLOT
-# so to keep eventual bookmarks to the doc from version to version
-src_install() {
-	default
-
-	if use doc ; then
-		emake DESTDIR="${D}" install-html
-		dodoc -r Examples Resources
-	fi
-}