[gentoo-commits] repo/gentoo:master commit in: dev-python/pdm-pep517/

["Michał Górny" <mgorny@gentoo.org>]

commit:     688f3e8a9c9d3ef0f2e3bb5433f03a80ceb7cc91
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 25 04:55:03 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Nov 25 05:14:28 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=688f3e8a

dev-python/pdm-pep517: Bump to 1.0.6

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pdm-pep517/Manifest                |  1 +
 dev-python/pdm-pep517/pdm-pep517-1.0.6.ebuild | 59 +++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-python/pdm-pep517/Manifest b/dev-python/pdm-pep517/Manifest
index 3e93e485cee0..6a13b3af642c 100644
--- a/dev-python/pdm-pep517/Manifest
+++ b/dev-python/pdm-pep517/Manifest
@@ -1,2 +1,3 @@
 DIST pdm-pep517-1.0.4.gh.tar.gz 314677 BLAKE2B dc6fad5bf6bd4aa6d9d490c6fb1df0d1a1543ae93f90ac4d53bbd515de6f6582a4fd032cc5c67aeebf71755fec6aac3b5a462a18eb08087c6a4da279e3c989ad SHA512 4edd016873c054f20efc39b8a044c2ff5dee70509c45ba1227e6982043dabb5ed0353afef4af73c88106ffe5a2c27f569077448fb27a0d58169710d2c6573c2f
 DIST pdm-pep517-1.0.5.gh.tar.gz 314932 BLAKE2B 5a0adce25de4aaa1d57d859223a3632c01f31d9be947384c9a1707fcb413f0a1d1434c9c6bee868ee0c668fa89cc78ef6d4831a4a2b1150607bc5f8173e61cd9 SHA512 e5cde819476187f4ad5caaa0dddb9409fbefb241e0548fb4ad9df4722de3c7b532aba969b399afade0bfd3d774ee5cdcd3bc9ece3a5ebfb2d5a2a6f3280a6ab5
+DIST pdm-pep517-1.0.6.gh.tar.gz 315755 BLAKE2B 7b221d9ddc9683521e901177cafd2ffd2908af4acbe083b4a7d6525a81ece64d3768331135451d45ffc5c40c67c8c72802d75d52fdf85fa89a13f30110436a13 SHA512 5aeef3179d508d2acaedf4b99df41e64b26537120e586a01870651d2b379e2e5a1bf42934ee28a4b285cb83fe10ead073408b6b7d022ca1f55653533d12a2da1

diff --git a/dev-python/pdm-pep517/pdm-pep517-1.0.6.ebuild b/dev-python/pdm-pep517/pdm-pep517-1.0.6.ebuild
new file mode 100644
index 000000000000..5efa042e7407
--- /dev/null
+++ b/dev-python/pdm-pep517/pdm-pep517-1.0.6.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-pep517/
+	https://github.com/pdm-project/pdm-pep517/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-pep517/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/cerberus-1.3.4[${PYTHON_USEDEP}]
+	dev-python/license-expression[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r pdm/pep517/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.pep517\._vendor\.:from :' \
+		-e 's:from pdm\.pep517\._vendor ::' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}