[gentoo-commits] repo/gentoo:master commit in: www-client/opera-developer/

["Sam James" <sam@gentoo.org>]

commit:     d2af97466d215f73f5b5a38481bb97e4fe435834
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 13 04:44:25 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Dec 13 04:44:25 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d2af9746

www-client/opera-developer: automated bump (95.0.4632.0)

Signed-off-by: Sam James <sam <AT> gentoo.org>

 www-client/opera-developer/Manifest                |   1 +
 .../opera-developer-95.0.4632.0.ebuild             | 159 +++++++++++++++++++++
 2 files changed, 160 insertions(+)

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index 7b97b61a11d5..98a22d64585d 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,4 +1,5 @@
 DIST opera-developer_94.0.4597.0_amd64.deb 101526096 BLAKE2B 35828e9019decab9e15cee7d21facb097386e0dca9aa99220af9d6fbdeb62f23647102c449b10c70f2ff35987e77b3105762b5ff2e9c7274b2538c3db8529c0d SHA512 ecaa86c61334fef6fa7f0b0273827a4e629a790a629138fa8598273bf424b3d19a57db7d100730653a1a0b7b5023a9fb970ea3cc6969931926c9660ac975b0cd
 DIST opera-developer_94.0.4604.0_amd64.deb 101495804 BLAKE2B d9667862b20f3fa5078098e8e659dfc8abdb3618414ca257ec81e6b0e8c240f3529e700ebab5b3f267f9d0b554f213c7a6fdcf4d563d8f2820c829f5de836a20 SHA512 76f07a60145ff568b889288571c7ed7bdae64774131428f1676c66f38dc92b07a82212c671ba4952fa601855bcc16eb647305a5d5283ae12532304b20eaa88ad
 DIST opera-developer_95.0.4618.0_amd64.deb 99587420 BLAKE2B 10d13d6edfe3195b07facae22bee2454ef429305e35ea51d6360dc95c0139770415a0c762671340f6c283388cbb4be73a7360b81ada0f8f691fe7a99e6b1e036 SHA512 6334eb6c824a7ca119933a2695b3337290c70aa4a4a67e74b3376108cded7690e8969c7c83139f5dd02bb29b633b650304b6d7cf73afd9a441740031d75a8ca6
+DIST opera-developer_95.0.4632.0_amd64.deb 98941292 BLAKE2B 92ceb4005724e31586a15bbf8fa7232bcd7265d6e7fc16339d3dde2cb34110bc66d9fefe3f61d9b6d4ed366428b6b4c55e1b650a74d55b78fcc0bbc44f8795c1 SHA512 3c63e709b4b555b2d0ca9b68c43eef2d835150644536eed4619d9f8d1effb815d3aa391663ba2433206122440723931b7e23d7d2689bd0b199e10a5620840061
 DIST opera-ffmpeg-codecs-105.0.5195.19.tar.xz 1413912 BLAKE2B 52e951eb93b2ed91b4053002a43e79884c46aab7b2218a08717927e3f43bc247b340bafc18488fcf6596d4441c318d6fe734869c8daad047107aeff0fade4c71 SHA512 f29bc9146fa67b71fa2df83a9b731e9cb4ce7827a573b63fa1c10baba5980f0375cfab2c6e1edce01415753b6f3e0b65de7d361d9400550d7a2d637236e2e414

diff --git a/www-client/opera-developer/opera-developer-95.0.4632.0.ebuild b/www-client/opera-developer/opera-developer-95.0.4632.0.ebuild
new file mode 100644
index 000000000000..861830ed07f3
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-95.0.4632.0.ebuild
@@ -0,0 +1,159 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="105.0.5195.19"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	|| (
+		>=app-accessibility/at-spi2-core-2.46.0:2
+		( app-accessibility/at-spi2-atk dev-libs/atk )
+	)
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}