[gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-data-server/

["Matt Turner" <mattst88@gentoo.org>]

commit:     416bf7aebd2cc987556713781d47aa172d310c1a
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Dec  2 14:09:40 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Dec  2 14:35:32 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=416bf7ae

gnome-extra/evolution-data-server: Version bump to 3.46.2

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/evolution-data-server/Manifest         |   1 +
 .../evolution-data-server-3.46.2.ebuild            | 144 +++++++++++++++++++++
 2 files changed, 145 insertions(+)

diff --git a/gnome-extra/evolution-data-server/Manifest b/gnome-extra/evolution-data-server/Manifest
index 7016358b3c90..76a17f13d2c7 100644
--- a/gnome-extra/evolution-data-server/Manifest
+++ b/gnome-extra/evolution-data-server/Manifest
@@ -1,3 +1,4 @@
 DIST evolution-data-server-3.44.4.tar.xz 4784388 BLAKE2B dd5b7094af9c66b710d61de282ff7e223fd87524f0135b7fc2c962d7829a8ed25a90a5fa73d155b692e28d9d18807f8c8731efbfb32613e2e1a020008739beae SHA512 385137f1e412b5c5bcd496d493da4657f8bb6e72519f6e62ab1a683c729082ea0ddcf7b5dae8c0cdf37cb279a1cf59ffb6dd61009c693001d03a0d54264e979a
 DIST evolution-data-server-3.46.0.tar.xz 4817048 BLAKE2B 5c07137659132fca4e2e42d616d3b7e26317f44009de1c9582105a65036884c5b1f7521ac325e2a74a6493362a38b6761d78dabd00b9e64b51a352bcd1d225af SHA512 3aef4ef51e5be2c5e392a2b2781283bb75d8e7d08a3a0daae6be488d14e998779b992095d12889d2d6afe5c732394090f99fa9a866e8825eecdcde2bf6b24ec1
 DIST evolution-data-server-3.46.1.tar.xz 4843728 BLAKE2B 1053389277c9b8f83c80db382ba14db974a0674e75f728ac24a21e49f2c744c0239d19f380487487a2798db85706c5c0a7cb867508726e40034bcdcbb46da6c1 SHA512 6dbb9b192c46fdec25eb3587f90c5c2f3de902c80996d691978be519d7f7aad9946d3282c44febcf498bb8d497b639f3afeeead3f032bbb0cd1ddb380a0ca5e7
+DIST evolution-data-server-3.46.2.tar.xz 4883032 BLAKE2B 530f2cd40716373a0d865edadefb5789dae3b894f202ecfc55d2d2e9f1409e59e2914065e7247ac0749d6af54de7705720347d7f9d93a5376c967ec804c9e805 SHA512 570a14ea21c18be8626530562483c1f112c6f773b4502c7c16005abe516dd35d810985ed3cd4c89b993e5169474791ff3694999ef41a6fe53e2309450c7c7341

diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.46.2.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.46.2.ebuild
new file mode 100644
index 000000000000..dffda67c17a7
--- /dev/null
+++ b/gnome-extra/evolution-data-server/evolution-data-server-3.46.2.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake db-use flag-o-matic gnome2 vala virtualx
+
+DESCRIPTION="Evolution groupware backend"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution https://gitlab.gnome.org/GNOME/evolution-data-server"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
+SLOT="0/64-11-21-4-2-27-2-27-4-0" # subslot = libcamel-1.2/libebackend-1.2/libebook-1.2/libebook-contacts-1.2/libecal-2.0/libedata-book-1.2/libedata-cal-2.0/libedataserver-1.2/libedataserverui-1.2/libedataserverui4-1.0 soname version
+
+IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ldap kerberos oauth vala +weather"
+REQUIRED_USE="
+	oauth? ( gtk )
+	vala? ( introspection )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
+# glib-2.70 for build-time optional GPowerProfileMonitor
+RDEPEND="
+	>=app-crypt/libsecret-0.5[crypt]
+	>=dev-db/sqlite-3.7.17:3
+	>=dev-libs/glib-2.70:2
+	>=dev-libs/libical-3.0.8:=[glib,introspection?]
+	>=dev-libs/libxml2-2
+	>=dev-libs/nspr-4.4
+	>=dev-libs/nss-3.9
+	>=net-libs/libsoup-3.1.1:3.0
+	>=dev-libs/json-glib-1.0.4
+
+	dev-libs/icu:=
+	sys-libs/zlib:=
+	virtual/libiconv
+
+	berkdb? ( >=sys-libs/db-4:= )
+	gtk? (
+		>=x11-libs/gtk+-3.20:3
+		>=gui-libs/gtk-4.4:4
+		>=media-libs/libcanberra-0.25[gtk3]
+
+		oauth? (
+			>=net-libs/webkit-gtk-2.34.0:4.1
+			>=net-libs/webkit-gtk-2.36.0:5
+		)
+	)
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+	kerberos? ( virtual/krb5:= )
+	ldap? ( >=net-nds/openldap-2:= )
+	weather? ( >=dev-libs/libgweather-4.2.0:4= )
+"
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend)
+		>=net-libs/libsoup-3.1.1:3.0[vala]
+		dev-libs/libical[vala]
+	)
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/gperf
+	gtk-doc? ( >=dev-util/gtk-doc-1.14
+		app-text/docbook-xml-dtd:4.1.2 )
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Some tests fail due to missing locales.
+# Also, dbus tests are flaky, bugs #397975 #501834
+# It looks like a nightmare to disable those for now.
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
+src_prepare() {
+	use vala && vala_setup
+	cmake_src_prepare
+	gnome2_src_prepare
+
+	eapply "${FILESDIR}"/3.36.5-gtk-doc-1.32-compat.patch
+
+	# Make CMakeLists versioned vala enabled
+	sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
+	  -e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
+	  -i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+	# /usr/include/db.h is always db-1 on FreeBSD
+	# so include the right dir in CPPFLAGS
+	use berkdb && append-cppflags "-I$(db_includedir)"
+
+	# phonenumber does not exist in tree
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DENABLE_GTK_DOC=$(usex gtk-doc)
+		-DWITH_PRIVATE_DOCS=$(usex gtk-doc)
+		-DENABLE_SCHEMAS_COMPILE=OFF
+		-DENABLE_INTROSPECTION=$(usex introspection)
+		-DWITH_KRB5=$(usex kerberos)
+		-DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
+		-DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
+		-DWITH_OPENLDAP=$(usex ldap)
+		-DWITH_PHONENUMBER=OFF
+		-DENABLE_SMIME=ON
+		-DENABLE_GTK=$(usex gtk)
+		-DENABLE_GTK4=$(usex gtk)
+		-DENABLE_CANBERRA=$(usex gtk)
+		-DENABLE_OAUTH2_WEBKITGTK=$(usex oauth)
+		-DENABLE_OAUTH2_WEBKITGTK4=$(usex oauth)
+		-DENABLE_EXAMPLES=OFF
+		-DENABLE_GOA=$(usex gnome-online-accounts)
+		-DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
+		# ENABLE_BACKTRACES requires libdwarf ?
+		-DENABLE_IPV6=ON
+		-DENABLE_WEATHER=$(usex weather)
+		-DENABLE_LARGEFILE=ON
+		-DENABLE_VALA_BINDINGS=$(usex vala)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	if use ldap; then
+		insinto /etc/openldap/schema
+		doins "${FILESDIR}"/calentry.schema
+		dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
+	fi
+}