[gentoo-commits] repo/proj/guru:dev commit in: dev-python/dateparser/

["Anna Vyalkova" <cyber+gentoo@sysrq.in>]

commit:     bd6dea52d1c3ea36be563eae4ceac84349a5b420
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Tue Nov 22 06:50:33 2022 +0000
Commit:     Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Tue Nov 22 06:50:33 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=bd6dea52

dev-python/dateparser: new package, add 1.1.4

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 dev-python/dateparser/Manifest                |  1 +
 dev-python/dateparser/dateparser-1.1.4.ebuild | 51 +++++++++++++++++++++++++++
 dev-python/dateparser/metadata.xml            | 12 +++++++
 3 files changed, 64 insertions(+)

diff --git a/dev-python/dateparser/Manifest b/dev-python/dateparser/Manifest
new file mode 100644
index 000000000..bb72cce7d
--- /dev/null
+++ b/dev-python/dateparser/Manifest
@@ -0,0 +1 @@
+DIST dateparser-1.1.4.tar.gz 294406 BLAKE2B 5e13a76f1a11dfdb322494a06f288b404149f22481beaf991b0256874aaabb65120fb3e217da5f18d3152cd1786354e2dc8a237591821458be27d5cbac6beac0 SHA512 a20f821dea1ec8e6eb7033de91b1e74777607c4b31286a87e06d85c7278dad3c164ddc88640e0372d9f32eed72a40e28c58bea26a77fdc01c59d2d9fc70bb2d7

diff --git a/dev-python/dateparser/dateparser-1.1.4.ebuild b/dev-python/dateparser/dateparser-1.1.4.ebuild
new file mode 100644
index 000000000..7e8fdc2c1
--- /dev/null
+++ b/dev-python/dateparser/dateparser-1.1.4.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Date parsing library designed to parse dates from HTML pages"
+HOMEPAGE="https://github.com/scrapinghub/dateparser"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-4"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/regex[${PYTHON_USEDEP}]
+	dev-python/tzlocal[${PYTHON_USEDEP}]
+"
+BDEPEND="test? (
+	dev-libs/fastText[python,${PYTHON_USEDEP}]
+	dev-python/convertdate[${PYTHON_USEDEP}]
+	dev-python/hijri-converter[${PYTHON_USEDEP}]
+	dev-python/langdetect[${PYTHON_USEDEP}]
+	dev-python/parameterized[${PYTHON_USEDEP}]
+)"
+
+EPYTEST_IGNORE=(
+	# GitPython fails to allocate memory
+	tests/test_dateparser_data_integrity.py
+)
+
+EPYTEST_DESELECT=(
+	# tests that require network
+	tests/test_language_detect.py::CustomLangDetectParserTest::test_custom_language_detect_fast_text_{0,1}
+)
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme
+
+pkg_postinst() {
+	optfeature "calendars support" "dev-python/hijri-converter dev-python/convertdate"
+	optfeature "fasttext support" "dev-libs/fastText[python]"
+	optfeature "langdetect support" dev-python/langdetect
+}

diff --git a/dev-python/dateparser/metadata.xml b/dev-python/dateparser/metadata.xml
new file mode 100644
index 000000000..69d0caa11
--- /dev/null
+++ b/dev-python/dateparser/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">scrapinghub/dateparser</remote-id>
+		<remote-id type="pypi">dateparser</remote-id>
+	</upstream>
+</pkgmetadata>