[gentoo-commits] repo/gentoo:master commit in: app-admin/vault/

["Zac Medico" <zmedico@gentoo.org>]

commit:     6cf223259ab025832540ba6c32beb69b0ba42007
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Thu Dec  1 04:52:50 2022 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Thu Dec  1 04:53:33 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6cf22325

app-admin/vault: add 1.12.2

Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 app-admin/vault/Manifest            |  2 +
 app-admin/vault/vault-1.12.2.ebuild | 86 +++++++++++++++++++++++++++++++++++++
 2 files changed, 88 insertions(+)

diff --git a/app-admin/vault/Manifest b/app-admin/vault/Manifest
index 492ac0c2039f..3172a34db5a4 100644
--- a/app-admin/vault/Manifest
+++ b/app-admin/vault/Manifest
@@ -10,3 +10,5 @@ DIST vault-1.12.0-vendor.tar.gz 53774794 BLAKE2B 2aa91274bcd3efe2c34c9acdc3000af
 DIST vault-1.12.0-webui.tar.xz 1413084 BLAKE2B 5f681ac61b14694e64be0a55445d0849b9b7481dc2456c923297f496b60d843ffae2d7f27b029ed33b4e7efd3029d99c1cb30110da3ad3162ee4135f3856d60e SHA512 4399f2e4c85712cd83b8265315186d6f7161fa545e0708a56ff7c56fbde335eb2ab9a357720850c0007e55679b94edbaadd3c2318671676e658f270f4d04de34
 DIST vault-1.12.1-vendor.tar.gz 53818036 BLAKE2B 58bf72efa345d737dd74a58bd56be3740d19fa5849d11f4aa4bc3ccb46ca42e84b1aa85bcf9f76e4ae5a72c3b954519a1ac989ff0f779c5fd25a42fe17b573c6 SHA512 55ccb2c61e6baf69627e1443ce6f524c2d6f8bf1ff59103173acd74e1a3a0a79a90a5dab95790f002ca7261e80c38dc2c8c27f95553bac65e2d0fa7f48254b23
 DIST vault-1.12.1-webui.tar.xz 1413308 BLAKE2B 1a6008bc67f08037a0dbd966d004c424b249597cd9f1002e30a23262bd1df6ddc388e7d863ff3f62350d8a4b3807de40a1d33da08ade1fe5ec84d4cecc64ade8 SHA512 87d30c77772fa982a110cfe4fa0d118b302796e7dcdfa71b94e6bd1cca0369cb0555169ef48acc68e16d11a1ab47ef096cc91e204be3189f4779125449cd9cd1
+DIST vault-1.12.2-vendor.tar.gz 53842063 BLAKE2B 42917c6310ca53254be9d6339a786902327074635297ad84fcacd2a73b9b2d974830f91f527116f6764ea8f848809944fd52e623c3ecc2ac88dae698aa6f4636 SHA512 8c6fd33c363099bda13a2992200356d4a877ff4c52ca4613f1cb2c8d2cbabaf0f9f760dcd6bcd3d4e4453324edce3efe07d27700f30bced85da0f56ef9321697
+DIST vault-1.12.2-webui.tar.xz 1413036 BLAKE2B 7d773274c27d93ca8f492d792390896b6b7ab0e52b3636428f182a62161049d1593aef5280826dd83535e9ad86e925edba234ca982f2c9d1d06d2012c9757779 SHA512 0076e7b75fc0d3c400022a95cc6abc4a9224fd76d3d9716f7d4a80e4856c9deb1890ba13e7e5adf86ee81486c2f530f2eb48e49d8bdb7fde6eab5bb83f815293

diff --git a/app-admin/vault/vault-1.12.2.ebuild b/app-admin/vault/vault-1.12.2.ebuild
new file mode 100644
index 000000000000..aaad01680cec
--- /dev/null
+++ b/app-admin/vault/vault-1.12.2.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps go-module systemd
+
+DESCRIPTION="A tool for managing secrets"
+HOMEPAGE="https://vaultproject.io/"
+
+VAULT_WEBUI_ARCHIVE="${P}-webui.tar.xz"
+SRC_URI="https://github.com/zmedico/vault/archive/refs/tags/v${PV}-vendor.tar.gz -> ${P}-vendor.tar.gz
+	webui? (
+		https://dev.gentoo.org/~zmedico/dist/${VAULT_WEBUI_ARCHIVE}
+	)"
+
+LICENSE="MPL-2.0 Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+IUSE="+webui"
+
+BDEPEND="
+	app-arch/zip
+	dev-go/gox
+	>=dev-lang/go-1.15.3"
+COMMON_DEPEND="acct-group/vault
+	acct-user/vault"
+	DEPEND="${COMMON_DEPEND}"
+	RDEPEND="${COMMON_DEPEND}"
+
+FILECAPS=(
+	-m 755 'cap_ipc_lock=+ep' usr/bin/${PN}
+)
+
+RESTRICT+=" test"
+S=${WORKDIR}/${P}-vendor
+
+src_unpack() {
+	default
+}
+
+src_prepare() {
+	default
+	# Avoid the need to have a git checkout
+	sed -e 's:^\(GIT_COMMIT=\).*:\1:' \
+		-e 's:^\(GIT_DIRTY=\).*:\1:' \
+		-e s:\'\${GIT_COMMIT}\${GIT_DIRTY}\':: \
+		-e "s|^BUILD_DATE=.*|BUILD_DATE=$(date +%Y-%m-%dT%H:%M:%SZ)|" \
+		-i scripts/build.sh || die
+	sed -e "/hooks/d" \
+		-e 's|^\([[:space:]]*\)goimports .*)|\1true|' \
+		-e "s/gofumpt/gofmt/g" \
+		-i Makefile || die
+	if [[ -d "${WORKDIR}/http/web_ui" ]]; then
+		rm -rf "${S}/http/web_ui" || die
+		mv "${WORKDIR}/http/web_ui" "${S}/http/web_ui" ||
+			die "mv failed"
+	else
+		mkdir -p "${S}/http/web_ui" || die
+		touch "${S}/http/web_ui/no_web_ui" || die
+	fi
+}
+
+src_compile() {
+	mkdir "${T}"/bin || die
+	BUILD_TAGS="$(usex webui ui '')" \
+	GOPATH="${T}" \
+	XC_ARCH=$(go env GOARCH) \
+	XC_OS=$(go env GOOS) \
+	XC_OSARCH=$(go env GOOS)/$(go env GOARCH) \
+	emake bin
+}
+
+src_install() {
+	dobin bin/${PN}
+	dodoc CHANGELOG.md CONTRIBUTING.md README.md
+	insinto /etc/${PN}.d
+	doins "${FILESDIR}/"*.json.example
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	keepdir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+}