[gentoo-commits] repo/gentoo:master commit in: app-misc/liquidctl/

["Stephan Hartmann" <sultan@gentoo.org>]

commit:     48ec3b8115eca5ecf31d0e539c74e083ec1d6791
Author:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 17 15:38:01 2022 +0000
Commit:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
CommitDate: Sat Dec 17 15:38:01 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=48ec3b81

app-misc/liquidctl: add 1.11.1

Signed-off-by: Stephan Hartmann <sultan <AT> gentoo.org>

 app-misc/liquidctl/Manifest                |  1 +
 app-misc/liquidctl/liquidctl-1.11.1.ebuild | 53 ++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/app-misc/liquidctl/Manifest b/app-misc/liquidctl/Manifest
index 98e326679412..fd09f0a631a6 100644
--- a/app-misc/liquidctl/Manifest
+++ b/app-misc/liquidctl/Manifest
@@ -1 +1,2 @@
 DIST liquidctl-1.10.0.tar.gz 1807672 BLAKE2B e7f06ed51c82f0f1fcf5e3adfca1f84040373b1010246eca9f74a170019e53acecc588772708753585fc9c8491e00fd0fa5a1ecd991bef6507e5042431519199 SHA512 3e86078d8d9f985f60a52a13778b14712dc56a7574a885bb4238bdce7ebb1bcc80c29e560c47e4d0523b621e9d3c7faf2e28631e20e45c083e365024327ba5a2
+DIST liquidctl-1.11.1.tar.gz 1836371 BLAKE2B e302251855b48405d811287061df3593f0549f02d8d369ae0c0178c27722b69e3c589763de5a963e2b2a37d88f3213e649da9e6f74db59a36f9b803d33d2b038 SHA512 06c11eb0bb258ec4111e885d5ed2bf89842fc0a9bfbc57aee6c86d405808d9bd9582fa137beac7250949448454412d03ade0bc3ee16cd3bd8de3fff66a0cc1bf

diff --git a/app-misc/liquidctl/liquidctl-1.11.1.ebuild b/app-misc/liquidctl/liquidctl-1.11.1.ebuild
new file mode 100644
index 000000000000..82826078f384
--- /dev/null
+++ b/app-misc/liquidctl/liquidctl-1.11.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 udev
+
+DESCRIPTION="Cross-platform tool and drivers for liquid coolers and other devices"
+HOMEPAGE="https://github.com/liquidctl/liquidctl"
+SRC_URI="https://github.com/liquidctl/liquidctl/releases/download/v${PV}/${P}.tar.gz"
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/crcmod[${PYTHON_USEDEP}]
+	dev-python/docopt[${PYTHON_USEDEP}]
+	dev-python/hidapi[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pyusb[${PYTHON_USEDEP}]
+	sys-apps/i2c-tools[${PYTHON_USEDEP},python]
+"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	# Without this variable, it attempts to write to /var/run and fails
+	XDG_RUNTIME_DIR="${T}/xdg" distutils-r1_src_test || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	dodoc docs/*.md
+	dodoc -r docs/linux/
+
+	udev_dorules extra/linux/71-liquidctl.rules
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}