[gentoo-commits] repo/gentoo:master commit in: gnome-extra/cinnamon-control-center/

["Sam James" <sam@gentoo.org>]

commit:     67ed0c925bdcfd2ec5f568dd18cb4de38e4a69c6
Author:     Matthew S. Turnbull <sparky <AT> bluefang-logic <DOT> com>
AuthorDate: Fri Nov 18 06:30:53 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Nov 22 06:17:38 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=67ed0c92

gnome-extra/cinnamon-control-center: add 5.6.0

Signed-off-by: Matthew S. Turnbull <sparky <AT> bluefang-logic.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 gnome-extra/cinnamon-control-center/Manifest       |   1 +
 .../cinnamon-control-center-5.6.0.ebuild           | 100 +++++++++++++++++++++
 2 files changed, 101 insertions(+)

diff --git a/gnome-extra/cinnamon-control-center/Manifest b/gnome-extra/cinnamon-control-center/Manifest
index c6eccbee9935..9eb11161140d 100644
--- a/gnome-extra/cinnamon-control-center/Manifest
+++ b/gnome-extra/cinnamon-control-center/Manifest
@@ -1,2 +1,3 @@
 DIST cinnamon-control-center-5.2.1.tar.gz 3863530 BLAKE2B 826494b8f8a4dead32d6031d7b4b2a44d357b3e8fedf1065b61193caa86ad433ba68fd9344f70bbce77bb94e086ae15f8854dc73916a5f60c49b1b2bd9e7101c SHA512 d322a9b460f13c697d327dda75a3ea16dd96414ed52ffbcdfc19479533178585da795c064ae441b36ef02f1aa779704db039328ca4ac4c373f363967948f2301
 DIST cinnamon-control-center-5.4.7.tar.gz 3873806 BLAKE2B 136ee3328f9ee19fabc70ac6f9da7e92f2e8748bebdda59228b866382122580a918630781935a49bd95401181661a84c498499ff46ed3ad62a7cf687848e9806 SHA512 b7d45e41984d53a169a08472d8b4f58b03acf670df3e8e741636155bfad3189cb8dc5ea929e887a7e4f29b354722dd344cb02f8d00b42de010ba4e24d106e08d
+DIST cinnamon-control-center-5.6.0.tar.gz 3872303 BLAKE2B c0db21dbad031e3a3e06ea2f6253421c548b993eef323e2be1ad131e0a8e980b7b3a93d9a7a6d1feaf13ebe8c5f77fd286f0cb56b7d22c7cb447e46178c6f328 SHA512 336c554c93212c28df4f163b6a06d2c287901c167dc8e5563dbb44ddd69119db36d15086b6b1e78ff1b199424a4a24ac9605d59877a3f8174fd1f406a0f7ca4f

diff --git a/gnome-extra/cinnamon-control-center/cinnamon-control-center-5.6.0.ebuild b/gnome-extra/cinnamon-control-center/cinnamon-control-center-5.6.0.ebuild
new file mode 100644
index 000000000000..2d9a5bb44676
--- /dev/null
+++ b/gnome-extra/cinnamon-control-center/cinnamon-control-center-5.6.0.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit meson gnome2-utils python-any-r1 xdg virtualx
+
+DESCRIPTION="Cinnamons's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-control-center"
+SRC_URI="https://github.com/linuxmint/cinnamon-control-center/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+IUSE="+colord input_devices_wacom +networkmanager +modemmanager gnome-online-accounts systemd test"
+REQUIRED_USE="modemmanager? ( networkmanager )"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=gnome-base/libgnomekbd-3.0.0:0=
+	>=gnome-extra/cinnamon-desktop-5.6:0=
+	>=gnome-extra/cinnamon-menus-5.6:0=
+	media-libs/fontconfig
+	>=sys-auth/polkit-0.103
+	>=sys-power/upower-0.99.8
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=x11-libs/gtk+-3.16.0:3
+	>=dev-libs/libgudev-232
+	>=x11-libs/libnotify-0.7.3:0=
+	x11-libs/libX11
+	>=x11-libs/libxklavier-5.1
+
+	colord? ( >=x11-misc/colord-0.1.14:0= )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7:=
+		>=x11-libs/libXi-1.2 )
+	networkmanager? (
+		>=gnome-extra/nm-applet-1.2.0
+		>=net-libs/libnma-1.8.34
+		>=net-misc/networkmanager-1.2.0:=[modemmanager?]
+
+		modemmanager? ( >=net-misc/modemmanager-0.7 )
+	)
+	gnome-online-accounts? (
+		>=net-libs/gnome-online-accounts-3.18.0
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+
+	colord? ( >=gnome-extra/gnome-color-manager-3 )
+	input_devices_wacom? ( gnome-extra/cinnamon-settings-daemon[input_devices_wacom] )
+	systemd? ( >=sys-apps/systemd-31 )
+	!systemd? ( app-admin/openrc-settingsd )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	app-text/iso-codes
+	x11-base/xorg-proto
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang meson_install_schemas.py
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use colord color)
+		$(meson_use modemmanager)
+		$(meson_use networkmanager)
+		$(meson_use gnome-online-accounts onlineaccounts)
+		$(meson_use input_devices_wacom wacom)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}