[gentoo-commits] repo/gentoo:master commit in: net-misc/networkmanager/

["Matt Turner" <mattst88@gentoo.org>]

commit:     2e7f7fe75b600f8f4ab142736d2894180e23feaf
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 16 18:56:37 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Dec 16 19:44:41 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2e7f7fe7

net-misc/networkmanager: Version bump to 1.40.8

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-misc/networkmanager/Manifest                   |   1 +
 .../networkmanager/networkmanager-1.40.8.ebuild    | 418 +++++++++++++++++++++
 2 files changed, 419 insertions(+)

diff --git a/net-misc/networkmanager/Manifest b/net-misc/networkmanager/Manifest
index 32a55312625a..0315969dd12f 100644
--- a/net-misc/networkmanager/Manifest
+++ b/net-misc/networkmanager/Manifest
@@ -1,2 +1,3 @@
 DIST NetworkManager-1.40.2.tar.xz 6585760 BLAKE2B 12bd809e0d5140ecb1f52f61680fbd21044350d0c265bfff2ac812f977a7db5c5342a0302b6f02b057ce675ab917f449106e4bb1bb9b1d187066e076785ed951 SHA512 b79119d11ad98262a22a3f78a7dfa979a7890682f97ed8154552f7ceb964402fc9c2dcda082bf80ba45d7f717f541d3145e40f7f6c4fbb8f2858272cc9505761
 DIST NetworkManager-1.40.6.tar.xz 6596776 BLAKE2B 32e2a496d68d183a44a15f9ecfef18f5c7fcbc7ba5e27e0eb62825edb0ebbcf8ec34dcdd6d4da953aa46029d7063197f549cae13eb3622dd1f52c92aa5961941 SHA512 cd8ced0598ea4224cfde23a157108c872bb3935e539029571110b6a0bb4bf3637ad8e3afe8e5f162890ed557e8b42a803bc4e18db00e1de840dd0fa20643e036
+DIST NetworkManager-1.40.8.tar.xz 6518080 BLAKE2B 90a65dde96b3127a5438aa4add47e66887c940a86598109bde74f9bc56d317c41f835858a0b2ea89dca228f7fcc43e811b20e0d4528018ebe95947114f405cb4 SHA512 1c3f986c0f37160fced3cc790f6e569ae2185aec2bb2b5ef9635848ba493d4e920cc7ea83cd34a8df7bc12902d071238f9ae6aeb7721658ac54ba862f7c822ef

