[gentoo-commits] repo/gentoo:master commit in: www-client/microsoft-edge/

["Stephan Hartmann" <sultan@gentoo.org>]

commit:     2f3b8f2fa05d2021ef8eb1d33c29d2c012b2c745
Author:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 17 19:22:08 2022 +0000
Commit:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
CommitDate: Sat Dec 17 19:29:29 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2f3b8f2f

www-client/microsoft-edge: remove old

Signed-off-by: Stephan Hartmann <sultan <AT> gentoo.org>

 www-client/microsoft-edge/Manifest                 |   1 -
 .../microsoft-edge-108.0.1462.46.ebuild            | 117 ---------------------
 2 files changed, 118 deletions(-)

diff --git a/www-client/microsoft-edge/Manifest b/www-client/microsoft-edge/Manifest
index 6947f3d45195..10f3a7106225 100644
--- a/www-client/microsoft-edge/Manifest
+++ b/www-client/microsoft-edge/Manifest
@@ -1,2 +1 @@
-DIST microsoft-edge-stable_108.0.1462.46-1_amd64.deb 137634906 BLAKE2B 6f7f5a0124e9924869890a19f28a6712f6a27277b229fe2cb54828f0d7fc12f62599512269531de87a4b642489604259d5a3a9bc03c29dab2e2c03b76f9339c7 SHA512 2f47658c2674e8529a924c03cafc9a73a77f74bc6781b2faf9471956cff80c70bc36816a9a374f79d613def96833bbf25287601c0534806b55b7673ff0a59185
 DIST microsoft-edge-stable_108.0.1462.54-1_amd64.deb 137832478 BLAKE2B 3518b1cdb2ad4d2afea2d3d0f90fb2ac96555072bdee1ca7a553d798a0234ad684435a36d26490f2884d0b700215e81529ba959cb5f9bbb0f1f9c5456f371842 SHA512 57ac49ba190bac2802bb9685769b6d90188fd9339176f31af5a57f233205405efd3e73d2163730eb4dc086a364f90d5a69cdccf5e40cc3e9af5c9d794aa678ff

diff --git a/www-client/microsoft-edge/microsoft-edge-108.0.1462.46.ebuild b/www-client/microsoft-edge/microsoft-edge-108.0.1462.46.ebuild
deleted file mode 100644
index 47d0b386f658..000000000000
--- a/www-client/microsoft-edge/microsoft-edge-108.0.1462.46.ebuild
+++ /dev/null
@@ -1,117 +0,0 @@
-# Copyright 2011-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="8"
-
-inherit chromium-2 desktop pax-utils unpacker xdg
-
-DESCRIPTION="The web browser from Microsoft"
-HOMEPAGE="https://www.microsoft.com/en-us/edge"
-
-if [[ ${PN} == microsoft-edge ]]; then
-	MY_PN=${PN}-stable
-else
-	MY_PN=${PN}
-fi
-
-KEYWORDS="-* amd64"
-
-MY_P="${MY_PN}_${PV}-1"
-
-SRC_URI="https://packages.microsoft.com/repos/edge/pool/main/m/${MY_PN}/${MY_P}_amd64.deb"
-
-LICENSE="microsoft-edge"
-SLOT="0"
-RESTRICT="bindist mirror strip"
-IUSE="+mip"
-
-RDEPEND="
-	|| (
-		>=app-accessibility/at-spi2-core-2.46.0:2
-		( app-accessibility/at-spi2-atk dev-libs/atk )
-	)
-	app-misc/ca-certificates
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/nspr
-	dev-libs/nss
-	media-fonts/liberation-fonts
-	media-libs/alsa-lib
-	media-libs/mesa[gbm(+)]
-	net-misc/curl[ssl]
-	net-print/cups
-	sys-apps/dbus
-	sys-apps/util-linux
-	sys-libs/glibc
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf:2
-	x11-libs/gtk+:3[X]
-	x11-libs/libdrm
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libXrandr
-	x11-libs/libxcb
-	x11-libs/libxkbcommon
-	x11-libs/libxshmfence
-	x11-libs/pango
-	x11-misc/xdg-utils
-	mip? ( app-crypt/libsecret )
-"
-
-QA_PREBUILT="*"
-QA_DESKTOP_FILE="usr/share/applications/microsoft-edge.*\\.desktop"
-S=${WORKDIR}
-EDGE_HOME="opt/microsoft/msedge${PN#microsoft-edge}"
-
-pkg_nofetch() {
-	eerror "Please wait 24 hours and sync your tree before reporting a bug for microsoft-edge fetch failures."
-}
-
-pkg_pretend() {
-	# Protect against people using autounmask overzealously
-	use amd64 || die "microsoft-edge only works on amd64"
-}
-
-pkg_setup() {
-	chromium_suid_sandbox_check_kernel_config
-}
-
-src_unpack() {
-	:
-}
-
-src_install() {
-	dodir /
-	cd "${ED}" || die
-	unpacker
-
-	rm -f _gpgorigin || die
-
-	rm -r etc usr/share/menu || die
-	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
-
-	gzip -d usr/share/doc/${PF}/changelog.gz || die
-	gzip -d usr/share/man/man1/${MY_PN}.1.gz || die
-	if [[ -L usr/share/man/man1/${PN}.1.gz ]]; then
-		rm usr/share/man/man1/${PN}.1.gz || die
-		dosym ${MY_PN}.1 usr/share/man/man1/${PN}.1
-	fi
-
-	local suffix=
-	[[ ${PN} == microsoft-edge-beta ]] && suffix=_beta
-	[[ ${PN} == microsoft-edge-dev ]] && suffix=_dev
-
-	local size
-	for size in 16 24 32 48 64 128 256 ; do
-		newicon -s ${size} "${EDGE_HOME}/product_logo_${size}${suffix}.png" ${PN}.png
-	done
-
-	if ! use mip; then
-		rm "${EDGE_HOME}"/libmip_{core,protection_sdk}.so || die
-	fi
-
-	pax-mark m "${EDGE_HOME}/msedge"
-}