[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-shell-extension-gsconnect/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     1eb3388c8cfd885068bcc78d8e007f2b93f41ccb
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 24 08:03:54 2022 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Thu Nov 24 08:03:54 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1eb3388c

gnome-extra/gnome-shell-extension-gsconnect: add 54

Closes: https://bugs.gentoo.org/878085
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 .../gnome-shell-extension-gsconnect/Manifest       |  1 +
 .../gnome-shell-extension-gsconnect-54.ebuild      | 68 ++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/gnome-extra/gnome-shell-extension-gsconnect/Manifest b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
index 265251df5e2e..07ce23d0aaf2 100644
--- a/gnome-extra/gnome-shell-extension-gsconnect/Manifest
+++ b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
@@ -1 +1,2 @@
 DIST gnome-shell-extension-gsconnect-50.tar.gz 852893 BLAKE2B 2da626ac3a2c6a06b01a6d502a63a208c0bd603ba2d989b254c57d4feaaf693134b5fd176449eb2465be1d910eb8bddd5398dbe2fb00b9bfe0bec6a428f074af SHA512 39edad97388f8c228d9698c7f2fc51ea04d74f5e3bdeb16f387dc2f5bae87966c6d1a3d7eaf06cc1d095638df1254c3b796875d403912d0c39424965b395cbc8
+DIST gnome-shell-extension-gsconnect-54.tar.gz 879104 BLAKE2B 7d666775fc1ddf3ca76f59d2047b85cbc35f9953883941d1bca93f8711dcbf7ed5b8be697c300c13edf2195ffab10aa8f7edc7cbc6fde3d09797155f47349706 SHA512 9a3cae1cfaf3cc66dde3de1d74f68df7817abce86a8f68d6f93151f9e750d797ad75667bcf532f818c1b6d5ddc57d2721225aa6bc499b46593f87c5721e98622

diff --git a/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-54.ebuild b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-54.ebuild
new file mode 100644
index 000000000000..7cccab723284
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-54.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome2-utils meson readme.gentoo-r1 xdg
+
+DESCRIPTION="KDE Connect implementation for Gnome Shell"
+HOMEPAGE="https://github.com/GSConnect/gnome-shell-extension-gsconnect"
+SRC_URI="https://github.com/GSConnect/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="nautilus"
+
+COMMON_DEPEND="dev-libs/glib:2"
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=dev-libs/gjs-1.68
+	=gnome-base/gnome-shell-43*
+	gnome-base/gvfs
+	gnome-extra/evolution-data-server
+	|| ( media-libs/libcanberra media-libs/gsound )
+	nautilus? (
+		dev-python/nautilus-python
+		gnome-base/nautilus[introspection] )
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="For knowing more about how to do the setup, please visit:
+https://github.com/andyholmes/gnome-shell-extension-gsconnect/wiki/Installation"
+
+src_configure() {
+	# nemo support relies on nemo-python from https://github.com/linuxmint/nemo-extensions
+	# https://bugs.gentoo.org/694388
+	meson_src_configure \
+		-Dinstalled_tests=false \
+		-Dnemo=false \
+		$(meson_use nautilus)
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}