diff --git a/net-misc/networkmanager/networkmanager-1.40.8.ebuild b/net-misc/networkmanager/networkmanager-1.40.8.ebuild
new file mode 100644
index 000000000000..e9b9b65cab73
--- /dev/null
+++ b/net-misc/networkmanager/networkmanager-1.40.8.ebuild
@@ -0,0 +1,418 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+GNOME_ORG_MODULE="NetworkManager"
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org linux-info meson-multilib python-any-r1 readme.gentoo-r1 systemd toolchain-funcs udev vala virtualx
+
+DESCRIPTION="A set of co-operative tools that make networking simple and straightforward"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+
+IUSE="audit bluetooth +concheck connection-sharing debug dhclient dhcpcd elogind gnutls +gtk-doc +introspection iptables iwd psl libedit lto +nss nftables +modemmanager ofono ovs policykit +ppp resolvconf selinux syslog systemd teamd test +tools vala +wext +wifi"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+	bluetooth? ( modemmanager )
+	connection-sharing? ( || ( iptables nftables ) )
+	gtk-doc? ( introspection )
+	iwd? ( wifi )
+	vala? ( introspection )
+	wext? ( wifi )
+	^^ ( gnutls nss )
+	?? ( elogind systemd )
+	?? ( dhclient dhcpcd )
+	?? ( syslog systemd )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+COMMON_DEPEND="
+	sys-apps/util-linux[${MULTILIB_USEDEP}]
+	elogind? ( >=sys-auth/elogind-219 )
+	>=virtual/libudev-175:=[${MULTILIB_USEDEP}]
+	sys-apps/dbus
+	net-libs/libndp
+	systemd? ( >=sys-apps/systemd-209:0= )
+	>=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.10.3:= )
+	selinux? (
+		sec-policy/selinux-networkmanager
+		sys-libs/libselinux
+	)
+	audit? ( sys-process/audit )
+	teamd? (
+		>=dev-libs/jansson-2.7:=
+		>=net-misc/libteam-1.9
+	)
+	policykit? ( >=sys-auth/polkit-0.106 )
+	nss? (
+		dev-libs/nspr[${MULTILIB_USEDEP}]
+		>=dev-libs/nss-3.11[${MULTILIB_USEDEP}]
+	)
+	gnutls? (
+		>=net-libs/gnutls-2.12:=[${MULTILIB_USEDEP}]
+	)
+	ppp? ( >=net-dialup/ppp-2.4.5:=[ipv6] )
+	modemmanager? (
+		net-misc/mobile-broadband-provider-info
+		>=net-misc/modemmanager-0.7.991:0=
+	)
+	bluetooth? ( >=net-wireless/bluez-5:= )
+	ofono? ( net-misc/ofono )
+	dhclient? ( >=net-misc/dhcp-4[client] )
+	dhcpcd? ( >=net-misc/dhcpcd-9.3.3 )
+	ovs? ( >=dev-libs/jansson-2.7:= )
+	resolvconf? ( virtual/resolvconf )
+	connection-sharing? (
+		net-dns/dnsmasq[dbus,dhcp]
+		iptables? ( net-firewall/iptables )
+		nftables? ( net-firewall/nftables )
+	)
+	psl? ( net-libs/libpsl )
+	concheck? ( net-misc/curl )
+	tools? (
+		>=dev-libs/newt-0.52.15
+		libedit? ( dev-libs/libedit )
+		!libedit? ( sys-libs/readline:= )
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	acct-group/plugdev
+	|| (
+		net-misc/iputils[arping(+)]
+		net-analyzer/arping
+	)
+	wifi? (
+		!iwd? ( >=net-wireless/wpa_supplicant-0.7.3-r3[dbus] )
+		iwd? ( net-wireless/iwd )
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=sys-kernel/linux-headers-3.18
+	net-libs/libndp[${MULTILIB_USEDEP}]
+	ppp? ( elibc_musl? ( net-libs/ppp-defs ) )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.1.2
+	)
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+	introspection? (
+		$(python_gen_any_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
+		dev-lang/perl
+		dev-libs/libxslt
+	)
+	vala? ( $(vala_depend) )
+	test? (
+		>=dev-libs/jansson-2.7
+		$(python_gen_any_dep '
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+			dev-python/pygobject:3[${PYTHON_USEDEP}]')
+	)
+"
+
+python_check_deps() {
+	if use introspection; then
+		python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" || return
+	fi
+	if use test; then
+		python_has_version "dev-python/dbus-python[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
+	fi
+}
+
+sysfs_deprecated_check() {
+	ebegin "Checking for SYSFS_DEPRECATED support"
+
+	if { linux_chkconfig_present SYSFS_DEPRECATED_V2; }; then
+		eerror "Please disable SYSFS_DEPRECATED_V2 support in your kernel config and recompile your kernel"
+		eerror "or NetworkManager will not work correctly."
+		eerror "See https://bugs.gentoo.org/333639 for more info."
+		die "CONFIG_SYSFS_DEPRECATED_V2 support detected!"
+	fi
+	eend $?
+}
+
+pkg_pretend() {
+	if use kernel_linux; then
+		get_version
+		if linux_config_exists; then
+			sysfs_deprecated_check
+		else
+			ewarn "Was unable to determine your kernel .config"
+			ewarn "Please note that if CONFIG_SYSFS_DEPRECATED_V2 is set in your kernel .config, NetworkManager will not work correctly."
+			ewarn "See https://bugs.gentoo.org/333639 for more info."
+		fi
+	fi
+}
+
+pkg_setup() {
+	if use connection-sharing; then
+		if kernel_is lt 5 1; then
+			CONFIG_CHECK="~NF_NAT_IPV4 ~NF_NAT_MASQUERADE_IPV4"
+		else
+			CONFIG_CHECK="~NF_NAT ~NF_NAT_MASQUERADE"
+		fi
+		linux-info_pkg_setup
+	fi
+
+	if use introspection || use test; then
+		python-any-r1_pkg_setup
+	fi
+
+	# bug 809695
+	if tc-is-clang && use lto; then
+		eerror "Clang does not support -flto-partition"
+		die "Please use gcc or turn off USE=lto flag when building with clang"
+	fi
+}
+
+src_prepare() {
+	DOC_CONTENTS="To modify system network connections without needing to enter the
+		root password, add your user account to the 'plugdev' group."
+
+	default
+	use vala && vala_setup
+
+	sed -i \
+		-e 's#/usr/bin/sed#/bin/sed#' \
+		data/84-nm-drivers.rules \
+		|| die
+}
+
+meson_nm_program() {
+	usex "$1" "-D${2:-$1}=$3" "-D${2:-$1}=no"
+}
+
+meson_nm_native_program() {
+	multilib_native_usex "$1" "-D${2:-$1}=$3" "-D${2:-$1}=no"
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		--localstatedir="${EPREFIX}/var"
+
+		-Dsystemdsystemunitdir=$(systemd_get_systemunitdir)
+		-Dsystem_ca_path=/etc/ssl/certs
+		-Dudev_dir=$(get_udevdir)
+		-Ddbus_conf_dir=/usr/share/dbus-1/system.d
+		-Dkernel_firmware_dir=/lib/firmware
+		-Diptables=/sbin/iptables
+		-Dnft=/sbin/nft
+		-Ddnsmasq=/usr/sbin/dnsmasq
+
+		-Ddist_version=${PVR}
+		$(meson_native_use_bool policykit polkit)
+		$(meson_native_use_bool policykit config_auth_polkit_default)
+		-Dmodify_system=true
+		-Dpolkit_agent_helper_1=/usr/lib/polkit-1/polkit-agent-helper-1
+		$(meson_native_use_bool selinux)
+		$(meson_native_use_bool systemd systemd_journal)
+		-Dhostname_persist=gentoo
+		-Dlibaudit=$(multilib_native_usex audit)
+
+		$(meson_native_use_bool wext)
+		$(meson_native_use_bool wifi)
+		$(meson_native_use_bool iwd)
+		$(meson_native_use_bool ppp)
+		-Dpppd=/usr/sbin/pppd
+		$(meson_native_use_bool modemmanager modem_manager)
+		$(meson_native_use_bool ofono)
+		$(meson_native_use_bool concheck)
+		$(meson_native_use_bool teamd teamdctl)
+		$(meson_native_use_bool ovs)
+		$(meson_native_use_bool tools nmcli)
+		$(meson_native_use_bool tools nmtui)
+		$(meson_native_use_bool tools nm_cloud_setup)
+		$(meson_native_use_bool bluetooth bluez5_dun)
+		-Debpf=true
+
+		-Dconfig_wifi_backend_default=$(multilib_native_usex iwd iwd default)
+		-Dconfig_plugins_default=keyfile
+		-Difcfg_rh=false
+		-Difupdown=false
+
+		$(meson_nm_native_program resolvconf "" /sbin/resolvconf)
+		-Dnetconfig=no
+		-Dconfig_dns_rc_manager_default=auto
+
+		$(meson_nm_program dhclient "" /sbin/dhclient)
+		-Ddhcpcanon=no
+		$(meson_nm_program dhcpcd "" /sbin/dhcpcd)
+
+		$(meson_native_use_bool introspection)
+		$(meson_native_use_bool vala vapi)
+		$(meson_native_use_bool gtk-doc docs)
+		-Dtests=$(multilib_native_usex test)
+		$(meson_native_true firewalld_zone)
+		-Dmore_asserts=0
+		$(meson_use debug more_logging)
+		-Dvalgrind=no
+		-Dvalgrind_suppressions=
+		-Dld_gc=false
+		$(meson_native_use_bool psl libpsl)
+		-Dqt=false
+
+		$(meson_use lto b_lto)
+	)
+
+	if multilib_is_native_abi && use systemd; then
+		emesonargs+=( -Dsession_tracking_consolekit=false )
+		emesonargs+=( -Dsession_tracking=systemd )
+		emesonargs+=( -Dsuspend_resume=systemd )
+	elif multilib_is_native_abi && use elogind; then
+		emesonargs+=( -Dsession_tracking_consolekit=false )
+		emesonargs+=( -Dsession_tracking=elogind )
+		emesonargs+=( -Dsuspend_resume=elogind )
+	else
+		emesonargs+=( -Dsession_tracking_consolekit=false )
+		emesonargs+=( -Dsession_tracking=no )
+		emesonargs+=( -Dsuspend_resume=auto )
+	fi
+
+	if multilib_is_native_abi && use syslog; then
+		emesonargs+=( -Dconfig_logging_backend_default=syslog )
+	elif multilib_is_native_abi && use systemd; then
+		emesonargs+=( -Dconfig_logging_backend_default=journal )
+	else
+		emesonargs+=( -Dconfig_logging_backend_default=default )
+	fi
+
+	if multilib_is_native_abi && use dhclient; then
+		emesonargs+=( -Dconfig_dhcp_default=dhclient )
+	elif multilib_is_native_abi && use dhcpcd; then
+		emesonargs+=( -Dconfig_dhcp_default=dhcpcd )
+	else
+		emesonargs+=( -Dconfig_dhcp_default=internal )
+	fi
+
+	if use nss; then
+		emesonargs+=( -Dcrypto=nss )
+	else
+		emesonargs+=( -Dcrypto=gnutls )
+	fi
+
+	if use tools ; then
+		emesonargs+=( -Dreadline=$(usex libedit libedit libreadline) )
+	else
+		emesonargs+=( -Dreadline=none )
+	fi
+
+	# Same hack as net-dialup/pptpd to get proper plugin dir for ppp, bug #519986
+	if use ppp; then
+		local PPPD_VER=`best_version net-dialup/ppp`
+		PPPD_VER=${PPPD_VER#*/*-} #reduce it to ${PV}-${PR}
+		PPPD_VER=${PPPD_VER%%[_-]*} # main version without beta/pre/patch/revision
+		emesonargs+=( -Dpppd_plugin_dir=/usr/$(get_libdir)/pppd/${PPPD_VER} )
+	fi
+
+	meson_src_configure
+}
+
+multilib_src_test() {
+	if use test && multilib_is_native_abi; then
+		python_setup
+		virtx meson_src_test
+	fi
+}
+
+multilib_src_install() {
+	meson_src_install
+	if ! multilib_is_native_abi; then
+		rm -r "${ED}"/{etc,usr/{bin,lib/NetworkManager,share},var} || die
+	fi
+}
+
+multilib_src_install_all() {
+	! use systemd && readme.gentoo_create_doc
+
+	newinitd "${FILESDIR}/init.d.NetworkManager-r2" NetworkManager
+	newconfd "${FILESDIR}/conf.d.NetworkManager" NetworkManager
+
+	# Need to keep the /etc/NetworkManager/dispatched.d for dispatcher scripts
+	keepdir /etc/NetworkManager/dispatcher.d
+
+	# Provide openrc net dependency only when nm is connected
+	exeinto /etc/NetworkManager/dispatcher.d
+	newexe "${FILESDIR}/10-openrc-status-r4" 10-openrc-status
+	sed -e "s:@EPREFIX@:${EPREFIX}:g" \
+		-i "${ED}/etc/NetworkManager/dispatcher.d/10-openrc-status" || die
+
+	keepdir /etc/NetworkManager/system-connections
+	chmod 0600 "${ED}"/etc/NetworkManager/system-connections/.keep* # bug #383765, upstream bug #754594
+
+	# Allow users in plugdev group to modify system connections
+	insinto /usr/share/polkit-1/rules.d/
+	doins "${FILESDIR}"/01-org.freedesktop.NetworkManager.settings.modify.system.rules
+
+	insinto /usr/lib/NetworkManager/conf.d #702476
+	doins "${S}"/examples/nm-conf.d/31-mac-addr-change.conf
+
+	if use iwd; then
+		# This goes to $nmlibdir/conf.d/ and $nmlibdir is '${prefix}'/lib/$PACKAGE, thus always lib, not get_libdir
+		cat <<-EOF > "${ED}"/usr/lib/NetworkManager/conf.d/iwd.conf || die
+		[device]
+		wifi.backend=iwd
+		EOF
+	fi
+
+	mv "${ED}"/usr/share/doc/{NetworkManager/examples/,${PF}} || die
+	rmdir "${ED}"/usr/share/doc/NetworkManager || die
+
+	# Empty
+	rmdir "${ED}"/var{/lib{/NetworkManager,},} || die
+}
+
+pkg_postinst() {
+	udev_reload
+
+	systemd_reenable NetworkManager.service
+	! use systemd && readme.gentoo_print_elog
+
+	if [[ -e "${EROOT}/etc/NetworkManager/nm-system-settings.conf" ]]; then
+		ewarn "The ${PN} system configuration file has moved to a new location."
+		ewarn "You must migrate your settings from ${EROOT}/etc/NetworkManager/nm-system-settings.conf"
+		ewarn "to ${EROOT}/etc/NetworkManager/NetworkManager.conf"
+		ewarn
+		ewarn "After doing so, you can remove ${EROOT}/etc/NetworkManager/nm-system-settings.conf"
+	fi
+
+	# NM fallbacks to plugin specified at compile time (upstream bug #738611)
+	# but still show a warning to remember people to have cleaner config file
+	if [[ -e "${EROOT}/etc/NetworkManager/NetworkManager.conf" ]]; then
+		if grep plugins "${EROOT}/etc/NetworkManager/NetworkManager.conf" | grep -q ifnet; then
+			ewarn
+			ewarn "You seem to use 'ifnet' plugin in ${EROOT}/etc/NetworkManager/NetworkManager.conf"
+			ewarn "Since it won't be used, you will need to stop setting ifnet plugin there."
+			ewarn
+		fi
+	fi
+
+	# NM shows lots of errors making nmcli almost unusable, bug #528748 upstream bug #690457
+	if grep -r "psk-flags=1" "${EROOT}"/etc/NetworkManager/; then
+		ewarn "You have psk-flags=1 setting in above files, you will need to"
+		ewarn "either reconfigure affected networks or, at least, set the flag"
+		ewarn "value to '0'."
+	fi
+
+	if use dhclient || use dhcpcd; then
+		ewarn "You have enabled USE=dhclient and/or USE=dhcpcd, but NetworkManager since"
+		ewarn "version 1.20 defaults to the internal DHCP client. If the internal client"
+		ewarn "works for you, and you're happy with, the alternative USE flags can be"
+		ewarn "disabled. If you want to use dhclient or dhcpcd, then you need to tweak"
+		ewarn "the main.dhcp configuration option to use one of them instead of internal."
+	fi
+}
+
+pkg_postrm() {
+	udev_reload
+}