[gentoo-commits] repo/gentoo:master commit in: net-misc/gerbera/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     4dbb71bbeab3098423fbd364dc77f1f389c3d7e1
Author:     Christian Tietz <christian.tietz <AT> mailbox <DOT> org>
AuthorDate: Sat Nov  5 17:51:54 2022 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Tue Nov 22 13:26:04 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4dbb71bb

net-misc/gerbera: add 1.12.0

Signed-off-by: Christian Tietz <christian.tietz <AT> mailbox.org>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 net-misc/gerbera/Manifest              |  1 +
 net-misc/gerbera/gerbera-1.12.0.ebuild | 91 ++++++++++++++++++++++++++++++++++
 2 files changed, 92 insertions(+)

diff --git a/net-misc/gerbera/Manifest b/net-misc/gerbera/Manifest
index 3504b55c31f9..89f1b498fa6a 100644
--- a/net-misc/gerbera/Manifest
+++ b/net-misc/gerbera/Manifest
@@ -1 +1,2 @@
 DIST gerbera-1.11.0.tar.gz 4115178 BLAKE2B 1b5f28c4602f949459816f57555bfebbedbabc9681b3d0d9eb3d7742a9b273644cf9c10b411baeb3b0c4b5ea3c340d1c0d8d6035cb0e7f38ba0c40fae1c5cd1b SHA512 ae2b3342b3b57ce6d656d0ebadfd73b5f2764f2164314f6b0deac170a82e6861349c37732e6914454918112124038b221dbd4882001b5de51a49326432ccd70f
+DIST gerbera-1.12.0.tar.gz 4363130 BLAKE2B c9db8418fecaa7d58046f61b52148eb2e3fe168414d78909517aad22ddf68cb19c658ec25e8a2c5e1764aa457d8f3cbb676e2a50f4bd610dfc275f576ec70881 SHA512 0dd051058638dc5c3a834f92e6733a3e3f2833c73dd8184f4878d6dd1f3b9e5dabba5d62c13fc9a0e2424b8efb5501dab9acbb8befa1bdfbf178894a6c70bc16

diff --git a/net-misc/gerbera/gerbera-1.12.0.ebuild b/net-misc/gerbera/gerbera-1.12.0.ebuild
new file mode 100644
index 000000000000..86e41fa7ab04
--- /dev/null
+++ b/net-misc/gerbera/gerbera-1.12.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake linux-info
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/gerbera/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/gerbera/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+	S="${WORKDIR}/${P}"
+fi
+
+DESCRIPTION="UPnP Media Server"
+HOMEPAGE="https://gerbera.io"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="curl debug +exif exiv2 +ffmpeg ffmpegthumbnailer +javascript lastfm +magic +matroska mysql systemd +taglib"
+
+RDEPEND="
+	acct-user/gerbera
+	dev-db/sqlite
+	dev-libs/libebml:=
+	dev-libs/libfmt:=
+	dev-libs/pugixml
+	dev-libs/spdlog:=
+	>=net-libs/libupnp-1.14.12:=[ipv6(+),reuseaddr,-blocking-tcp]
+	sys-apps/util-linux
+	sys-libs/zlib
+	virtual/libiconv
+	curl? ( net-misc/curl )
+	exif? ( media-libs/libexif )
+	exiv2? ( media-gfx/exiv2 )
+	ffmpeg? ( media-video/ffmpeg:= )
+	ffmpegthumbnailer? ( media-video/ffmpegthumbnailer )
+	javascript? ( dev-lang/duktape:= )
+	lastfm? ( media-libs/lastfmlib )
+	magic? ( sys-apps/file )
+	matroska? ( media-libs/libmatroska:= )
+	mysql? ( dev-db/mysql-connector-c )
+	taglib? ( media-libs/taglib )
+"
+
+DEPEND="${RDEPEND}"
+
+CONFIG_CHECK="~INOTIFY_USER"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_AVCODEC=$(usex ffmpeg)
+		-DWITH_CURL=$(usex curl)
+		-DWITH_DEBUG=$(usex debug)
+		-DWITH_EXIF=$(usex exif)
+		-DWITH_EXIV2=$(usex exiv2)
+		-DWITH_FFMPEGTHUMBNAILER=$(usex ffmpegthumbnailer)
+		-DWITH_INOTIFY=1
+		-DWITH_JS=$(usex javascript)
+		-DWITH_LASTFM=$(usex lastfm)
+		-DWITH_MAGIC=$(usex magic)
+		-DWITH_MATROSKA=$(usex matroska)
+		-DWITH_MYSQL=$(usex mysql)
+		-DWITH_SYSTEMD=$(usex systemd)
+		-DWITH_TAGLIB=$(usex taglib)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	newinitd "${FILESDIR}"/${PN}-1.0.0.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}-1.0.0.confd ${PN}
+
+	insinto /etc/${PN}
+	newins "${FILESDIR}"/${PN}-1.3.0.config config.xml
+	fperms 0640 /etc/${PN}/config.xml
+	fowners root:gerbera /etc/${PN}/config.xml
+}
+
+pkg_postinst() {
+	if use mysql; then
+		elog "Gerbera has been built with MySQL support and needs"
+		elog "to be configured before being started. By default"
+		elog "SQLite will be used."
+	fi
+}